Reference Manual

Volume I

Basic Programming Guide

XSI/CLIPS Basic Programming Guide

Version 6.xx January 2010

The History of CLIPS

The origins of the C Language Integrated Production System (CLIPS) date back to 1984 at NASA’s Johnson Space Center. At this time, the Artificial Intelligence Section had developed over a dozen prototype expert systems applications using state of the art hardware and software. However, despite extensive demonstrations of the potential of expert systems, few of these applications were put into regular use. This failure to provide expert systems technology within NASA’s operational computing constraints could largely be traced to the use of LISP as the base language for nearly all expert system software tools at that time. In particular, three problems hindered the use of LISP based expert system tools within NASA: the low availability of LISP on a wide variety of conventional computers, the high cost of state of the art LISP tools and hardware, and the poor integra­tion of LISP with other languages (making embedded applications difficult).

The Artificial Intelligence Section felt that the use of a conventional language, such as C, would eliminate most of these problems, and initially looked to the expert system tool vendors to provide an expert system tool written using a conventional language. Although a number of tool vendors started converting their tools to run in C, the cost of each tool was still very high, most were restricted to a small variety of computers, and the projected availability times were discouraging. To meet all of its needs in a timely and cost effective manner, it became evident that the Artificial Intelligence Section would have to develop its own C based expert system tool.

The prototype version of CLIPS was developed in the spring of 1985 in a little over two months. Particular attention was given to making the tool compatible with expert systems under development at that time by the Artificial Intelligence Section. Thus, the syntax of CLIPS was made to very closely resemble the syntax of a subset of the ART expert system tool developed by Inference Corporation. Although originally modelled from ART, CLIPS was developed entirely without assistance from Inference or access to the ART source code.

The original intent for CLIPS was to gain useful insight and knowledge about the construction of expert system tools and to lay the groundwork for the construction of a replacement tool for the commercial tools currently being used. Version 1.0 demonstrated the feasibility of the project concept. After additional development, it became apparent that CLIPS would be a low cost expert system tool ideal for the purposes of training. Another year of development and internal use went into CLIPS improving its portability, performance, functionality, and supporting documentation. Version 3.0 of CLIPS was made available to groups outside of NASA in the summer of 1986.2

Further enhancements transformed CLIPS from a training tool into a tool useful for the development and delivery of expert systems as well. Versions 4.0 and 4.1 of CLIPS, released respectively in the summer and fall of 1987, featured greatly improved performance, external language integration, and delivery capabilities. Version 4.2 of CLIPS, released in the summer of 1988, was a complete rewrite of CLIPS for code modularity. Also included with this release were an architecture manual providing a detailed description of the CLIPS software architecture and a utility program for aiding in the verification and validation of rule based programs. Version 4.3 of CLIPS, released in the summer of 1989, added still more functionality.

Originally, the primary representation methodology in CLIPS was a forward chaining rule lan­guage based on the Rete algorithm (hence the Production System part of the CLIPS acronym). Version 5.0 of CLIPS, released in the spring of 1991, introduced two new programming paradigms: procedural programming (as found in languages such as C and Ada) and object oriented programming (as found in languages such as the Common Lisp Object System and Smalltalk). The object oriented programming language provided within CLIPS is called the CLIPS Object Oriented Language (COOL). Version 5.1 of CLIPS, released in the fall of 1991, was primarily a software maintenance upgrade required to support the newly developed and/or enhanced X Window, MS DOS, and Macintosh interfaces. Version 6.0 of CLIPS, released in 1993, provided support for the development of modular programs and tight integration between the object-oriented and rule-based programming capabilities of CLIPS. Version 6.1 of CLIPS, released in 1998, removed support for older non-ANSI C Compilers and added support for C++ compilers. Commands to profile the time spent in constructs and user-defined functions were also added.

CLIPS is now maintained independently from NASA as public domain software.

Because of its portability, extensibility, capabilities, and low cost, CLIPS has received widespread acceptance throughout the government, industry, and academia. The development of CLIPS has helped to improve the ability to deliver expert system technology throughout the public and private sectors for a wide range of applications and diverse computing environments. See appendix A of the Basic Programming Guide for information on obtaining CLIPS and support.

CLIPS Version 6.2+

Version 6.2 of CLIPS contains two major enhancements. First, CLIPS now provides a mechanism which allows an embedded application to create multiple environments into which programs can be loaded. Second, an improved Windows 95/98/NT CLIPS interface is now available and the Macintosh CLIPS interface has been enhanced to support MacOS X. For a detailed listing of differences between the 6.x releases of CLIPS, refer to appendix B of the Basic Programming Guide and appendix C of the Advanced Programming Guide.

Two documents are provided with CLIPS.

The CLIPS Reference Manual which is split into the following parts:

• Volume I - The Basic Programming Guide, which provides the definitive description of CLIPS syntax and examples of usage.
• Volume II - The Advanced Programming Guide, which provides detailed discus­sions of the more sophisticated features in CLIPS and is intended for people with extensive programming experience who are using CLIPS for advanced ap­plications.
• Volume III - The Interfaces Guide, which provides information on machine specific interfaces.
• The CLIPS User’s Guide which provides an introduction to CLIPS rule based and object oriented programming and is intended for people with little or no expert system experience.

As with any large project, CLIPS is the result of the efforts of numerous people. The primary contributors have been: Robert Savely, who conceived the project and provided overall direction and support; Chris Culbert, who managed the project and wrote the original CLIPS Reference Manual; Gary Riley, who designed and developed the rule based portion of CLIPS, co authored the CLIPS Reference Manual, and developed the Macintosh interface for CLIPS; Brian Donnell, who designed and developed the CLIPS Object Oriented Language (COOL) and co authored the CLIPS Reference Manual; Bebe Ly, who developed the X Window interface for CLIPS; Chris Ortiz, who developed the original Windows 95 interface for CLIPS; Dr. Joseph Giarratano of the University of Houston-Clear Lake, who wrote the CLIPS User’s Guide; and Frank Lopez, who designed and developed CLIPS version 1.0 and wrote the CLIPS 1.0 User’s Guide.

Many other individuals contributed to the design, development, review, and general support of CLIPS, including: Jack Aldridge, Carla Armstrong, Paul Baffes, Ann Baker, Stephen Baudendistel, Les Berke, Tom Blinn, Marlon Boarnet, Dan Bochsler, Bob Brown, Barry Cameron, Tim Cleghorn, Major Paul Condit, Major Steve Cross, Andy Cunningham, Dan Danley, Mark Engelberg, Kirt Fields, Ken Freeman, Kevin Greiner, Ervin Grice, Sharon Hecht, Patti Herrick, Mark Hoffman, Grace Hua, Gordon Johnson, Phillip Johnston, Sam Juliano, Ed Lineberry, Bowen Loftin, Linda Martin, Daniel McCoy, Terry McGregor, Becky McGuire, Scott Meadows, C. J. Melebeck, Paul Mitchell, Steve Mueller, Bill Paseman, Cynthia Rathjen, Eric Raymond, Reza Razavipour, Marsha Renals, Monica Rua, Tim Saito, Michael Sullivan, Gregg Swietek, Eric Taylor, James Villarreal, Lui Wang, Bob Way, Jim Wescott, Charlie Wheeler, and Wes White.

This manual is the Basic Programming Guide for CLIPS. It is intended for users interested in the syntax of CLIPS. No previous expert system background is required, al­though a general understanding of computer languages is assumed. Section 2 of this manual provides an overview of the CLIPS language and basic terminology. Sections 3 through 11 provide additional details regarding the CLIPS programming language on topics such as rules and the CLIPS Object Oriented Programming Language (COOL). The types of actions and functions provided by CLIPS are defined in section 12. Finally, commands typically used from the CLIPS interactive interface are described in section 13.

The Basic Programming Guide documents just the basic CLIPS syntax. More advanced capabilities, such as user defined functions, embedded applications, etc., are docu­mented more fully in the Advanced Programming Guide. The Advanced Programming Guide is intended for users who have a complete knowledge of the CLIPS syntax and a programming background. It is not necessary to read the Advanced Program­ming Guide to learn how to use CLIPS. CLIPS can be learned and simple expert systems can be built with the information provided in this manual.

This section gives a general overview of CLIPS and of the basic concepts used through­out this manual.

CLIPS expert systems may be executed in three ways: interactively using a simple, text oriented, command prompt interface; interactively using a window/menu/mouse interface on certain ma­chines; or as embedded expert systems in which the user provides a main pro­gram and controls execution of the expert system. Embedded applications are dis­cussed in the Advanced Programming Guide. In addition, a series of commands can be automatically read di­rectly from a file when CLIPS is first started or as the result of the batch command.

The generic CLIPS interface is a simple, interactive, text oriented, command prompt interface for high porta­bility. The stan­dard usage is to create or edit a knowledge base using any standard text editor, save the knowledge base as one or more text files, exit the editor and execute CLIPS, then load the knowledge base into CLIPS. The in­terface provides commands for viewing the current state of the sys­tem, tracing execu­tion, adding or removing information, and clearing CLIPS.

A more sophisticated window interface is available for the Macintosh, Windows 3.1, and X Window environments. All interface commands described in this section are available in the window interfaces. These interfaces are described in more detail in the Interfaces Guide.

The primary method for interacting with CLIPS in a non embedded environment is through the CLIPS command prompt (or top level). When the “CLIPS>” prompt is printed, a command may be entered for evaluation. Commands may be function calls, constructs, global variables, or constants. If a function call is entered (see section 2.3.2), that function is evaluated and its return value is printed. Function calls in CLIPS use a prefix notation—the operands to a function always appear after the function name. Entering a construct definition (see section 2.3.3) at the CLIPS prompt creates a new construct of the appropriate type. Entering a global variable (see section 2.4.3) causes the value of the global variable to be printed. Entering a constant (see section 2.3.1) at the top level causes the constant to be printed (which is not very useful). For example,

CLIPS (V6.0 05/12/93)

CLIPS> (+ 3 4)

7

CLIPS> (defglobal ?*x* = 3)

CLIPS> ?*x*

3

CLIPS> red

red

CLIPS>

The previous example first called the addition function adding the numbers 3 and 4 to yield the result 7. A global variable ?*x* was then defined and given the value 3. The variable ?*x* was then entered at the prompt and its value of 3 was returned. Finally the constant symbol red was entered and was returned (since a constant evaluates to itself).

Some operating systems allow additional arguments to be specified to a program when it begins execution. When the CLIPS executable is started under such an operating system, CLIPS can be made to automatically execute a series of commands read directly from a file or to load constructs from a file. The command line syntax for starting CLIPS and automatically reading commands or loading constructs from a file is as follows:

Syntax

clips <option>*

<option> ::= -f <filename> |

-f2 <filename> |

-l <filename>

For the  f option, <filename> is a file that contains CLIPS commands. If the exit command is included in the file, CLIPS will halt and the user is returned to the operat­ing system after executing the commands in the file. If an exit command is not in the file, CLIPS will enter in its interactive state after executing the commands in the file. Commands in the file should be entered exactly as they would be interactively (i.e. opening and closing parentheses must be included and a carriage return must be at the end of the command). The  f command line option is equivalent to interactively entering a batch command as the first command to the CLIPS prompt.

The -f2 option is similar to the -f option, but is equivalent to interactively entering a batch* command. The commands stored in <filename> are immediately executed, but the commands and their return values are not displayed as they would be for a batch command.

For the -l option, <filename> should be a file containing CLIPS constructs. This file will be loaded into the environment. The  l command line option is equivalent to interactively entering a load command.

When using an expert system, two kinds of integration are important: embedding CLIPS in other systems, and calling external functions from CLIPS. CLIPS was designed to allow both kinds of integration.

Using CLIPS as an embedded application allows the easy integration of CLIPS with existing systems. This is useful in cases where the expert system is a small part of a larger task or needs to share data with other functions. In these situations, CLIPS can be called as a subroutine and information may be passed to and from CLIPS. Em­bedded applications are discussed in the Advanced Programming Guide.

It also may be useful to call external functions while executing a CLIPS construct or from the top level of the interactive interface. CLIPS variables or literal values may be passed to an external function, and functions may return val­ues to CLIPS. The easy addition of external functions allows CLIPS to be extended or customized in almost any way. The Advanced Programming Guide describes how to integrate CLIPS with functions or systems written in C as well as in other lan­guages.

The terminology used throughout this manual to describe the CLIPS syntax is fairly com­mon to computer reference manuals. Plain words or characters, particularly paren­theses, are to be typed exactly as they appear. Bolded words or characters, however, represent a verbal description of what is to be entered. Sequences of words enclosed in single angle brackets (called terms or non terminal symbols), such as <string>, represent a single entity of the named class of items to be supplied by the user. A non terminal symbol followed by a *, represents zero or more entities of the named class of items which must be supplied by the user. A non terminal symbol followed by a +, represents one or more entities of the named class of items which must be supplied by the user. A * or + by itself is to be typed as it appears. Vertical and horizontal ellipsis (three dots arranged respectively vertically and horizontally) are also used between non terminal symbols to indicate the occurrence of one or more entities. A term enclosed within square brackets, such as [<comment>], is optional (i.e. it may or may not be included). Vertical bars indicate a choice between multiple terms. White spaces (tabs, spaces, carriage re­turns) are used by CLIPS only as delimiters between terms and are ignored otherwise (unless inside double quotes). The ::= symbol is used to indicate how a non terminal symbol can be replaced. For example, the following syntax description indicates that a <lexeme> can be replaced with either a <symbol> or a <string>.

<lexeme> ::= <symbol> | <string>

A complete BNF listing for CLIPS constructs along with some commonly used replacements for non terminal symbols are listed in appendix I.

CLIPS provides three basic elements for writing programs: primitive data types, functions for manipulating data, and constructs for adding to a knowledge base.

CLIPS provides eight primitive data types for representing information. These types are float, integer, symbol, string, external address, fact address, instance name and instance address. Numeric information can be represented using floats and integers. Symbolic information can be represented using symbols and strings.

A .ib;number; consists only of digits (0 9), a decimal point (.), a sign (+ or  ), and, optionally, an (e) for exponential notation with its corresponding sign. A number is either stored as a float; or an integer. Any number consisting of an optional sign followed by only digits is stored as an integer (represented internally by CLIPS as a C long integer). All other numbers are stored as floats (represented internally by CLIPS as a C double precision float). The number of significant digits will de­pend on the machine implementation. Roundoff errors also may occur, again depend­ing on the machine implementation. As with any computer language, care should be taken when comparing floating point values to each other or comparing integers to floating point values. Some examples of integers are

237 15 +12 -32

Some examples of floats are

237e3 15.09 +12.0 -32.3e-7

Specifically, integers use the following format:

<integer> ::= [+ | -] <digit>+

<digit> ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9

Floating point numbers use the following format:

<float> ::= <integer> <exponent> |

<integer> . [exponent]

. <unsigned integer> [exponent]

<integer> . <unsigned integer> [exponent]

<unsigned-integer> ::= <digit>+

<exponent> ::= e | E <integer>

A sequence of characters which does not exactly follow the format of a number is treated as a symbol (see the next paragraph).

A symbol in CLIPS is any sequence of characters that starts with any printable ASCII character and is followed by zero or more printable ASCII characters. When a delimiter is found, the symbol is ended. The following characters act as delimiters: any non printable ASCII character (including spaces, tabs, carriage returns, and line feeds), a double quote, opening and closing parentheses “(” and “)”, an ampersand “&”, a vertical bar “|”, a less than “<”, and a tilde “~”. A semicolon “;” starts a CLIPS comment (see section 2.3.3) and also acts as a de­limiter. Delimiters may not be included in symbols with the exception of the “<“ character which may be the first character in a symbol. In addition, a symbol may not begin with either the “?” character or the “$?” sequence of characters (although a symbol may contain these characters). These characters are reserved for variables (which are discussed later in this section). CLIPS is case sensitive (i.e. uppercase letters will match only uppercase let­ters). Note that numbers are a special case of symbols (i.e. they satisfy the definition of a symbol, but they are treated as a different data type). Some simple examples of symbols are

foo Hello B76-HI bad_value

127A 456-93-039 @+=-% 2each

A string is a set of characters that starts with a double quote (“) and is followed by zero or more printable characters. A string ends with double quotes. Double quotes may be embedded within a string by placing a backslash (\) in front of the character. A backslash may be embedded by placing two consecutive back­slash characters in the string. Some examples are

“foo” “a and b” “1 number” “a\”quote”

Note that the string “abcd“ is not the same as the symbol abcd. They both contain the same characters, but are of different types. The same holds true for the instance name [abcd].

An external address is the address of an external data structure returned by a function (written in a language such as C or Ada) that has been integrated with CLIPS. This data type can only be created by calling a function (i.e. it is not possible to specify an external address by typing the value). In the basic version of CLIPS (which has no user defined external functions), it is not possible to create this data type. External addresses are discussed in further detail in the Advanced Programming Guide;. Within CLIPS, the printed representation of an external address is

<Pointer-XXXXXX>

where XXXXXX is the external address.

A fact is a list of atomic values that are either referenced positionally (ordered facts) or by name (non ordered or template facts). Facts are referred to by index or address; section 2.4.1 gives more details. The printed format of a fact address is:

<Fact-XXX>

where XXX is the fact index.

An instance is an object that is an instantiation or specific example of a class. Objects in CLIPS are defined to be floats, integers, symbols, strings, multifield values, external addresses, fact addresses or instances of a user defined class. A user defined class is created using the defclass construct. An instance of a user defined class is created with the make instance function, and such an instance can be referred to uniquely by address. Within the scope of a module (see section 10.5.1), an instance can also be uniquely referred to by name. All of these definitions will be covered in more detail in Sections 2.4.2, 2.5.2.3, 2.6 and 9. An instance name is formed by enclosing a symbol within left and right brackets. Thus, pure symbols may not be surrounded by brackets. If the CLIPS Object Oriented Language (COOL) is not included in a particular CLIPS configuration, then brackets may be wrapped around symbols. Some examples of instance names are:

[pump-1] [foo] [+++] [123-890]

Note that the brackets are not part of the name of the instance; they merely indicate that the enclosed symbol is an instance name. An instance address can only be obtained by binding the return value of a function called instance address or by binding a variable to an instance matching an object pattern on the LHS of a rule (i.e., it is not possible to specify an instance address by typing the value). A reference to an instance of a user defined class can either be by name or address; instance addresses should only be used when speed is critical. Within CLIPS, the printed representation of an instance address is

<Instance-XXX>

where XXX is the name of the instance.

In CLIPS, a placeholder that has a value (one of the primitive data types) is referred to as a field. The primitive data types are referred to as single field values. A constant is a non varying single field value directly expressed as a series of characters (which means that external addresses, fact addresses and instance addresses cannot be expressed as constants because they can only be obtained through function calls and variable bindings). A multifield value is a sequence of zero or more single field values. When displayed by CLIPS, multifield values are enclosed in parentheses. Collectively, single and multifield values are referred to as values. Some examples of multifield values are

(a) (1 bar foo) () (x 3.0 “red” 567)

Note that the multifield value (a) is not the same as the single field value a. Multifield values are created either by calling functions which return multifield values, by using wildcard arguments in a deffunction, object message handler, or method, or by binding variables during the pattern matching process for rules. In CLIPS, a variable is a symbolic location that is used to store values. Variables are used by many of the CLIPS constructs (such as defrule, deffunction, defmethod, and defmessage handler) and their usage is explained in the sections describing each of these constructs.

A function in CLIPS is a piece of executable code identified by a specific name which returns a useful value or performs a useful side effect (such as displaying information). Throughout the CLIPS documentation, the word function is generally used to refer only to functions which return a value (whereas commands and actions are used to refer to functions which have a side effect but generally do not return a value).

There are several types of functions. User defined functions and system defined functions are pieces of code that have been written in an external language (such as C, FORTRAN, or Ada) and linked with the CLIPS environment. System defined functions are those functions that have been defined internally by the CLIPS environment. User defined functions are functions that have been defined externally of the CLIPS environment. A complete list of system defined functions can be found in appendix J.

The deffunction construct allows users to define new functions directly in the CLIPS environment using CLIPS syntax. Functions defined in this manner appear and act like other functions, however, instead of being directly executed (as code written in an external language would be) they are interpreted by the CLIPS environment. Deffunctions are also discussed in section 2.5.2.1 in the context of procedural knowledge representation.

Generic functions can be defined using the defgeneric and defmethod constructs. Generic functions allow different pieces of code to be executed depending upon the arguments passed to the generic function. Thus, a single function name can be overloaded with more than one piece of code. Generic functions are also discussed in section 2.5.2.2 in the context of procedural knowledge representation.

Function calls in CLIPS use a prefix notation – the arguments to a function always appear after the function name. Function calls begin with a left parenthesis, followed by the name of the function, then the arguments to the function follow (each argument separated by one or more spaces). Arguments to a function can be primitive data types, variables, or another function call. The function call is then closed with a right parenthesis. Some examples of function calls using the addition (+) and multiplication (*) functions are shown following.

(+ 3 4 5)

(* 5 6.0 2)

(+ 3 (* 8 9) 4)

(* 8 (+ 3 (* 2 3 4) 9) (* 3 4))

While a function refers to a piece of executable code identified by a specific name, an expression refers to a function which has its arguments specified (which may or may not be functions calls as well). Thus the previous examples are expressions which make calls to the * and + functions.

Several defining constructs appear in CLIPS: defmodule, defrule, deffacts, deftemplate, defglobal, deffunction, defclass, definstances, defmessage handler, defgeneric, and defmethod. All constructs in CLIPS are surrounded by parentheses. The construct opens with a left parenthe­sis and closes with a right parenthesis. Defining a construct differs from calling a function primarily in effect. Typically a function call leaves the CLIPS environment unchanged (with some notable exceptions such as resetting or clearing the environment or opening a file). Defining a construct, however, is explicitly intended to alter the CLIPS environment by adding to the CLIPS knowledge base. Unlike function calls, constructs never have a return value.

As with any programming language, it is highly beneficial to comment CLIPS code. All constructs (with the exception of defglobal) allow a comment directly following the construct name. Comments also can be placed within CLIPS code by using a semicolon (;). Everything from the semicolon until the next return character will be ignored by CLIPS. If the semicolon is the first character in the line, the entire line will be treated as a comment. Examples of commented code will be pro­vided throughout the reference manual. Semicolon commented text is not saved by CLIPS when loading constructs (however, the optional comment string within a construct is saved).

There are three primary formats for representing information in CLIPS: facts, objects and global variables.

Facts are one of the basic high level forms for representing information in a CLIPS system. Each fact represents a piece of information which has been placed in the current list of facts, called the fact list. Facts are the fundamental unit of data used by rules (see section 2.5.1).

Facts may be added to the fact list (using the assert command), removed from the fact list (using the retract command), modified (using the modify command), or duplicated (using the duplicate command) through explicit user interaction or as a CLIPS program executes;. The number of facts in the fact list and the amount of information that can be stored in a fact is limited only by the amount of memory in the computer. If a fact is asserted into the fact list that exactly matches an already existing fact, the new assertion will be ignored (however, this behavior can be changed, see sections 13.4.4 and 13.4.5).

Some commands, such as the retract, modify, and duplicate commands, require a fact to be specified. A fact can be specified either by fact index or fact address. Whenever a fact is added (or modified) it is given a unique integer index called a fact index. Fact indices start at zero and are incremented by one for each new or changed fact. Whenever a reset or clear command is given, the fact indices restart at zero. A fact may also be specified through the use of a fact address. A fact address can be obtained by capturing the return value of commands which return fact addresses (such as assert, modify, and duplicate) or by binding a variable to the fact address of a fact which matches a pattern on the LHS of a rule (see section 5.4.1.8 for details).

A fact identifier is a shorthand notation for displaying a fact. It consists of the character “f”, followed by a dash, followed by the fact index of the fact. For example, f 10 refers to the fact with fact index 10.

A fact is stored in one of two formats: ordered or non ordered.

Ordered facts consist of a symbol followed by a sequence of zero or more fields separated by spaces and delimited by an opening parenthesis on the left and a closing parenthesis on the right. The first field of an ordered fact specifies a “relation” that applied to the remaining fields in the ordered fact. For example, (father of jack bill) states that bill is the father of jack.

Some examples of ordered facts are shown following.

(the pump is on)

(altitude is 10000 feet)

(grocery-list bread milk eggs)

Fields in a non ordered fact may be of any of the primitive data types (with the exception of the first field which must be a symbol), and no restriction is placed on the ordering of fields. The following symbols are reserved and should not be used as the first field in any fact (ordered or non ordered): test, and, or, not, declare, logical, object, exists, and forall. These words are reserved only when used as a deftemplate name (whether explicitly defined or implied). These symbols may be used as slot names, however, this is not recommended.

Ordered facts encode information positionally. To access that information, a user must know not only what data is stored in a fact but which field contains the data. Non ordered (or deftemplate) facts provide the user with the ability to abstract the structure of a fact by assign­ing names to each field in the fact. The deftemplate construct (see section 3) is used to create a template which can then be used to access fields by name. The deftemplate construct is analogous to a record or structure definition in programming languages such as Pascal and C.

The deftemplate construct allows the name of a template to be defined along with zero or more definitions of named fields or slots. Unlike ordered facts, the slots of a deftemplate fact may be constrained by type, value, and numeric range. In addition, default values can be specified for a slot. A slot consists of an opening parenthesis followed by the name of the slot, zero or more fields, and a closing parenthesis. Note that slots may not be used in an ordered fact and that positional fields may not be used in a deftemplate fact.

Deftemplate facts are distinguished from ordered facts by the first field within the fact. The first field of all facts must be a symbol, however, if that symbol corresponds to the name of a deftemplate, then the fact is a deftemplate fact. The first field of a deftemplate fact is followed by a list of zero or more slots. As with ordered facts, deftemplate facts are enclosed by an opening parenthesis on the left and a closing parenthesis on the right.

Some examples of deftemplate facts are shown following.

(client (name “Joe Brown”) (id X9345A))

(point-mass (x-velocity 100) (y-velocity -200))

(class (teacher “Martha Jones”) (#-students 30) (Room “37A”))

(grocery-list (#-of-items 3) (items bread milk eggs))

Note that the order of slots in a deftemplate fact is not important. For example the following facts are all identical:

(class (teacher “Martha Jones”) (#-students 30) (Room “37A”))

(class (#-students 30) (teacher “Martha Jones”) (Room “37A”))

(class (Room “37A”) (#-students 30) (teacher “Martha Jones”))

In contrast, note that the following ordered fact are not identical.

(class “Martha Jones” 30 “37A”)

(class 30 “Martha Jones” “37A”)

(class “37A” 30 “Martha Jones”)

The im­mediate advantages of clarity and slot order independence for deftemplate facts should be readily apparent.

In addition to being asserted and retracted, deftemplate facts can also be modified and duplicated (using the modify and duplicate commands). Modifying a fact changes a set of specified slots within that fact. Duplicating a fact creates a new fact identical to the original fact and then changes a set of specified slots within the new fact. The benefit of using the modify and duplicate commands is that slots which don’t change, don’t have to be specified.

The deffacts construct allows a set of a priori or initial knowledge to be specified as a collection of facts. When the CLIPS environment is reset (using the reset command) every fact specified within a deffacts construct in the CLIPS knowledge base is added to the fact list.

An object in CLIPS is defined to be a symbol, a string, a floating point or integer number, a multifield value, an external address or an instance of a user defined class. Section 2.3.1 explains how to reference instances of user defined classes. Objects are described in two basic parts: properties and behavior. A classis a template for common properties and behavior of objects which are instances of that class. Some examples of objects and their classes are:

| Object (Printed Representation) | Class |

Objects in CLIPS are split into two important categories: primitive types and instances of user defined classes. These two types of objects differ in the way they are referenced, created and deleted as well as how their properties are specified.

Primitive type objects are referenced simply by giving their value, and they are created and deleted implicitly by CLIPS as they are needed. Primitive type objects have no names or slots, and their classes are predefined by CLIPS. The behavior of primitive type objects is like that of instances of user defined classes, however, in that you can define message handlers and attach them to the primitive type classes. It is anticipated that primitive types will not be used often in an object oriented programming (OOP) context; the main reason classes are provided for them is for use in generic functions. Generic functions use the classes of their arguments to determine which methods to execute; sections 2.3.2, 2.5.2.2 and 8 give more detail.

An instance of a user defined class is referenced by name or address, and they are created and deleted explicitly via messages and special functions. The properties of an instance of a user defined class are expressed by a set of slots, which the object obtains from its class. As previously defined, slots are named single field or multifield values. For example, the object Rolls Royce is an instance of the class CAR. One of the slots in class CAR might be “price”, and the Rolls Royce object’s value for this slot might be $75,000.00. The behavior of an object is specified in terms of procedural code called message handlers, which are attached to the object’s class. Message handlers and manipulation of objects are described in Section 2.5.2.3. All instances of a user defined class have the same set of slots, but each instance may have different values for those slots. However, two instances which have the same set of slots do not necessarily belong to the same class, since two different classes can have identical sets of slots.

The primary difference between object slots and template (or non ordered) facts is the notion of inheritance. Inheritance allows the properties and behavior of a class to be described in terms of other classes. COOL supports multiple inheritance: a class may directly inherit slots and message handlers from more than one class. Since inheritance is only useful for slots and message handlers, it is often not meaningful to inherit from one of the primitive type classes, such as MULTIFIELD or NUMBER. This is because these classes cannot have slots and usually do not have message handlers.

Further discussion on these topics can be found in Section 2.6, and a comprehensive description of the CLIPS Object Oriented Language (COOL) can be found in Section 9.

The definstances construct allows a set of a priori or initial knowledge to be specified as a collection of instances of user defined classes. When the CLIPS environment is reset (using the reset command) every instance specified within a definstances construct in the CLIPS knowledge base is added to the instance list.

The defglobal construct allows variables to be defined which are global in scope throughout the CLIPS environment. That is, a global variable can be accessed anywhere in the CLIPS environment and retains its value independent of other constructs. In contrast, some constructs (such as defrule and deffunction) allow local variables to be defined within the definition of the construct. These local variables can be referred to within the construct, but have no meaning outside the construct. A CLIPS global variable is similar to global variables found in procedural programming languages such as LISP, C and Ada. Unlike C and Ada, however, CLIPS global variables are weakly typed (they are not restricted to holding a value of a single data type).

CLIPS provides heuristic and procedural paradigms for representing knowledge. These two paradigms are discussed in this section. Object oriented programming (which combines aspects of both data abstraction and procedural knowledge) is discussed in section 2.6.

One of the primary methods of representing knowledge in CLIPS is a rule. Rules are used to represent heuristics, or “rules of thumb”, which specify a set of actions to be performed for a given situation. The de­veloper of an expert system defines a set of rules which collectively work together to solve a problem. A rule is composed of an antecedent and a consequent. The antecedent of a rule is also referred to as the if portion or the left hand side (LHS) of the rule. The consequent of a rule is also referred to as the then portion or the right hand side (RHS) of the rule.

The antecedent of a rule is a set of conditions (or conditional elements) which must be satisfied for the rule to be applicable. In CLIPS, the conditions of a rule are satisfied based on the existence or non existence of specified facts in the fact list or specified instances of user defined classes in the instance list. One type of condition which can be specified is a pattern. Patterns consist of a set of restrictions which are used to determine which facts or objects satisfy the condition specified by the pattern. The process of matching facts and objects to patterns is called pattern matching. CLIPS provides a mechanism, called the inference engine, which automatically matches patterns against the current state of the fact list and instance list and determines which rules are applicable.

The consequent of a rule is the set of actions to be executed when the rule is applicable. The actions of applicable rules are executed when the CLIPS inference engine is instructed to begin execution of applicable rules. If more than one rule is applicable, the inference engine uses a conflict resolution strategy to select which rule should have its actions executed. The actions of the selected rule are executed (which may affect the list of applicable rules) and then the inference engine selects another rule and executes its actions. This process continues until no applicable rules remain.

In many ways, rules can be thought of as IF THEN statements found in procedural programming languages such as C and Ada. However, the conditions of an IF THEN statement in a procedural language are only evaluated when the program flow of control is directly at the IF THEN statement. In contrast, rules act like WHENEVER THEN statements. The inference engine always keeps track of rules which have their conditions satisfied and thus rules can immediately be executed when they are applicable. In this sense, rules are similar to exception handlers found in languages such as Ada.

CLIPS also supports a procedural paradigm for representing knowledge like that of more conventional languages, such as Pascal and C. Deffunctions and generic functions allow the user to define new executable elements to CLIPS that perform a useful side effect or return a useful value. These new functions can be called just like the built in functions of CLIPS. Message handlers allow the user to define the behavior of objects by specifying their response to messages. Deffunctions, generic functions and message handlers are all procedural pieces of code specified by the user that CLIPS executes interpretively at the appropriate times. Defmodules allow a knowledge base to be partitioned.

Deffunctions allow you to define new functions in CLIPS directly. In previous versions of CLIPS, the only way to have user defined functions was to write them in some external language, such as C or Ada, and then recompile and relink CLIPS with the new functions. The body of a deffunction is a series of expressions similar to the RHS of a rule that are executed in order by CLIPS when the deffunction is called. The return value of a deffunction is the value of the last expression evaluated within the deffunction. Calling a deffunction is identical to calling any other function in CLIPS. Deffunctions are covered comprehensively in Section 7.

Generic functions are similar to deffunctions in that they can be used to define new procedural code directly in CLIPS, and they can be called like any other function. However, generic functions are much more powerful because they can be overloaded. A generic function will do different things depending on the types (or classes) and number of its arguments. Generic functions are comprised of multiple components called methods, where each method handles different cases of arguments for the generic function. For example, you might overload the “+” operator to do string concatenation when it is passed strings as arguments. However, the “+” operator will still perform arithmetic addition when passed numbers. There are two methods in this example: an explicit one for strings defined by the user and an implicit one which is the standard CLIPS arithmetic addition operator. The return value of a generic function is the evaluation of the last expression in the method executed. Generic functions are covered comprehensively in Section 8.

Objects are described in two basic parts: properties and behavior. Object properties are specified in terms of slots obtained from the object’s class; slots are discussed in more detail in Section 2.4.2. Object behavior is specified in terms of procedural code called message handlers which are attached to the object’s class. Objects are manipulated via message passing. For example, to cause the Rolls Royce object, which is an instance of the class CAR, to start its engine, the user must call the send function to send the message “start engine” to the Rolls Royce. How the Rolls Royce responds to this message will be dictated by the execution of the message handlers for “start engine” attached to the CAR class and any of its superclasses. The result of a message is similar to a function call in CLIPS: a useful return value or side effect.

Further discussion on message handlers can be found in Section 2.6, and a comprehensive description of the CLIPS Object Oriented Language (COOL) can be found in Section 9.

Defmodules allow a knowledge based to be partitioned. Every construct defined must be placed in a module. The programmer can explicitly control which constructs in a module are visible to other modules and which constructs from other modules are visible to a module. The visibility of facts and instances between modules can be controlled in a similar manner. Modules can also be used to control the flow of execution of rules. Defmodules are covered comprehensively in Section 10.

This section gives a brief overview of the programming elements of the CLIPS Object Oriented Language (COOL). COOL includes elements of data abstraction and knowledge representation. This section gives an overview of COOL as a whole, incorporating the elements of both concepts. Object references are discussed in Section 2.3.1, and the structure of objects is discussed in Sections 2.4.2 and 2.5.2.3. The comprehensive details of COOL are given in Section 9.

In a pure OOP language, all programming elements are objects which can only be manipulated via messages. In CLIPS, the definition of an object is much more constrained: floating point and integer numbers, symbols, strings, multifield values, external addresses, fact addresses and instances of user defined classes. All objects may be manipulated with messages, except instances of user defined classes, which must be. For example, in a pure OOP system, to add two numbers together, you would send the message “add” to the first number object with the second number object as an argument. In CLIPS, you may simply call the “+” function with the two numbers as arguments, or you can define message handlers for the NUMBER class which allow you to do it in the purely OOP fashion.

All programming elements which are not objects must be manipulated in a non OOP utilizing function tailored for those programming elements. For example, to print a rule, you call the function ppdefrule; you do not send a message “print” to a rule, since it is not an object.

There are five primary characteristics that an OOP system must possess: abstraction, encapsulation, inheritance, polymorphism and dynamic binding. An abstraction is a higher level, more intuitive representation for a complex concept. Encapsulation is the process whereby the implementation details of an object are masked by a well defined external interface. Classes may be described in terms of other classes by use of inheritance. Polymorphism is the ability of different objects to respond to the same message in a specialized manner. Dynamic binding is the ability to defer the selection of which specific message handlers will be called for a message until run time.

The definitions of new classes allows the abstraction of new data types in COOL. The slots and message handlers of these classes describe the properties and behavior of a new group of objects.

COOL supports encapsulation by requiring message passing for the manipulation of instances of user defined classes. An instance cannot respond to a message for which it does not have a defined message handler.

COOL allows the user to specify some or all of the properties and behavior of a class in terms of one or more unrelated superclasses. This process is called multiple inheritance. COOL uses the existing hierarchy of classes to establish a linear ordering called the class precedence list for a new class. Objects which are instances of this new class can inherit properties (slots) and behavior (message handlers) from each of the classes in the class precedence list. The word precedence implies that properties and behavior of a class first in the list override conflicting definitions of a class later in the list.

One COOL object can respond to a message in a completely different way than another object; this is polymorphism. This is accomplished by attaching message handlers with differing actions but which have the same name to the classes of these two objects respectively.

Dynamic binding is supported in that an object reference (see section 2.3.1) in a send function call is not bound until run time. For example, an instance name or variable might refer to one object at the time a message is sent and another at a later time.

In addition to the ability of rules to directly pattern match on objects, COOL provides a useful query system for determining, grouping and performing actions on sets of instances of user defined classes that meet user defined criteria. The query system allows you to associate instances that are either related or not. You can simply use the query system to determine if a particular association set exists, you can save the set for future reference, or you can iterate an action over the set. An example of the use of the query system might be to find the set of all pairs of boys and girls that have the same age.

Ordered facts encode information positionally. To access that information, a user must know not only what data is stored in a fact but which field contains the data. Non ordered (or deftemplate) facts provide the user with the ability to abstract the structure of a fact by assign­ing names to each field found within the fact. The deftemplate construct is used to create a template which can then be used by non ordered facts to access fields of the fact by name. The deftemplate construct is analogous to a record or structure definition in programming languages such as Pascal and C.

The syntax of the deftemplate construct is:

Syntax

(deftemplate <deftemplate-name> [<comment>]

<slot-definition>*)

<slot-definition> ::= <single-slot-definition> |

<multislot-definition>

<single-slot-definition>

::= (slot <slot-name>

<template-attribute>*)

<multislot-definition>

::= (multislot <slot-name>

<template-attribute>*)

<template-attribute> ::= <default-attribute> |

<constraint-attribute>

<default-attribute>

::= (default ?DERIVE | ?NONE | <expression>*) |

(default-dynamic <expression>*)

Redefining a deftemplate will result in the previous definition being discarded. A deftemplate can not be redefined while it is being used (for example, by a fact or pattern in a rule). A deftemplate can have any number of single or multifeld slots. CLIPS always enforces the single and multifield definitions of the deftemplate. For example, it is an error to store (or match) multiple values in a single-field slot.

Example

(deftemplate object

(slot name)

(slot location)

(slot on-top-of)

(slot weight)

(multislot contents))

The <default attribute> specifies the value to be used for unspecified slots of a template fact when an assert action is performed. One of two types of default selections can be chosen: default or dynamic default.

The default attribute specifies a static default value. The specified expressions are evaluated once when the deftemplate is defined and the result is stored with the deftemplate. The result is assigned to the appropriate slot when a new template fact is asserted. If the keyword ?DERIVE is used for the default value, then a default value is derived from the constraints for the slot (see section 11.5 for more details). By default, the default attribute for a slot is (default ?DERIVE). If the keyword ?NONE is used for the default value, then a value must explicitly be assigned for a slot when an assert is performed. It is an error to assert a template fact without specifying the values for the (default ?NONE) slots.

The default dynamic attribute is a dynamic default. The specified expressions are evaluated every time a template facts is asserted, and the result is assigned to the appropriate slot.

A single field slot may only have a single value for its default. Any number of values may be specified as the default for a multifield slot (as long as the number of values satisfies the cardinality attribute for the slot).

Example

CLIPS> (clear)

CLIPS>

(deftemplate foo

(slot w (default ?NONE))

(slot x (default ?DERIVE))

(slot y (default (gensym*)))

(slot z (default-dynamic (gensym*))))

CLIPS> (assert (foo))

[TMPLTRHS1] Slot w requires a value because of its (default ?NONE) attribute.

CLIPS> (assert (foo (w 3)))

<Fact-0>

CLIPS> (assert (foo (w 4)))

<Fact-1>

CLIPS> (facts)

f-0 (foo (w 3) (x nil) (y gen1) (z gen2))

f-1 (foo (w 4) (x nil) (y gen1) (z gen3))

For a total of 2 facts.

CLIPS>

Single field slots that are not specified in a pattern on the LHS of a rule are defaulted to single field wildcards (?) and multifield slots are defaulted to multifield wildcards ($?).

The syntax and functionality of single and multifield constraint attributes are described in detail in Section 11. Static and dynamic constraint checking for deftemplates is supported. Static checking is performed when constructs or commands using deftemplates slots are being parsed (and the specific deftemplate associated with the construct or command can be immediately determined). Template patterns used on the LHS of a rule are also checked to determine if constraint conflicts exist among variables used in more that one slot. Errors for inappropriate values are immediately signaled. References to fact indexes made in commands such as modify and duplicate are considered to be ambiguous and are never checked using static checking. Static checking is enabled by default. This behavior can be changed using the set static constraint checking function. Dynamic checking is also supported. If dynamic checking is enabled, then new deftemplate facts have their values checked when added to the fact list. This dynamic checking is disabled by default. This behavior can be changed using the set dynamic constraint checking function. If an violation occurs when dynamic checking is being performed, then execution will be halted.

Example

(deftemplate object

(slot name

(type SYMBOL)

(default ?DERIVE))

(slot location

(type SYMBOL)

(default ?DERIVE))

(slot on-top-of

(type SYMBOL)

(default floor))

(slot weight

(allowed-values light heavy)

(default light))

(multislot contents

(type SYMBOL)

(default ?DERIVE)))

Asserting or referring to an ordered fact (such as in a LHS pattern) creates an “implied” deftemplate with a single implied multifield slot. The implied multifield slot’s name is not printed when the fact is printed. The implied deftemplate can be manipulated and examined identically to any user defined deftemplate (although it has no pretty print form).

Example

CLIPS> (clear)

CLIPS> (assert (foo 1 2 3))

<Fact-0>

CLIPS> (defrule yak (bar 4 5 6) ⇒)

CLIPS> (list-deftemplates)

initial-fact

foo

bar

For a total of 3 deftemplates.

CLIPS> (facts)

f-0 (foo 1 2 3)

For a total of 1 fact.

CLIPS>

With the deffacts construct, a list of facts can be defined which are automatically asserted whenever the reset command is performed. Facts as­serted through deffacts may be retracted or pattern matched like any other fact. The initial fact list, including any defined deffacts, is always reconstructed after a reset command.

Syntax

(deffacts <deffacts-name> [<comment>]
<RHS-pattern>*)

Redefining a currently existing deffacts causes the previous deffacts with the same name to be removed even if the new definition has errors in it. There may be multiple deffacts constructs and any number of facts (either ordered or deftemplate) may be asserted into the initial fact list by each deffacts construct.

Dynamic expressions may be included in a fact by embedding the expression directly within the fact. All such expressions are evaluated when CLIPS is reset.

Example

(deffacts startup “Refrigerator Status”
(refrigerator light on)
(refrigerator door open)

(refrigerator temp (get-temp)))

Upon startup and after a clear command, CLIPS automatically constructs the following deftemplate and deffacts.

(deftemplate initial-fact)

(deffacts initial-fact

(initial-fact))

This deffacts provides a convenient method for starting the execution of a system – Rules that are given no conditional element are automatically given a pattern which matches the (initial fact) fact. The initial fact deffacts can be treated identically as any other deffacts defined by the user.

One of the primary methods of representing knowledge in CLIPS is a rule. A rule is a collec­tion of conditions and the actions to be taken if the conditions are met. The developer of an expert system defines the rules which describe how to solve a problem. Rules execute (or fire) based on the existence or non existence of facts or instances of user defined classes. CLIPS provides the mechanism (the inference engine) which attempts to match the rules to the cur­rent state of the system (as represented by the fact list and instance list) and applies the actions.

Throughout this section, the term pattern entity will be used to refer to either a fact or an instance of a user defined class.

Rules are defined using the defrule construct.

Syntax

(defrule <rule-name> [<comment>]

[<declaration>] ; Rule Properties

<conditional-element>* ; Left-Hand Side (LHS)
⇒
<action>*) ; Right-Hand Side (RHS)

Redefining a currently existing defrule causes the previous defrule with the same name to be removed even if the new definition has errors in it. The LHS is made up of a series of conditional elements (CEs) which typically consist of pattern conditional elements (or just simply patterns) to be matched against pattern entities. An implicit and conditional element always surrounds all the patterns on the LHS. The RHS contains a list of actions to be per­formed when the LHS of the rule is sat­isfied. In addition, the LHS of a rule may also contain declarations about the rule’s properties immediately following the rule’s name and comment (see section 5.4.10 for more details). The arrow (⇒) separates the LHS from the RHS. There is no limit to the number of conditional elements or ac­tions a rule may have (other than the limitation placed by actual avail­able memory). Actions are performed sequentially if, and only if, all condi­tional elements on the LHS are satisfied.

If no conditional elements are on the LHS, the pattern CE (initial fact) or (initial object) is automatically used. If no ac­tions are on the RHS, the rule can be activated and fired but nothing will happen.

As rules are defined, they are incrementally reset. This means that CEs in newly defined rules can be satisfied by pattern entities at the time the rule is defined, in addition to pattern entities created after the rule is defined (see sections 13.1.8, 13.6.9, and 13.6.10 for more details).

Example

(defrule example-rule “This is an example of a simple rule”
(refrigerator light on)
(refrigerator door open)
⇒
(assert (refrigerator food spoiled)))

Once a knowledge base (in the form of rules) is built and the fact list and instance list is prepared, CLIPS is ready to execute rules. In a conventional language, the starting point, the stopping point, and the sequence of operations are defined explicitly by the program­mer. With CLIPS, the program flow does not need to be defined quite so explicitly. The knowledge (rules) and the data (facts and instances) are separated, and the inference engine pro­vided by CLIPS is used to apply the knowledge to the data. The basic execution cycle is as follows:

a) If the rule firing limit has been reached or there is no current focus, then execution is halted. Otherwise, the top rule on the agenda of the module which is the current focus is selected for execution. If there are no rules on that agenda, then the current focus is removed from the focus stack and the current focus becomes the next module on the focus stack. If the focus stack is empty, then execution is halted, otherwise step a is executed again. See sections 5.4.10.2, 10.6, 12.2, and 13.7 for information on the focus stack and the current focus.

b) The right hand side (RHS) actions of the selected rule are executed. The use of the return function on the RHS of a rule may remove the current focus from the focus stack (see sections 10.6 and 12.6.7). The number of rules fired is incremented for use with the rule firing limit.

c) As a result of step b, rules may be activated or deactivated. Activated rules (those rules whose conditions are currently satisfied) are placed on the agenda of the module in which they are defined. The placement on the agenda is determined by the salience of the rule and the current conflict resolution strategy (see sections 5.3, 5.4.10, 13.7.5, and 13.7.6). Deactivated rules are removed from the agenda. If the activations item is being watched (see section 13.2), then an informational message will be displayed each time a rule is activated or deactivated.

d) If dynamic salience is being used, the salience values for all rules on the agenda are reevaluated (see sections 5.4.10, 13.7.9, and 13.7.10). Repeat the cycle beginning with step a.

The agenda is the list of all rules which have their conditions satisfied (and have not yet been executed). Each module has its own agenda. The agenda acts similar to a stack (the top rule on the agenda is the first one to be executed). When a rule is newly activated, its placement on the agenda is based (in order) on the following factors:

a) Newly activated rules are placed above all rules of lower salience and below all rules of higher salience.

b) Among rules of equal salience, the current conflict resolution strategy is used to determine the placement among the other rules of equal salience.

c) If a rule is activated (along with several other rules) by the same assertion or retraction of a fact, and steps a and b are unable to specify an ordering, then the rule is arbitrarily (not randomly) ordered in relation to the other rules with which it was activated. Note, in this respect, the order in which rules are defined has an arbitrary effect on conflict resolution (which is highly dependent upon the current underlying implementation of rules). Do not depend upon this arbitrary ordering for the proper execution of your rules.

CLIPS provides seven conflict resolution strategies: depth, breadth, simplicity, complexity, lex, mea, and random. The default strategy is depth. The current strategy can be set by using the set strategy command (which will reorder the agenda based upon the new strategy).

Newly activated rules are placed above all rules of the same salience. For example, given that fact a activates rule 1 and rule 2 and fact b activates rule 3 and rule 4, then if fact a is asserted before fact b, rule 3 and rule 4 will be above rule 1 and rule 2 on the agenda. However, the position of rule 1 relative to rule 2 and rule 3 relative to rule 4 will be arbitrary.

Newly activated rules are placed below all rules of the same salience. For example, given that fact a activates rule 1 and rule 2 and fact b activates rule 3 and rule 4, then if fact a is asserted before fact b, rule 1 and rule 2 will be above rule 3 and rule 4 on the agenda. However, the position of rule 1 relative to rule 2 and rule 3 relative to rule 4 will be arbitrary.

Among rules of the same salience, newly activated rules are placed above all activations of rules with equal or higher specificity. The specificity of a rule is determined by the number of comparisons that must be performed on the LHS of the rule. Each comparison to a constant or previously bound variable adds one to the specificity. Each function call made on the LHS of a rule as part of the :, =, or test conditional element adds one to the specificity. The boolean functions and, or, and not do not add to the specificity of a rule, but their arguments do. Function calls made within a function call do not add to the specificity of a rule. For example, the following rule

(defrule example

(item ?x ?y ?x)

(test (and (numberp ?x) (> ?x (+ 10 ?y)) (< ?x 100)))

⇒)

has a specificity of 5. The comparison to the constant item, the comparison of ?x to its previous binding, and the calls to the numberp, <, and > functions each add one to the specificity for a total of 5. The calls to the and and + functions do not add to the specificity of the rule.

Among rules of the same salience, newly activated rules are placed above all activations of rules with equal or lower specificity.

Among rules of the same salience, newly activated rules are placed using the OPS5 strategy of the same name. First the recency of the pattern entities that activated the rule is used to determine where to place the activation. Every fact and instance is marked internally with a “time tag” to indicate its relative recency with respect to every other fact and instance in the system. The pattern entities associated with each rule activation are sorted in descending order for determining placement. An activation with a more recent pattern entities is placed before activations with less recent pattern entities. To determine the placement order of two activations, compare the sorted time tags of the two activations one by one starting with the largest time tags. The comparison should continue until one activation’s time tag is greater than the other activation’s corresponding time tag. The activation with the greater time tag is placed before the other activation on the agenda.

If one activation has more pattern entities than the other activation and the compared time tags are all identical, then the activation with more time tags is placed before the other activation on the agenda. If two activations have the exact same recency, the activation with the higher specificity is placed above the activation with the lower specificity. Unlike OPS5, the not conditional elements in CLIPS have pseudo time tags which are used by the LEX conflict resolution strategy. The time tag of a not CE is always less than the time tag of a pattern entity, but greater than the time tag of a not CE that was instantiated after the not CE in question.

As an example, the following six activations have been listed in their LEX ordering (where the comma at the end of the activation indicates the presence of a not CE). Note that a fact’s time tag is not necessarily the same as it’s index (since instances are also assigned time tags), but if one fact’s index is greater than another facts’s index, then it’s time tag is also greater. For this example, assume that the time tags and indices are the same.

rule-6: f-1,f-4

rule-5: f-1,f-2,f-3,

rule-1: f-1,f-2,f-3

rule-2: f-3,f-1

rule-4: f-1,f-2,

rule-3: f-2,f-1

Shown following are the same activations with the fact indices sorted as they would be by the LEX strategy for comparison.

rule-6: f-4,f-1

rule-5: f-3,f-2,f-1,

rule-1: f-3,f-2,f-1

rule-2: f-3,f-1

rule-4: f-2,f-1,

rule-3: f-2,f-1

Among rules of the same salience, newly activated rules are placed using the OPS5 strategy of the same name. First the time tag of the pattern entity associated with the first pattern is used to determine where to place the activation. An activation thats first pattern’s time tag is greater than another activations first pattern’s time tag is placed before the other activation on the agenda. If both activations have the same time tag associated with the first pattern, then the LEX strategy is used to determine placement of the activation. Again, as with the CLIPS LEX strategy, negated patterns have pseudo time tags.

As an example, the following six activations have been listed in their MEA ordering (where the comma at the end of the activation indicates the presence of a negated pattern).

rule-2: f-3,f-1

rule-3: f-2,f-1

rule-6: f-1,f-4

rule-5: f-1,f-2,f-3,

rule-1: f-1,f-2,f-3

rule-4: f-1,f-2,

Each activation is assigned a random number which is used to determine its placement among activations of equal salience. This random number is preserved when the strategy is changed so that the same ordering is reproduced when the random strategy is selected again (among activations that were on the agenda when the strategy was originally changed).

This section describes the syntax used on the LHS of a rule. The LHS of a CLIPS rule is made up of a series of conditional elements (CEs) that must be satisfied for the rule to be placed on the agenda. There are eight types of conditional elements: pattern CEs, test CEs, and CEs, or CEs, not CEs, exists CEs, forall CEs, and logical CEs. The pattern CE is the most basic and commonly used conditional element. Pattern CEs contain constraints which are used to determine if any pattern entities (facts or instances) satisfy the pattern. The test CE is used to evaluate expressions as part of the pattern matching process. The and CE is used to specify that an entire group of CEs must all be satisfied. The or CE is used to specify that only one of a group of CEs must be satisfied. The not CE is used to specify that a CE must not be satisfied. The exists CE is used to test for the occurence of at least one partial match for a set of CEs. The forall CE is used to test that a set of CEs is satisfied for every partial match of a specified CE. Finally, the logical CE allows assertions of facts and the creation of instances on the RHS of a rule to be logically dependent upon pattern entities matching patterns on the LHS of a rule (truth maintenance).

Syntax

<conditional-element> ::= <pattern-CE> |

<assigned-pattern-CE> |

<not-CE> |

<and-CE> |

<or-CE> |

<logical-CE> |

<test-CE> |

<exists-CE> |

<forall-CE>

Pattern conditional elements consist of a collection of field constraints, wildcards, and variables which are used to constrain the set of facts or instances which match the pattern CE. A pattern CE is satisfied by each and every pattern entity that satisfies its constraints. Field constraints are a set of constraints that are used to test a single field or slot of a pattern entity. A field constraint may consist of only a single literal constraint:literal;, however, it may also consist of several constraints connected together. In addition to literal constraints, CLIPS provides three other types of constraints: connective constraints, predicate constraints, and return value constraints. Wildcards are used within pattern CEs to indicate that a single field or group of fields can be matched by anything. Variables are used to store the value of a field so that it can be used later on the LHS of a rule in other conditional elements or on the RHS of a rule as an argument to an action.

The first field of any pattern must be a symbol and can not use any other constraints. This first field is used by CLIPS to determine if the pattern applies to an ordered fact, a template fact, or an instance. The symbol object is reserved to indicate an object pattern. Any other symbol used must correspond to a deftemplate name (or an implied deftemplate will be created). Slot names must also be symbols and cannot contain any other constraints.

For object and deftemplate patterns, a single field slot can only contain one field constraint and that field constraint must only be able to match a single field (no multifield wildcards or variables). A multifield slot can contain any number of field constraints.

The examples and syntax shown in the following sections will be for ordered and deftemplate fact patterns. Section 5.4.1.7 will discuss differences between deftemplate patterns and object patterns. The following constructs are used by the examples.

(deffacts data-facts

(data 1.0 blue “red”)

(data 1 blue)

(data 1 blue red)

(data 1 blue RED)

(data 1 blue red 6.9))

(deftemplate person

(slot name)

(slot age)

(multislot friends))

(deffacts people

(person (name Joe) (age 20))

(person (name Bob) (age 20))

(person (name Joe) (age 34))

(person (name Sue) (age 34))

(person (name Sue) (age 20)))

The most basic constraint which can be used in a pattern CE is one which precisely defines the exact value that will match a field. This is called a literal constraint. A literal pattern CE consists entirely of constants such as floats, integers, symbols, strings, and instance names. It does not contain any variables or wildcards. All constraints in a literal pattern must be matched exactly by all fields of a pattern entity.

Syntax

An ordered pattern conditional element containing only literals has the following basic syntax:

(<constant-1> … <constant-n>)

A deftemplate pattern conditional element containing only literals has the following basic syntax:

(<deftemplate-name> (<slot-name-1> <constant-1>)
•
•
•
(<slot-name-n> <constant-n>))

Example 1

This example utilizes the data facts deffacts shown in section 5.4.1.

CLIPS> (clear)

CLIPS> (defrule find-data (data 1 blue red) ⇒)

CLIPS> (reset)

CLIPS> (agenda)

0 find-data: f-3

For a total of 1 activation.

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data 1.0 blue “red”)

f-2 (data 1 blue)

f-3 (data 1 blue red)

f-4 (data 1 blue RED)

f-5 (data 1 blue red 6.9)

For a total of 6 facts.

CLIPS>

Example 2

This example utilizes the person deftemplate and people deffacts shown in section 5.4.1.

CLIPS> (clear)

CLIPS>

(defrule Find-Bob

(person (name Bob) (age 20))

⇒)

CLIPS>

(defrule Find-Sue

(person (age 34) (name Sue))

⇒)

CLIPS> (reset)

CLIPS> (agenda)

0 Find-Sue: f-4

0 Find-Bob: f-2

For a total of 2 activations.

CLIPS> (facts)

f-0 (initial-fact)

f-1 (person (name Joe) (age 20) (friends))

f-2 (person (name Bob) (age 20) (friends))

f-3 (person (name Joe) (age 34) (friends))

f-4 (person (name Sue) (age 34) (friends))

f-5 (person (name Sue) (age 20) (friends))

For a total of 6 facts.

CLIPS>

CLIPS has two wildcard symbols that may be used to match fields in a pat­tern. CLIPS in­terprets these wildcard symbols as standing in place of some part of a pattern entity. The single field wild­card, denoted by a question mark character (?), matches any value stored in exactly one field in the pattern entity. The multifield wildcard, denoted by a dollar sign followed by a question mark ($?), matches any value in zero or more fields in a pattern entity. Single field and multifield wildcards may be combined in a single pattern in any combination. It is illegal to use a multifield wildcard in a single field slot of a deftemplate or object pattern. By default, an unspecified single field slot in a deftemplate/object pattern is matched against an implied single field wildcard. Similarly, an unspecified multifield slot in a deftemplate/object pattern is matched against an implied multifield wildcard.

Syntax

An ordered pattern conditional element containing only literals and wildcards has the following basic syntax:

(<constraint-1> … <constraint-n>)

where

<constraint> ::= <constant> | ? | $?

A deftemplate pattern conditional element containing only literals and wildcards has the following basic syntax:

(<deftemplate-name> (<slot-name-1> <constraint-1>)
•
•
•
(<slot-name-n> <constraint-n>))

Example 1

This example utilizes the data facts deffacts shown in section 5.4.1.

CLIPS> (clear)

CLIPS>

(defrule find-data

(data ? blue red $?)

⇒)

CLIPS> (reset)

CLIPS> (agenda)

0 find-data: f-5

0 find-data: f-3

For a total of 2 activations.

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data 1.0 blue “red”)

f-2 (data 1 blue)

f-3 (data 1 blue red)

f-4 (data 1 blue RED)

f-5 (data 1 blue red 6.9)

For a total of 6 facts.

CLIPS>

Example 2

This example utilizes the person deftemplate and people deffacts shown in section 5.4.1.

CLIPS> (clear)

CLIPS>

(defrule match-all-persons

(person)

⇒)

CLIPS> (reset)

CLIPS> (agenda)

0 match-all-persons: f-5

0 match-all-persons: f-4

0 match-all-persons: f-3

0 match-all-persons: f-2

0 match-all-persons: f-1

For a total of 5 activations.

CLIPS> (facts)

f-0 (initial-fact)

f-1 (person (name Joe) (age 20) (friends))

f-2 (person (name Bob) (age 20) (friends))

f-3 (person (name Joe) (age 34) (friends))

f-4 (person (name Sue) (age 34) (friends))

f-5 (person (name Sue) (age 20) (friends))

For a total of 6 facts.

CLIPS>

Multifield wildcard and literal constraints can be combined to yield some powerful pattern matching capabilities. A pattern to match all of the facts that have the symbol YELLOW in any field (other than the first) could be written as

(data $? YELLOW $?)

Some examples of what this pattern would match are

(data YELLOW blue red green)

(data YELLOW red)

(data red YELLOW)

(data YELLOW)

(data YELLOW data YELLOW)

The last fact will match twice since YELLOW appears twice in the fact. The use of multifield wildcards should be confined to cases of patterns in which the single field wildcard cannot create a pattern that satisfies the match required, since the multifield wildcard produces every possible match combination that can be derived from a pattern entity. This derivation of matches requires a significant amount of time to perform when compared to the time needed to perform a single field match.

Wildcard symbols replace portions of a pattern and accept any value. The value of the field being replaced may be captured in a variable for comparison, display, or other manipulations. This is done by directly following the wildcard symbol with a variable name.

Syntax

Expanding on the syntax definition given in section 5.4.1.2 now gives:

<constraint> ::= <constant> | ? | $? |

<single-field-variable> |

<multifield-variable>

<single-field-variable> ::= ?<variable-symbol>

<multifield-variable> ::= $?<variable-symbol>

where <variable symbol> is similar to a symbol, except that it must start with an alphabetic char­acter. Double quotes are not allowed as part of a variable name; i.e. a string cannot be used for a variable name. The rules for pattern matching are similar to those for wildcard symbols. On its first appearance, a variable acts just like a wildcard in that it will bind to any value in the field(s). However, later appearances of the variable require the field(s) to match the binding of the variable. The binding will only be true within the scope of the rule in which it occurs. Each rule has a private list of variable names with their associated values; thus, variables are local to a rule. Bound vari­ables can be passed to external functions. The $ operator has special significance on the LHS as a pattern matching operator to indicate that zero or more fields need to be matched. In other places (such as the RHS of a rule), the $ in front of a variable indicates that sequence expansion should take place before calling the function. Thus, when passed as parameters in function calls (either on the LHS or RHS of a rule), multifield variables should not be preceded by the $ (unless sequence expansion is desired). All other uses of a multifield variable on the LHS of a rule, however, should use the $. It is illegal to use a multifield variable in a single field slot of a deftemplate/object pattern.

Example 1

CLIPS> (clear)

CLIPS> (reset)

CLIPS> (assert (data 2 blue green)

(data 1 blue)

(data 1 blue red))

<Fact-3>

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data 2 blue green)

f-2 (data 1 blue)

f-3 (data 1 blue red)

For a total of 4 facts.

CLIPS>

(defrule find-data-1

(data ?x ?y ?z)

⇒

(printout t ?x ” : “ ?y ” : “ ?z crlf))

CLIPS> (run)

1 : blue : red

2 : blue : green

CLIPS>

Example 2

CLIPS> (reset)

CLIPS> (assert (data 1 blue)

(data 1 blue red)

(data 1 blue red 6.9))

<Fact-3>

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data 1 blue)

f-2 (data 1 blue red)

f-3 (data 1 blue red 6.9)

For a total of 4 facts.

CLIPS>

(defrule find-data-1

(data ?x $?y ?z)

⇒

(printout t ”?x = “ ?x crlf

”?y = “ ?y crlf

”?z = “ ?z crlf

”——“ crlf))

CLIPS> (run)

?x = 1

?y = (blue red)

?z = 6.9

------

?x = 1

?y = (blue)

?z = red

------

?x = 1

?y = ()

?z = blue

------

CLIPS>

Once the initial binding of a variable occurs, all references to that variable have to match the value that the first binding matched. This applies to both single  and multi­field variables. It also applies across patterns.

Example 3

CLIPS> (clear)

CLIPS>

(deffacts data

(data red green)

(data purple blue)

(data purple green)

(data red blue green)

(data purple blue green)

(data purple blue brown))

CLIPS>

(defrule find-data-1

(data red ?x)

(data purple ?x)

⇒)

CLIPS>

(defrule find-data-2

(data red $?x)

(data purple $?x)

⇒)

CLIPS> (reset)

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data red green)

f-2 (data purple blue)

f-3 (data purple green)

f-4 (data red blue green)

f-5 (data purple blue green)

f-6 (data purple blue brown)

For a total of 7 facts.

CLIPS> (agenda)

0 find-data-2: f-4,f-5

0 find-data-1: f-1,f-3

0 find-data-2: f-1,f-3

For a total of 3 activations.

CLIPS>

Three connective constraints are available for connecting individual constraints and variables to each other. These are the & (and), | (or), and ~ (not) connective constraints. The & constraint is satisfied if the two adjoining constraints are satisfied. The | constraint is satisfied if either of the two adjoining constraints is satisfied. The ~ constraint is satisfied if the following constraint is not satisfied. The connective constraints can be com­bined in almost any manner or number to constrain the value of specific fields while pattern matching. The ~ constraint has highest precedence, followed by the & constraint, followed by the | constraint. Otherwise, evaluation of multiple constraints can be considered to occur from left to right. There is one exception to the precedence rules which applies to the binding occurrence of a variable. If the first constraint is a variable followed by an & connective constraint, then the first constraint is treated as a separate constraint which also must be satisified. Thus the constraint ?x&red|blue is treated like ?x&(red|blue) rather than (?x&red)|blue as the normal precedence rules would indicate.

Basic Syntax

Connective constraints have the following basic syntax:

<term-1>&<term-2> … &<term-3>

<term-1>|<term-2> … |<term-3>

~<term>

where <term> could be a single field variable, multifield variable, constant, or connected constraint.

Syntax

Expanding on the syntax definition given in section 5.4.1.3 now gives:

<constraint> ::= ? | $? | <connected-constraint>

<connected-constraint>

::= <single-constraint> |

<single-constraint> & <connected-constraint> |

<single-constraint> | <connected-constraint>

<single-constraint> ::= <term> | ~<term>

<term> ::= <constant> |

<single-field-variable> |

<multifield-variable>

The &constraint typically is used only in conjunction with other constraints or variable bindings. Notice that connective constraints may be used together and/or with variable bindings. If the first term of a connective constraint is the first occurrence of a variable name, then the field will be constrained only by the remaining field constraints. The variable will be bound to the value of the field. If the variable has been bound previously, it is considered an additional con­straint along with the remaining field constraints; i.e., the field must have the same value already bound to the variable and must satisfy the field constraints.

Example 1

CLIPS> (clear)

CLIPS> (deftemplate data-B (slot value))

CLIPS>

(deffacts AB

(data-A green)

(data-A blue)

(data-B (value red))

(data-B (value blue)))

CLIPS>

(defrule example1-1

(data-A ~blue)

⇒)

CLIPS>

(defrule example1-2

(data-B (value ~red&~green))

⇒)

CLIPS>

(defrule example1-3

(data-B (value green|red))

⇒)

CLIPS> (reset)

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data-A green)

f-2 (data-A blue)

f-3 (data-B (value red))

f-4 (data-B (value blue))

For a total of 5 facts.

CLIPS> (agenda)

0 example1-2: f-4

0 example1-3: f-3

0 example1-1: f-1

For a total of 3 activations.

CLIPS>

Example 2

CLIPS> (clear)

CLIPS> (deftemplate data-B (slot value))

CLIPS>

(deffacts B

(data-B (value red))

(data-B (value blue)))

CLIPS>

(defrule example2-1

(data-B (value ?x&~red&~green))

⇒

(printout t ”?x in example2-1 = “ ?x crlf))

CLIPS>

(defrule example2-2

(data-B (value ?x&green|red))

⇒

(printout t ”?x in example2-2 = “ ?x crlf))

CLIPS> (reset)

CLIPS> (run)

?x in example2-1 = blue

?x in example2-2 = red

CLIPS>

Example 3

CLIPS> (clear)

CLIPS> (deftemplate data-B (slot value))

CLIPS>

(deffacts AB

(data-A green)

(data-A blue)

(data-B (value red))

(data-B (value blue)))

CLIPS>

(defrule example3-1

(data-A ?x&~green)

(data-B (value ?y&~?x))

⇒)

CLIPS>

(defrule example3-2

(data-A ?x)

(data-B (value ?x&green|blue))

⇒)

CLIPS>

(defrule example3-3

(data-A ?x)

(data-B (value ?y&blue|?x))

⇒)

CLIPS> (reset)

CLIPS> (facts)

f-0 (initial-fact)

f-1 (data-A green)

f-2 (data-A blue)

f-3 (data-B (value red))

f-4 (data-B (value blue))

For a total of 5 facts.

CLIPS> (agenda)

0 example3-3: f-1,f-4

0 example3-3: f-2,f-4

0 example3-2: f-2,f-4

0 example3-1: f-2,f-3

For a total of 4 activations.

CLIPS>

Sometimes it becomes necessary to constrain a field based upon the truth of a given boolean expression. CLIPS allows the use of a predicate constraint to restrict a field in this manner. The predicate constraint allows a predicate function (one returning the symbol FALSE for unsatisfied and a non FALSE value for satisfied) to be called during the pattern matching process. If the predicate function returns a non FALSE value, the constraint is satisfied. If the predicate function returns the symbol FALSE, the constraint is not satisfied. A predicate constraint is invoked by following a colon with an appropriate function call to a predicate function. Typically, predicate constraints are used in conjunction with a connective constraint and a variable binding (i.e. you have to bind the variable to be tested and then connect it to the predicate constraint).

Basic Syntax

:<function-call>

Syntax

Expanding on the syntax definition given in section 5.4.1.4 now gives:

<term> ::= <constant> |

<single-field-variable> |

<multifield-variable> |

:<function-call>

Multiple predicate constraints may be used to constrain a single field. Several predicate functions are provided by CLIPS (see section 12.2). Users also may develop their own predicate functions.

Example 1

CLIPS> (clear)

CLIPS>

(defrule example-1

(data ?x&:(numberp ?x))

⇒)

CLIPS> (assert (data 1) (data 2) (data red))

<Fact-2>

CLIPS> (agenda)

0 example-1: f-1

0 example-1: f-0

For a total of 2 activations.

CLIPS>

Example 2

CLIPS> (clear)

CLIPS>

(defrule example-2

(data ?x&~:(symbolp ?x))

⇒)

CLIPS> (assert (data 1) (data 2) (data red))

<Fact-2>

CLIPS> (agenda)

0 example-2: f-1

0 example-2: f-0

For a total of 2 activations.

CLIPS>

Example 3

CLIPS> (clear)

CLIPS>

(defrule example-3

(data ?x&:(numberp ?x)&:(oddp ?x))

⇒)

CLIPS> (assert (data 1) (data 2) (data red))

<Fact-2>

CLIPS> (agenda)

0 example-3: f-0

For a total of 1 activation.

CLIPS>

Example 4

CLIPS> (clear)

CLIPS>

(defrule example-4

(data ?y)

(data ?x&:(> ?x ?y))

⇒)

CLIPS> (assert (data 3) ; f-0

(data 5) ; f-1

(data 9)) ; f-2

<Fact-2>

CLIPS> (agenda)

0 example-4: f-0,f-2

0 example-4: f-1,f-2

0 example-4: f-0,f-1

For a total of 3 activations.

CLIPS>

Example 5

CLIPS> (clear)

CLIPS>

(defrule example-5

(data $?x&:(> (length$ ?x) 2))

⇒)

CLIPS> (assert (data 1) ; f-0

(data 1 2) ; f-1

(data 1 2 3)) ; f-2

<Fact-2>

CLIPS> (agenda)

0 example-5: f-2

For a total of 1 activation.

CLIPS>

It is possible to use the return value of an external function to constrain the value of a field. The return value constraint ( allows the user to call external functions from inside a pat­tern. (This constraint is different from the com­parison function which uses the same symbol. The difference can be determined from context.) The return value must be one of the primitive data types. This value is incorporated directly into the pattern at the position at which the function was called as if it were a literal constraint, and any matching pat­terns must match this value as though the rule were typed with that value. Note that the function is evaluated each time the constraint is checked (not just once).

Basic Syntax

=<function-call>

Syntax

Expanding on the syntax definition given in section 5.4.1.5 now gives:

<term> ::= <constant> |

<single-field-variable> |

<multifield-variable> |

:<function-call> |

=<function-call>

Example 1

CLIPS> (clear)

CLIPS> (deftemplate data (slot x) (slot y))

CLIPS>

(defrule twice

(data (x ?x) (y =(* 2 ?x)))

⇒)

CLIPS> (assert (data (x 2) (y 4)) ; f-0

(data (x 3) (y 9))) ; f-1

<Fact-1>

CLIPS> (agenda)

0 twice: f-0

For a total of 1 activation.

CLIPS>

Example 2

CLIPS> (clear)

CLIPS>

(defclass DATA (is-a USER)

(role concrete) (pattern-match reactive)

(slot x (create-accessor write)))

CLIPS>

(defrule return-value-example-2

(object (is-a DATA)

(x ?x1))

(object (is-a DATA)

(x ?x2&=(+ 5 ?x1)|=(- 12 ?x1)))

⇒)

CLIPS> (make-instance of DATA (x 4))

[gen1]

CLIPS> (make-instance of DATA (x 9))

[gen2]

CLIPS> (make-instance of DATA (x 3))

[gen3]

CLIPS> (agenda)

0 return-value-example-2: [gen3],[gen2]

0 return-value-example-2: [gen2],[gen3]

0 return-value-example-2: [gen1],[gen2]

For a total of 3 activations.

CLIPS>

Instances of user defined classes in COOL can be pattern matched on the left hand side of rules. Patterns can only match objects for which the object’s most specific class is defined before the pattern and which are in scope for the current module. Any classes which could have objects which match the pattern cannot be deleted or changed until the pattern is deleted. Even if a rule is deleted by its RHS, the classes bound to its patterns cannot be changed until after the RHS finishes executing.

When an instance is created or deleted, all patterns applicable to that object are updated. However, when a slot is changed, only those patterns which explicitly match on that slot are affected. Thus, one could use logical dependencies to hook to a change to a particular slot (rather than a change to any slot, which is all that is possible with deftemplates).

Changes to non reactive slots or instances of non reactive classes (see sections 9.3.2.2 and 9.3.3.7) will have no effect on rules. Also Rete network activity will not be immediately apparent after changes to slots are made if pattern matching is being delayed through the use of the make instance, i.initialize instance;, i.modify instance;, i.message modify instance;, i.duplicate instance;, i.message duplicate instance; or object pattern match delay functions.

Syntax

<object-pattern> ::= (object <attribute-constraint>*)

<attribute-constraint> ::= (is-a <constraint>) |

(name <constraint>) |

(<slot-name> <constraint>*)

The is a constraint is used for specifying class constraints such as “Is this object a member of class FOO?”. The is a constraint also encompasses subclasses of the matching classes unless specifically excluded by the pattern. The name constraint is used for specifying a specific instance on which to pattern match. The evaluation of the name constraint must be of primitive type instance name, not symbol. Multifield constraints (such as $?) cannot be used with the is a or name constraints. Other than these special cases, constraints used in object slots work similarly to constraints used in deftemplate slots. As with deftemplate patterns, slot names for object patterns must be symbols and can not contain any other constraints.

Example 1

The following rules illustrate pattern matching on an object's class.

(defrule class-match-1

(object)

⇒)

(defrule class-match-2

(object (is-a FOO))

⇒)

(defrule class-match-3

(object (is-a FOO | BAR))

⇒)

(defrule class-match-4

(object (is-a ?x))

(object (is-a ~?x))

⇒)

Rule class match 1 is satisified by all instances of any reactive class. Rule class match 2 is satisfied by all instances of class FOO. Rule class match 3 is satisfied by all instances of class FOO or BAR. Rule class match 4 will be satisfied by any two instances of mutually exclusive classes.

Example 2

The following rules illustrate pattern matching on various attributes of an object's slots.

(defrule slot-match-1

(object (width))

⇒)

(defrule slot-match-2

(object (width ?))

⇒)

(defrule slot-match-3

(object (width $?))

⇒)

Rule slot match 1 is satisfied by all instances of reactive classes that contain a reactive width slot with a zero length multifield value. Rule slot match 2 is satisfied by all instances of reactive classes that contain a reactive single or multifield width slot that is bound to a single value. Rule slot match 3 is satisfied by all instances of reactive classes that contain a reactive single or multifield width slot that is bound to any number of values. Note that a slot containing a zero length multifield value would satisfy rules slot match 1 and slot match 3, but not rule slot match 2 (because the value's cardinality is zero).

Example 3

The following rules illustrate pattern matching on the slot values of an object.

(defrule value-match-1

(object (width 10)

⇒)

(defrule value-match-2

(object (width ?x&:(> ?x 20)))

⇒)

(defrule value-match-3

(object (width ?x) (height ?x))

⇒)

Rule value match 1 is satisified by all instances of reactive classes that contain a reactive width slot with value 10. Rule value match 2 is satisfied by all instances of reactive classes that contain a reactive width slot that has a value greater than 20. Rule value match 3 is satisfied by all instances of reactive classes that contain a reactive width and height slots with the same value.

Certain RHS actions, such as retract and unmake instance, operate on an entire pattern CE. To signify which fact or instance they are to act upon, a variable can be bound to the fact address or instance address of a pattern CE. Collectively, fact addresses and instance addresses bound on the LHS of a rule are referred to as pattern addresses.

Syntax

<assigned-pattern-CE> ::= ?<variable-symbol> ← <pattern-CE>

The left arrow, < , is a required part of the syntax. A variable bound to a fact address or instance address can be compared to other variables or passed to external functions. Variables bound to a fact or instance address may later be used to constrain fields within a pattern CE, however, the reverse is not allowed. It is an error to bind a varible to a not CE.

Examples

(defrule dummy

(data 1)

?fact ← (dummy pattern)

⇒

(retract ?fact))

(defrule compare-facts-1

?f1 ← (color ~red)

?f2 ← (color ~green)

(test (neq ?f1 ?f2))

⇒

(printout t “Rule fires from different facts” crlf))

(defrule compare-facts-2

?f1 ← (color ~red)

?f2 ← (color ~green&:(neq ?f1 ?f2))

⇒

(printout t “Rule fires from different facts” crlf))

(defrule print-and-delete-all-objects

?ins ← (object)

⇒

(send ?ins print)

(unmake-instance ?ins))

Field constraints used within pattern CEs allow very descriptive constraints to be applied to pattern matching. Additional capability is provided with the test conditional element. The test CE is satisfied if the function call within the test CE evaluates to a non FALSE value and unsatisfied if the function call evaluates to FALSE. As with predicate constraints, the user can compare the variable bindings that already have oc­curred in any manner. Mathematical comparisons on variables (e.g., is the differ­ence between ?x and ?y greater than some value?) and complex logical or equality comparisons can be done. External functions also can be called which compare vari­ables in any way that the user desires.

Any kind of external function may be embedded within a test conditional element (or within field constraints). User defined predicate functions must take arguments as defined in the Advanced Programming Guide. Sev­eral predicate functions are provided by CLIPS (see section 12.1).

Syntax

<test-CE> ::= (test <function-call>)

Since the symbol test is used to indicate this type of conditional element, rules may not use the symbol test as the first field in a pattern CE. A test CE is evaluated when all proceeding CEs are satisfied. This means that a test CE will be evaluated more than once if the proceeding CEs can be satisfied by more than one group of pattern entities. In order to cause the reevaluation of a test CE, a pattern entity matching a CE prior to the test CE must be changed. The use of test CEs can cause additional CEs to be added to the rule. In addition, test CEs may also be automatically reordered by CLIPS. See section 5.4.9 for more details.

Example 1

This example checks to see if the difference between two numbers is greater than or equal to three:

CLIPS> (clear)

CLIPS>

(defrule example-1

(data ?x)

(value ?y)

(test (>= (abs (- ?y ?x)) 3))

⇒)

CLIPS> (assert (data 6) (value 9))

<Fact-1>

CLIPS> (agenda)

0 example-1: f-0,f-1

For a total of 1 activation.

CLIPS>

Example 2

This example checks to see if there is a positive slope between two points on a line.

CLIPS> (clear)

CLIPS>

(deffunction positive-slope

(?x1 ?y1 ?x2 ?y2)

(< 0 (/ (- ?y2 ?y1) (- ?x2 ?x1))))

CLIPS>

(defrule example-2

(point ?a ?x1 ?y1)

(point ?b ?x2 ?y2)

(test (> ?b ?a))

(test (positive-slope ?x1 ?y1 ?x2 ?y2))

⇒)

CLIPS>

(assert (point 1 4.0 7.0) (point 2 5.0 9.0))

<Fact-1>

CLIPS> (agenda)

0 example-2: f-0,f-1

For a total of 1 activation.

CLIPS>

Important Note

Because the test CE can cause the addition of the initial fact fact pattern or the initial object instance pattern to a rule, a reset command (which creates the initial fact fact and the initial object instance) must be issued for the correct operation of the test CE under all circumstances.

The or conditional element allows any one of several conditional elements to activate a rule. If any of the conditional elements inside of the or CE is satisfied, then the or CE is satisfied. If all other LHS condi­tional elements are satisfied, the rule will be activated. Note that a rule will be activated for each conditional element with an or CE that is satisfied (assuming the other conditional elements of the rule are also satisfied). Any number of conditional elements may appear within an or CE. The or CE produces the identical effect of writing several rules with sim­ilar LHS’s and RHS’s.

Syntax

<or-CE> ::= (or <conditional-element>+)

Again, if more than one of the conditional elements in the or CE can be met, the rule will fire multiple times, once for each satisfied combination of conditions.

Example

(defrule system-fault
(error-status unknown)
(or (temp high)
(valve broken)

(pump (status off)))
⇒
(printout t “The system has a fault.” crlf))

Note that the above example is exactly equivalent to the following three (separate) rules:

(defrule system-fault
(error-status unknown)
(pump (status off))
⇒
(printout t “The system has a fault.” crlf))

(defrule system-fault
(error-status unknown)
(valve broken)
⇒
(printout t “The system has a fault.” crlf))

(defrule system-fault
(error-status unknown)
(temp high)
⇒
(printout t “The system has a fault.” crlf))

CLIPS assumes that all rules have an implicit and conditional element surrounding the conditional elements on the LHS. This means that all conditional elements on the LHS must be satisfied before the rule can be activated. An explicit and conditional element is provided to allow the mixing of and CEs and or CEs. This allows other types of conditional elements to be grouped together within or and not CEs. The and CE is satisfied if all of the CEs inside of the explicit and CE are satisfied. If all other LHS condi­tions are true, the rule will be activated. Any number of conditional elements may be placed within an and CE.

Syntax

<and-CE> ::= (and <conditional-element>+)

Example

(defrule system-flow
(error-status confirmed)
(or (and (temp high)
(valve closed))
(and (temp low)
(valve open)))
⇒
(printout t “The system is having a flow problem.” crlf))

An and CE that has a test or not CE as its first CE has the pattern (initial fact) or (initial object) added as the first CE. Note that the LHS of any rule is enclosed within an implied and CE. For example, the following rule

(defrule nothing-to-schedule

(not (schedule ?))

⇒

(printout t “Nothing to schedule.” crlf))

is converted to

(defrule nothing-to-schedule

(and (initial-fact)

(not (schedule ?)))

⇒

(printout t “Nothing to schedule.” crlf))

Sometimes the lack of information is meaningful; i.e., one wishes to fire a rule if a pattern entity or other CE does not exist. The not conditional element provides this capability. The not CE is satisfied only if the conditional element contained within it is not satisfied. As with other conditional elements, any number of additional CEs may be on the LHS of the rule and field con­straints may be used within the negated pattern.

Syntax

<not-CE> ::= (not <conditional-element>)

Only one CE may be negated at a time. Multiple patterns may be negated by using multiple not CEs. Care must be taken when combining not CEs with or and and CEs; the results are not always obvi­ous! The same holds true for variable bindings within a not CE. Previously bound variables may be used freely inside of a not CE. However, variables bound for the first time within a not CE can be used only in that pattern.

Examples

(defrule high-flow-rate
(temp high)
(valve open)
(not (error-status confirmed))
⇒
(printout t “Recommend closing of valve due to high temp”

crlf))

(defrule check-valve
(check-status ?valve)
(not (valve-broken ?valve))
⇒
(printout t “Device ” ?valve ” is OK“ crlf))

(defrule double-pattern
(data red)

(not (data red ?x ?x))
⇒
(printout t “No patterns with red green green!” crlf ))

A not CE that contains a single test CE is converted such that the test CE is contained within an and CE and is preceded by the (initial fact) or (initial object) pattern. For example, the following conditional element

(not (test (> ?time-1 ?time-2)))

is converted to

(not (and (initial-fact)

(test (> ?time-1 ?time-2))))

Note that it is much simpler just to convert the test CE to the following format:

(test (not (> ?time-1 ?time-2)))

Important Note

Because the not CE can cause the addition of the initial fact fact pattern or the initial object instance pattern to a rule, a reset command (which creates the initial fact fact and the initial object instance) must be issued for the correct operation of the not CE under all circumstances.

The exists conditional element provides a mechanism for determining if a group of specified CEs is satisfied by a least one set of pattern entities.

Syntax

<exists-CE> ::= (exists <conditional-element>+)

The exists CE is implemented by replacing the exists keyword with two nested not CEs. For example, the following rule

(defrule example

(exists (a ?x) (b ?x))

⇒)

is equivalent to the rule below

(defrule example

(not (not (and (a ?x) (b ?x))))

⇒)

Because of the way the exists CE is implemented using not CEs, the restrictions which apply to CEs found within not CEs (such as binding a pattern CE to a fact address) also apply to the CEs found within an exists CE.

Example

Given the following constructs,

CLIPS> (clear)

CLIPS>

(deftemplate hero

(multislot name)

(slot status (default unoccupied)))

CLIPS>

(deffacts goal-and-heroes

(goal save-the-day)

(hero (name Death Defying Man))

(hero (name Stupendous Man))

(hero (name Incredible Man)))

CLIPS>

(defrule save-the-day

(goal save-the-day)

(exists (hero (status unoccupied)))

⇒

(printout t “The day is saved.” crlf))

CLIPS>

the following commands illustrate that even though there are three facts which can match the second CE in the save the day rule, there is only one partial match generated.

CLIPS> (reset)

CLIPS> (agenda)

0 save-the-day: f-1,

For a total of 1 activation.

CLIPS> (facts)

f-0 (initial-fact)

f-1 (goal save-the-day)

f-2 (hero (name Death Defying Man) (status unoccupied))

f-3 (hero (name Stupendous Man) (status unoccupied))

f-4 (hero (name Incredible Man) (status unoccupied))

For a total of 5 facts.

CLIPS> (matches save-the-day)

Matches for Pattern 1

f-1

Matches for Pattern 2

f-0

Matches for Pattern 3

f-2

f-3

f-4

Partial matches for CEs 1 - 2

f-1,

Activations

f-1,

CLIPS>

Important Note

The exists CE is implemented using the not CE. Because the not CE can cause the addition of the initial fact fact pattern or the initial object instance pattern to a rule, a reset command (which creates the initial fact fact and the initial object instance) must be issued for the correct operation of the exists CE under all circumstances.

The forall conditional element provides a mechanism for determining if a group of specified CEs is satisfied for every occurence of another specified CE.

Syntax

<forall-CE> ::= (forall <conditional-element>

<conditional-element>+)

The forall CE is implemented by replacing the forall keyword with combinations of not and and CEs. For example, the following rule

(defrule example

(forall (a ?x) (b ?x) (c ?x))

⇒)

is equivalent to the rule below

(defrule example

(not (and (a ?x)

(not (and (b ?x) (c ?x)))))

⇒)

Because of the way the forall CE is implemented using not CEs, the restrictions which apply to CE found within not CEs (such as binding a pattern CE to a fact address) also apply to the CEs found within an forall CE.

Example

The following rule determines if every student has passed in reading, writing, and arithmetic by using the forall CE.

CLIPS> (clear)

CLIPS>

(defrule all-students-passed

(forall (student ?name)

(reading ?name)

(writing ?name)

(arithmetic ?name))

⇒

(printout t “All students passed.” crlf))

CLIPS>

The following commands illustrate how the forall CE works in the all students passed rule. Note that initially the all students passed rule is satisfied because there are no students.

CLIPS> (reset)

CLIPS> (agenda)

0 all-students-passed: f-0,

For a total of 1 activation.

CLIPS>

After the (student Bob) fact is asserted, the rule is no longer satisfied since Bob has not passed reading, writing, and arithmetic.

CLIPS> (assert (student Bob))

<Fact-1>

CLIPS> (agenda)

CLIPS>

The rule is still not satisfied after Bob has passed reading and writing, since he still has not passed arithmetic.

CLIPS> (assert (reading Bob) (writing Bob))

<Fact-3>

CLIPS> (agenda)

CLIPS>

Once Bob has passed arithmetic, the all students passed rule is reactivated.

CLIPS> (assert (arithmetic Bob))

<Fact-4>

CLIPS> (agenda)

0 all-students-passed: f-0,

For a total of 1 activation.

CLIPS>

If a new student is asserted, then the rule is taken off the agenda, since John has not passed reading, writing, and arithmetic.

CLIPS> (assert (student John))

<Fact-5>

CLIPS> (agenda)

CLIPS>

Removing both student facts reactivates the rule again.

CLIPS> (retract 1 5)

CLIPS> (agenda)

0 all-students-passed: f-0,

For a total of 1 activation.

CLIPS>

Important Note

The forall CE is implemented using the not CE. Because the not CE can cause the addition of the initial fact fact pattern or the initial object instance pattern to a rule, a reset command (which creates the initial fact fact and the initial object instance) must be issued for the correct operation of the forall CE under all circumstances.

The logical conditional element provides a truth maintenance capability for pattern entities (facts or instances) created by rules which use the logical CE. A pattern entity created on the RHS (or as a result of actions performed from the RHS) can be made logically dependent upon the pattern entities which matched the patterns enclosed with the logical CE on the LHS of the rule. The pattern entities matching the LHS logical patterns provide logical support to the facts and instance created by the RHS of the rule. A pattern entity can be logically supported by more than one group of pattern entities from the same or different rules. If any one supporting pattern entities is removed from a group of supporting pattern entities (and there are no other supporting groups), then the pattern entity is removed.

If a pattern entity is created without logical support (e.g., from a deffacts, definstaces, as a top level command, or from a rule without any logical patterns), then the pattern entity has unconditional support. Unconditionally supporting a pattern entity removes all logical support (without causing the removal of the pattern entity). In addition, further logical support for an unconditionally supported pattern entity is ignored. Removing a rule that generated logical support for a pattern entity, removes the logical support generated by that rule (but does not cause the removal of the pattern entity if no logical support remains).

Syntax

<logical-CE> ::= (logical <conditional-element>+)

The logical CE groups patterns together exactly as the explicit and CE does. It may be used in conjunction with the and, or, and not CEs. However, only the first N patterns of a rule can have the logical CE applied to them. For example, the following rule is legal

(defrule ok

(logical (a))

(logical (b))

©

⇒

(assert (d)))

whereas the following rules are illegal

(defrule not-ok-1

(logical (a))

(b)

(logical ©)

⇒

(assert (d)))

(defrule not-ok-2

(a)

(logical (b))

(logical ©)

⇒

(assert (d)))

(defrule not-ok-3

(or (a)

(logical (b)))

(logical ©)

⇒

(assert (d)))

Example

Given the following rules,

CLIPS> (clear)

CLIPS>

(defrule rule1

(logical (a))

(logical (b))

©

⇒

(assert (g) (h)))

CLIPS>

(defrule rule2

(logical (d))

(logical (e))

(f)

⇒

(assert (g) (h)))

CLIPS>

the following commands illustrate how logical dependencies work.

CLIPS> (watch facts)

CLIPS> (watch activations)

CLIPS. (watch rules)

CLIPS> (assert (a) (b) © (d) (e) (f))

==> f-0 (a)

==> f-1 (b)

==> f-2 ©

==> Activation 0 rule1: f-0,f-1,f-2

==> f-3 (d)

==> f-4 (e)

==> f-5 (f)

==> Activation 0 rule2: f-3,f-3,f-5

<Fact-5>

CLIPS> (run)

FIRE 1 rule2: f-3,f-4,f-5 ; 1st rule adds logical support

==> f-6 (g)

==> f-7 (h)

FIRE 2 rule1: f-0,f-1,f-2 ; 2nd rule adds further support

CLIPS> (retract 1)

⇐= f-0 (a) ; Removes 1st support for (g) and (h)

CLIPS> (assert (h)) ; (h) is unconditionally supported

FALSE

CLIPS> (retract 3)

⇐= f-3 (d) ; Removes 2nd support for (g)

⇐= f-6 (g) ; (g) has no more support

CLIPS> (unwatch all)

CLIPS>

As mentioned in section 5.4.1.7, the logical CE can be used with an object pattern to create pattern entities which are logically dependent on changes to specific slots in the matching instance(s) rather than all slots. This cannot be accomplished with template facts because a change to a template fact slot actually involves the retraction of the old template fact and the assertion of a new one, whereas a change to an instance slot is done in place. The example below illustrates this behavior:

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(pattern-match reactive)

(slot foo (create-accessor write))

(slot bar (create-accessor write)))

CLIPS>

(deftemplate A

(slot foo)

(slot bar))

CLIPS>

(defrule match-A-s

(logical (object (is-a A) (foo ?))

(A (foo ?)))

⇒

(assert (new-fact)))

CLIPS> (make-instance a of A)

[a]

CLIPS> (assert (A))

<Fact-0>

CLIPS> (watch facts)

CLIPS> (run)

==> f-1 (new-fact)

CLIPS> (send [a] put-bar 100)

100

CLIPS> (agenda)

CLIPS> (modify 0 (bar 100))

⇐= f-0 (A (foo nil) (bar nil))

⇐= f-1 (new-fact)

==> f-2 (A (foo nil) (bar 100))

<Fact-2>

CLIPS> (agenda)

0 match-A-s: [a],f-2

For a total of 1 activation.

CLIPS> (run)

==> f-3 (new-fact)

CLIPS> (send [a] put-foo 100)

⇐= f-3 (new-fact)

100

CLIPS> (agenda)

0 match-A-s: [a],f-2

For a total of 1 activation.

CLIPS> (unwatch facts)

CLIPS>

Under certain circumstances, CLIPS adds additional pattern CEs to rules (usually for the benefit of the pattern matching algorithm used by CLIPS). There are two default patterns used by CLIPS: the initial fact fact pattern and the initial object instance pattern. The initial fact pattern is

(initial-fact)

and the initial object pattern is

(object (is-a INITIAL-OBJECT) (name [initial-object]))

The initial fact pattern is added to any rule that has no patterns on its LHS (unless facts have been disabled by configuring CLIPS in which case the initial object pattern is added to the LHS of the rule). For example, the following rule

(defrule example-1

⇒)

would be changed as follows.

(defrule example-1

(initial-fact)

⇒)

Test CEs and not CEs that are the first CE within an and CE have an initial fact or an initial object pattern added immediately before them. An initial fact pattern is added if the first pattern CE preceding the CE in question is a fact pattern. An initial object pattern is added if the first pattern CE preceding the CE in question is an object pattern. If there are no preceding pattern CEs, the type of pattern is determined by the succeeding pattern CEs using the same methodology. If there are no pattern CEs in the rule at all, then an initial fact pattern is placed before the CE in question (unless facts have been disabled by configuring CLIPS in which case the initial object pattern is added before the CE). For example, the following rules

(defrule example-2

(test (> 80 (startup-value)))

⇒)

(defrule example-3

(test (> 80 (startup-value)))

(object (is-a MACHINE))

⇒)

(defrule example-4

(machine ?x)

(not (and (not (part ?x ?y))

(inventoried ?x)))

⇒)

would be changed as follows.

(defrule example-2

(initial-fact)

(test (> 80 (startup-value)))

⇒)

(defrule example-3

(object (is-a INITIAL-OBJECT) (name [initial-object]))

(test (> 80 (startup-value)))

(object (is-a MACHINE))

⇒)

(defrule example-4

(machine ?x)

(not (and (initial-fact)

(not (part ?x ?y))

(inventoried ?x)))

⇒)

Test CEs that immediately follow a not CE are automatically moved by CLIPS behind the first pattern CE that precedes the not CE. For example, the following rule

(defrule example

(a ?x)

(not (b ?x))

(test (> ?x 5))

⇒)

would be changed as follows.

(defrule example

(a ?x)

(test (> ?x 5))

(not (b ?x))

⇒)

If an or CE immediately follows a not CE, then the not/or CE combination is replaced with an and/not CE combination where each of the CEs contained in the original or CE is enclosed within a not CE and then all of the not CEs are enclosed within a single and CE. For example, the following rule

(defrule example

(a ?x)

(not (or (b ?x)

(c ?x)))

⇒)

would be changed as follows.

(defrule example

(a ?x)

(and (not (b ?x))

(not (c ?x)))

⇒)

There are several points which should be noted about the addition and reordering of pattern CEs: 1) The entire LHS of a rule is considered to be within an implicit and CE; 2) The conversion of the forall and exists CEs to equivalent not and and CEs is performed before patterns are added to the LHS of a rule; 3) In general, it is not very useful to have a test CE as the first CE within an and CE; and 4) The output of commands such as the matches command display information for the CEs that are actually added to the LHS of a rule and, because of reordering and implicit additions, may not reflect the rule exactly as defined by the user.

This feature allows the properties or characteristics of a rule to be defined. The char­acter­istics are declared on the LHS of a rule using the declare keyword. A rule may only have one declare statement and it must appear be­fore the first conditional element on the LHS (as shown in section 5.1).

Syntax

<declaration> ::= (declare <rule-property>+)

<rule-property> ::= (salience <integer-expression>) |

(auto-focus <boolean-symbol>)

<boolean-symbol> ::= TRUE | FALSE

The salience rule property allows the user to assign a priority to a rule. When multiple rules are in the agenda, the rule with the highest priority will fire first. The declared salience value should be an expression that evaluates to an an integer in the range  10000 to +10000. Salience expressions may freely reference global variables and other functions (however, you should avoid using functions with side effects). If unspecified, the salience value for a rule defaults to zero.

Example

(defrule test-1
(declare (salience 99))
(fire test-1)
⇒
(printout t “Rule test-1 firing.” crlf))

(defrule test-2
(declare (salience (+ ?*constraint-salience* 10)))

(fire test-2)
⇒
(printout t “Rule test-2 firing.” crlf))

Salience values can be evaluated at one of three times: when a rule is defined, when a rule is activated, and every cycle of execution (the latter two situations are referred to as dynamic salience). By default, salience values are only evaluated when a rule is defined. The set salience evaluation command can be used to change this behavior. Note that each salience evaluation method encompasses the previous method (i.e. if saliences are evaluated every cycle, then they are also evaluated when rules are activated or defined).

The auto focus rule property allows an automatic focus command to be executed whenever a rule becomes activated. If the auto focus property for a rule is TRUE, then a focus command on the module in which the rule is defined is automatically executed whenever the rule is activated. If the auto focus property for a rule is FALSE, then no action is taken when the rule is activated. If unspecified, the auto focus value for a rule defaults to FALSE.

Example

(defrule VIOLATIONS::bad-age
(declare (auto-focus TRUE))
(person (name ?name) (age ?x&:(< ?x 0)))
⇒
(printout t ?name ” has a bad age value.“ crlf))

With the defglobal construct, global variables can be defined, set, and accessed within the CLIPS environment. Global variables can be accessed as part of the pattern matching process, but changing them does not invoke the pattern matching process. The bind function is used to set the value of global variables. Global variables are reset to their original value when the reset command is performed or when bind is called for the global with no values. This behavior can be changed using the set reset globals function. Global variables can be removed by using the clear command or the undefglobal command. If the globals item is being watched (see section 13.2), then an informational message will be displayed each time the value of a global variable is changed.

Syntax

(defglobal [<defmodule-name>] <global-assignment>*)

<global-assignment> ::= <global-variable> = <expression>

<global-variable> ::= ?*<symbol>*

There may be multiple defglobal constructs and any number of global variables may be defined in each defglobal statement. The optional <defmodule name> indicates the module in which the defglobals will be defined. If none is specified, the globals will be placed in the current module. If a variable was defined in a previous defglobal construct, its value will be replaced by the value found in the new defglobal construct. If an error is encountered when defining a defglobal construct, any global variable definitions that occurred before the error was encountered will still remain in effect.

Commands that operate on defglobals such as ppdefglobal and undefglobal expect the symbolic name of the global without the astericks (e.g. use the symbol max when you want to refer to the global variable ?*max*).

Global variables may be used anyplace that a local variable could be used (with two exceptions). Global variables may not be used as a parameter variable for a deffunction, defmethod, or message-handler. Global variables may not be used in the same way that a local variable is used on the LHS of a rule to bind a value. Therefore, the following rule is illegal

(defrule example

(fact ?*x*)

⇒)

The following rule, however, is legal.

(defrule example

(fact ?y&:(> ?y ?*x*))

⇒)

Note that this rule will not necessarily be updated when the value of ?*x* is changed. For example, if ?*x* is 4 and the fact (fact 3) is added, then the rule is not satisfied. If the value of ?*x* is now changed to 2, the rule will not be activated.

Example

(defglobal

?*x* = 3

?*y* = ?*x*

?*z* = (+ ?*x* ?*y*)

?*q* = (create$ a b c))

With the deffunction construct, new functions may be defined directly in CLIPS. Deffunctions are equivalent in use to other functions; see section 2.3.2 for more detail on calling functions in CLIPS. The only differences between user defined external functions and deffunctions are that deffunctions are written in CLIPS and executed by CLIPS interpretively and user defined external functions are written in an external language, such as C, and executed by CLIPS directly. Also, deffunctions allow the addition of new functions without having to recompile and relink CLIPS.

A deffunction is comprised of five elements: 1) a name, 2) an optional comment, 3) a list of zero or more required parameters, 4) an optional wildcard parameter to handle a variable number of arguments and 5) a sequence of actions, or expressions, which will be executed in order when the deffunction is called.

Syntax

(deffunction <name> [<comment>]

(<regular-parameter>* [<wildcard-parameter>])

<action>*)

<regular-parameter> ::= <single-field-variable>

<wildcard-parameter> ::= <multifield-variable>

A deffunction must have a unique name different from all other system functions and generic functions. In particular, a deffunction cannot be overloaded like a system function (see section 8 for more detail). A deffunction must be declared prior to being called from another deffunction, generic function method, object message handler, rule, or the top level. The only exception is a self recursive deffunction.

A deffunction may accept exactly or at least a specified number of arguments, depending on whether a wildcard parameter is used or not. The regular parameters specify the minimum number of arguments that must be passed to the deffunction. Each of these parameters may be referenced like a normal single field variable within the actions of the deffunction. If a wildcard parameter is present, the deffunction may be passed any number of arguments greater than or equal to the minimum. If no wildcard parameter is present, then the deffunction must be passed exactly the number of arguments specified by the regular parameters. All arguments to a deffunction that do not correspond to a regular parameter are grouped into a multifield value that can be referenced by the wildcard parameter. The standard CLIPS multifield functions, such as length and nth, can be applied to the wildcard parameter.

Example

CLIPS> (clear)

CLIPS>

(deffunction print-args (?a ?b $?c)

(printout t ?a ” “ ?b ” and “ (length ?c) ” extras: “ ?c

crlf))

CLIPS> (print-args 1 2)

1 2 and 0 extras: ()

CLIPS> (print-args a b c d)

a b and 2 extras: (c d)

CLIPS>

When a deffunction is called, its actions are executed in order. The return value of a deffunction is the evaluation of the last action. If a deffunction has no actions, its return value is the symbol FALSE. If an error occurs while the deffunction is executing, any actions not yet executed will be aborted, and the deffunction will return the symbol FALSE.

Deffunctions may be self and mutually recursive. Self recursion is accomplished simply by calling the deffunction from within its own actions.

Example

(deffunction factorial (?a)

(if (or (not (integerp ?a)) (< ?a 0)) then

(printout t “Factorial Error!” crlf)

else

(if (= ?a 0) then

1

else

(* ?a (factorial (- ?a 1))))))

Mutual recursion between two deffunctions requires a forward declaration of one of the deffunctions. A forward declaration is simply a declaration of the deffunction without any actions. In the following example, the deffunction foo is forward declared so that it may be called by the deffunction bar. Then the deffunction foo is redefined with actions that call the deffunction bar.

Example

(deffunction foo ())

(deffunction bar ()

(foo))

(deffunction foo ()

(bar))

Care should be taken with recursive deffunctions; too many levels of recursion can lead to an overflow of stack memory (especially on PC type machines).

With the defgeneric and defmethod constructs, new genericfunctions may be written directly in CLIPS. Generic functions are similar to deffunctions because they can be used to define new procedural code directly in CLIPS, and they can be called like any other function (see sections 2.3.2 and 7). However, generic functions are much more powerful because they can do different things depending on the types (or classes) and number of their arguments. For example, a “+” operator could be defined which performs concatenation for strings but still performs arithmetic addition for numbers. Generic functions are comprised of multiple components called methods, where each method handles different cases of arguments for the generic function. A generic function which has more than one method is said to be overloaded.

Generic functions can have system functions and user defined external functions as implicit methods. For example, an overloading of the “+” operator to handle strings consists of two methods: 1) an implicit one which is the system function handling numerical addition, and 2) an explicit (user defined) one handling string concatenation. Deffunctions, however, may not be methods of generic functions because they are subsumed by generic functions anyway. Deffunctions are only provided so that basic new functions can be added directly in CLIPS without the concerns of overloading. For example, a generic function which has only one method that restricts only the number of arguments is equivalent to a deffunction.

In most cases, generic function methods are not called directly (the function call specific method described in section 12.15.8 can be used to do so, however). CLIPS recognizes that a function call is generic and uses the generic function’s arguments to find and execute the appropriate method. This process is termed the generic dispatch.

Most OOP systems support procedural behavior of objects either through message passing (e.g. Smalltalk) or by generic functions (e.g. CLOS). CLIPS supports both of these mechanisms, although generic functions are not strictly part of COOL. A generic function may examine the classes of its arguments but must still use messages within the bodies of its methods to manipulate any arguments which are instances of user defined classes. Section 9 gives more details on COOL. The fact that CLIPS supports both mechanisms leads to a confusion in terminology. In OOP systems which support message passing only, the term method is used to denote the different implementations of a message for different classes. In systems which support generic functions only, however, the term method is used to denote the different implementations of a generic function for different sets of argument restrictions. To avoid this confusion, the term message handleris used to take the place of method in the context of messages. Thus in CLIPS, message handlers denote the different implementations of a message for different classes, and methods denote the different implementations of a generic function for different sets of argument restrictions.

A call to a generic function is computationally more expensive than a call to a system function, user defined external function or deffunction. This is because CLIPS must first examine the function arguments to determine which method is applicable. A performance penalty of 15% 20% is not unexpected. Thus, generic functions should not be used for routines for which time is critical, such as routines which are called within a while loop, if at all possible. Also, generic functions should always have at least two methods. Deffunctions or user defined external functions should be used when overloading is not required. A system or user defined external function which is not overloaded will, of course, execute as quickly as ever, since the generic dispatch is unnecessary.

If a construct which uses a system or user defined external function is loaded before a generic function which uses that function as an implicit method, all calls to that function from that construct will bypass the generic dispatch. For example, if a generic function which overloads the “+” operator is defined after a rule which uses the “+” operator, that rule will always call the “+” system function directly. However, similar rules defined after the generic function will use the generic dispatch.

A generic function is comprised of a header (similar to a forward declaration) and zero or more methods. A generic function header can either be explicitly declared by the user or implicitly declared by the definition of at least one method. A method is comprised of six elements: 1) a name (which identifies to which generic function the method belongs), 2) an optional index, 3) an optional comment , 4) a set of parameter restrictions, 5) an optional wildcard parameter restriction to handle a variable number of arguments and 6) a sequence of actions, or expressions, which will be executed in order when the method is called. The parameter restrictions are used by the generic dispatch to determine a method’s applicability to a set of arguments when the generic function is actually called. The defgeneric construct is used to specify the generic function header, and the defmethod construct is used for each of the generic function’s methods.

Syntax

(defgeneric <name> [<comment>])

(defmethod <name> [<index>] [<comment>]

(<parameter-restriction>* [<wildcard-parameter-restriction>])

<action>*)

<parameter-restriction> ::=

<single-field-variable> |

(<single-field-variable> <type>* [<query>])

<wildcard-parameter-restriction> ::=

<multifield-variable> |

(<multifield-variable> <type>* [<query>])

<type> ::= <class-name>

<query> ::= <global-variable> |

<function-call>

A generic function must be declared, either by a header or a method, prior to being called from another generic function method, deffunction, object message handler, rule, or the top level. The only exception is a self recursive generic function.

A generic function is uniquely identified by name. In order to reference a generic function in other constructs before any of its methods are declared, an explicit header is necessary. Otherwise, the declaration of the first method implicitly creates a header. For example, two generic functions whose methods mutually call the other generic function (mutually recursive generic functions) would require explicit headers.

A method is uniquely identified by name and index, or by name and parameter restrictions. Each method for a generic function is assigned a unique integer index within the group of all methods for that generic function. Thus, if a new method is defined which has exactly the same name and parameter restrictions as another method, CLIPS will automatically replace the older method. However, any difference in parameter restrictions will cause the new method to be defined in addition to the older method. To replace an old method with one that has different parameter restrictions, the index of the old method can be explicitly specified in the new method definition. However, the parameter restrictions of the new method must not match that of another method with a different index. If an index is not specified, CLIPS assigns an index that has never been used by any method (past or current) of this generic function. The index assigned by CLIPS can be determined with the list defmethods command (see section 13.10.4).

Each parameter for a method can be defined to have arbitrarily complex restrictions or none at all. A parameter restriction is applied to a generic function argument at run time to determine if a particular method will accept the argument. A parameter can have two types of restrictions: type and query. A type restriction constrains the classes of arguments that will be accepted for a parameter. A query restriction is a user defined boolean test which must be satisfied for an argument to be acceptable. The complexity of parameter restrictions directly affects the speed of the generic dispatch.

A parameter that has no restrictions means that the method will accept any argument in that position. However, each method of a generic function must have parameter restrictions that make it distinguishable from all of the other methods so that the generic dispatch can tell which one to call at run time. If there are no applicable methods for a particular generic function call, CLIPS will generate an error (see section 8.5.4 for more detail).

A type restriction allows the user to specify a list of types (or classes), one of which must match (or be a superclass of) the class of the generic function argument. If COOL is not installed in the current CLIPS configuration, the only types (or classes) available are: OBJECT, PRIMITIVE, LEXEME, SYMBOL, STRING, NUMBER, INTEGER, FLOAT, MULTIFIELD, FACT ADDRESS and EXTERNAL ADDRESS. Section 9 describes each of these system classes. With COOL, INSTANCE, INSTANCE ADDRESS, INSTANCE NAME, USER, INITIAL OBJECT and any user defined classes are also available. Generic functions which use only the first group of types in their methods will work the same whether COOL is installed or not. The classes in a type restriction must be defined already, since they are used to predetermine the precedence between a generic function’s methods (see section 8.5.2 for more detail). Redundant classes are not allowed in restriction class lists. For example, the following method parameter’s type restriction is redundant since INTEGER is a subclass of NUMBER.

Example

(defmethod foo ((?a INTEGER NUMBER)))

If the type restriction (if any) is satisfied for an argument, then a query restriction (if any) will be applied. The query restriction must either be a global variable or a function call. CLIPS evaluates this expression, and if it evaluates to anything but the symbol FALSE, the restriction is considered satisfied. Since a query restriction is not always satisfied, queries should not have any side effects, for they will be evaluated for a method that may not end up being applicable to the generic function call. Since parameter restrictions are examined from left to right, queries which involve multiple parameters should be included with the rightmost parameter. This insures that all parameter type restrictions have already been satisfied. For example, the following method delays evaluation of the query restriction until the classes of both arguments have been verified.

Example

(defmethod foo ((?a INTEGER) (?b INTEGER (> ?a ?b))))

If the argument passes all these tests, it is deemed acceptable to a method. If all generic function arguments are accepted by a method’s restrictions, the method itself is deemed applicable to the set of arguments. When more than one method is applicable to a set of arguments, the generic dispatch must determine an ordering among them and execute the first one in that ordering. Method precedence is used for this purpose and will be discussed in section 8.5.2.

Example

In the following example, the first call to the generic function “+” executes the system operator “+”, an implicit method for numerical addition. The second call executes the explicit method for string concatenation, since there are two arguments and they are both strings. The third call generates an error because the explicit method for string concatenation only accepts two arguments and the implicit method for numerical addition does not accept strings at all.

CLIPS> (clear)

CLIPS>

(defmethod + ((?a STRING) (?b STRING))

(str-cat ?a ?b))

CLIPS> (+ 1 2)

3

CLIPS> (+ “foo” “bar”)

“foobar”

CLIPS> (+ “foo” “bar” “woz”)

[GENRCEXE1] No applicable methods for +.

FALSE

A method may accept exactly or at least a specified number of arguments, depending on whether a wildcard parameter is used or not. The regular parameters specify the minimum number of arguments that must be passed to the method. Each of these parameters may be referenced like a normal single field variable within the actions of the method. If a wildcard parameter is present, the method may be passed any number of arguments greater than or equal to the minimum. If no wildcard parameter is present, then the method must be passed exactly the number of arguments specified by the regular parameters. Method arguments which do not correspond to a regular parameter can be grouped into a multifield value that can be referenced by the wildcard parameter within the body of the method. The standard CLIPS multifield functions, such as length$ and expand$, can be applied to the wildcard parameter.

If multifield values are passed as extra arguments, they will all be merged into one multifield value referenced by the wildcard parameter. This is because CLIPS does not support nested multifield values.

Type and query restrictions can be applied to arguments grouped in the wildcard parameter similarly to regular parameters. Such restrictions apply to each individual field of the resulting multifield value (not the entire multifield). However, expressions involving the wildcard parameter variable may be used in the query. In addition, a special variable may be used in query restrictions on the wildcard parameter to refer to the individual arguments grouped into the wildcard: ?current argument. This variable is only in scope within the query and has no meaning in the body of the method. For example, to create a version of the ‘+’ operator which acts differently for sums of all even integers:

Example

CLIPS>

(defmethod +

(($?any INTEGER (evenp ?current-argument)))

(div (call-next-method) 2))

CLIPS> (+ 1 2)

3

CLIPS> (+ 4 6 4)

7

CLIPS>

It is important to emphasize that query and type restrictions on the wildcard parameter are applied to every argument grouped in the wildcard. Thus in the following example, the > and length$ functions are actually called three times, since there are three arguments:

Example

CLIPS> (defmethod foo (($?any (> (length$ ?any) 2))) yes)

CLIPS> (foo 1 red 3)

yes

CLIPS>

In addition, a query restriction will never be examined if there are no arguments in the wildcard parameter range. For example, the the previous methodwould be applicable to a call to the generic function with no arguments because the query restriction is never evaluated:

Example

CLIPS> (foo)

yes

CLIPS>

Typically query restrictions applied to the entire wildcard parameter are testing the cardinality (the number of arguments passed to the method). In cases like this where the type is irrelevant to the test, the query restriction can be attached to a regular parameter instead to improve performance (see section 8.5.1). Thus the previous method could be improved as follows:

Example

CLIPS> (clear)

CLIPS> (defmethod foo ((?arg (> (length$ ?any) 1)) $?any) yes)

CLIPS> (foo)

[GENRCEXE1] No applicable methods for foo.

FALSE

CLIPS>

This approach should not be used if the types of the arguments grouped by the wildcard must be verified prior to safely evaluating the query restriction.

When a generic function is called, CLIPS selects the method for that generic function with highest precedence for which parameter restrictions are satisfied by the arguments. This method is executed, and its value is returned as the value of the generic function. This entire process is referred to as the generic dispatch. Below is a flow diagram summary:

| |

The solid arrows indicate automatic control transfer by the generic dispatch.
The dashed arrows indicate control transfer that can only be accomplished by the use or lack of the use of call next method or override next method |

An explicit (user defined) method is applicable to a generic function call if the following three conditions are met: 1) its name matches that of the generic function, 2) it accepts at least as many arguments as were passed to the generic function, and 3) every argument of the generic function satisfies the corresponding parameter restriction (if any) of the method.

Method restrictions are examined from left to right. As soon as one restriction is not satisfied, the method is abandoned, and the rest of the restrictions (if any) are not examined.

When a standard CLIPS system function is overloaded, CLIPS forms an implicit method definition corresponding to that system function. This implicit method is derived from the argument restriction string for the external DefineFunction2 call defining that function to CLIPS (see the Advanced Programming Guide). This string can be accessed with the function get function restrictions. The specification of this implicit method can be examined with the list defmethods or get method restrictions functions. The method that CLIPS will form for a system function can be derived by the user from the BNF given in this document. For example,

(+ <number> <number>+)

would yield the following method for the ‘+’ function:

(defmethod + ((?first NUMBER) (?second NUMBER) ($?rest NUMBER))

…)

The method definition is used to determine the applicability and precedence of the system function to the generic function call.

The following system functions cannot be overloaded, and CLIPS will generate an error if an attempt is made to do so.

| active duplicate instance | delayed do for all instances | message modify instance |

When two or more methods are applicable to a particular generic function call, CLIPS must pick the one with highest precedence for execution. Method precedence is determined when a method is defined; the list defmethods function can be used to examine the precedence of methods for a generic function (see section 13.10).

The precedence between two methods is determined by comparing their parameter restrictions. In general, the method with the most specific parameter restrictions has the highest precedence. For example, a method which demands an integer for a particular argument will have higher precedence than a method which only demands a number. The exact rules of precedence between two methods are given in order below; the result of the first rule which establishes precedence is taken.

1) ) The parameter restrictions of both methods are positionally compared from left to right. In other words, the first parameter restriction in the first method is matched against the first parameter restriction in the second method, and so on. The comparisons between these pairs of parameter restrictions from the two methods determine the overall precedence between the two methods. The result of the first pair of parameter restrictions which specifies precedence is taken. The following rules are applied in order to a parameter pair; the result of the first rule which establishes precedence is taken.

1a) A regular parameter has precedence over a wildcard parameter.

1b) The most specific type restriction on a particular parameter has priority. A class is more specific than any of its superclasses.

1c) A parameter with a query restriction has priority over one that does not.

2) The method with the greater number of regular parameters has precedence.

3) A method without a wildcard parameter has precedence over one that does

4) A method defined before another one has priority.

If there are multiple classes on a single restriction, determining specificity is slightly more complicated. Since all precedence determination is done when the new method is defined, and the actual class of the generic function argument will not be known until run time, arbitrary (but deterministic) rules are needed for determining the precedence between two class lists. The two class lists are examined by pairs from left to right, e.g. the pair of first classes from both lists, the pair of second classes from both lists and so on. The first pair containing a class and its superclass specify precedence. The class list containing the subclass has priority. If no class pairs specify precedence, then the shorter class list has priority. Otherwise, the class lists do not specify precedence between the parameter restrictions.

Example 1

; The system operator '+' is an implicit method ; #1

; Its definition provided by the system is:

; (defmethod + ((?a NUMBER) (?b NUMBER) ($?rest NUMBER)))

(defmethod + ((?a NUMBER) (?b INTEGER))) ; #2

(defmethod + ((?a INTEGER) (?b INTEGER))) ; #3

(defmethod + ((?a INTEGER) (?b NUMBER))) ; #4

(defmethod + ((?a NUMBER) (?b NUMBER)

($?rest PRIMITIVE))) ; #5

(defmethod + ((?a NUMBER)

(?b INTEGER (> ?b 2)))) ; #6

(defmethod + ((?a INTEGER (> ?a 2))

(?b INTEGER (> ?b 3)))) ; #7

(defmethod + ((?a INTEGER (> ?a 2))

(?b NUMBER))) ; #8

The precedence would be: #7,#8,#3,#4,#6,#2,#1,#5. The methods can be immediately partitioned into three groups of decreasing precedence according to their restrictions on the first parameter: A) methods which have a query restriction and a type restriction of INTEGER (#7,#8), B) methods which have a type restriction of INTEGER (#3,#4), and C) methods which have a type restriction of NUMBER (#1,#2,#5,#6). Group A has precedence over group B because parameters with query restrictions have priority over those that do not. Group B has precedence over group C because INTEGER is a subclass of NUMBER. Thus, the ordering so far is: (#7,#8),(#3,#4),(#1,#2,#5,#6). Ordering between the methods in a particular set of parentheses is not yet established.

The next step in determining precedence between these methods considers their restrictions on the second parameter. #7 has priority over #8 because INTEGER is a subclass of NUMBER. #3 has priority over #4 because INTEGER is a subclass of NUMBER. #6 and #2 have priority over #1 and #5 because INTEGER is a subclass of NUMBER. #6 has priority over #2 because it has a query restriction and #2 does not. Thus the ordering is now: #7,#8,#3,#4,#6,#2,(#1,#5).

The restriction on the wildcard argument yields that #1 (the system function implicit method) has priority over #5 since NUMBER is a sublclass of PRIMITIVE. This gives the final ordering: #7,#8,#3,#4,#6,#2,#1,#5.

Example 2

(defmethod foo ((?a NUMBER STRING))) ; #1

(defmethod foo ((?a INTEGER LEXEME))) ; #2

The precedence would be #2,#1. Although STRING is a subclass of LEXEME, the ordering is still #2,#1 because INTEGER is a subclass of NUMBER, and NUMBER/INTEGER is the leftmost pair in the class lists.

Example 3

(defmethod foo ((?a MULTIFIELD STRING))) ; #1

(defmethod foo ((?a LEXEME))) ; #2

The precedence would be #2,#1 because the classes of the first pair in the type restriction (MULTIFIELD/LEXEME) are unrelated and #2 has fewer classes in its class list.

Example 4

(defmethod foo ((?a INTEGER LEXEME))) ; #1

(defmethod foo ((?a STRING NUMBER))) ; #2

Both pairs of classes (INTEGER/STRING and LEXEME/NUMBER) are unrelated, and the class lists are of equal length. Thus, the precedence is taken from the order of definition: #1,#2.

If one method must be called by another method in order to be executed, the first function or method is a said to be shadowed by the second method. Normally, only one method or system function will be applicable to a particular generic function call. If there is more than one applicable method, the generic dispatch will only execute the one with highest precedence. Letting the generic dispatch automatically handle the methods in this manner is called the declarative technique, for the declarations of the method restrictions dictate which method gets executed in specific circumstances. However, the functions call next method and override next method (see section 12.15.6 and 12.15.7) may also be used which allow a method to execute the method that it is shadowing. This is called the imperative technique, since the method execution itself plays a role in the generic dispatch. This is not recommended unless it is absolutely necessary. In most circumstances, only one piece of code should need to be executed for a particular set of arguments. Another imperative technique is to use the function call specific method to override method precedence (see section 12.15.8)

If an error occurs while any method for a generic function call is executing, any actions in the current method not yet executed will be aborted, any methods not yet called will be aborted, and the generic function will return the symbol FALSE. The lack of any applicable methods for a set of generic function arguments is considered a method execution error.

The return value of a generic function is the return value of the applicable method with the highest precedence. Each applicable method that is executed can choose to ignore or capture the return value of any method that it is shadowing.

The return value of a particular method is the last action evaluated by that method.

This section provides the comprehensive details of the CLIPS Object Oriented Language (COOL). Sections 2.3.1, 2.4.2 and 2.5.2.3 explain object references and structure. Section 2.6 gives a high level overview of COOL. This section assumes a complete understanding of the material given in the listed sections.

COOL is a hybrid of features from many different OOP systems as well as new ideas. For example, object encapsulation concepts are similar to those in Smalltalk, and the Common Lisp Object System (CLOS) provides the basis for multiple inheritance rules. A mixture of ideas from Smalltalk, CLOS and other systems form the foundation of messages. Section 8.1 explains an important contrast between the terms method and message handler in CLIPS.

COOL provides seventeen system classes: OBJECT, USER, INITIAL OBJECT, PRIMITIVE, NUMBER, INTEGER, FLOAT, INSTANCE, INSTANCE NAME, INSTANCE ADDRESS, ADDRESS, FACT ADDRESS, EXTERNAL ADDRESS, MULTIFIELD, LEXEME, SYMBOL and STRING. The user may not delete or modify any of these classes. The diagram illustrates the inheritance relationships between these classes.

All of these system classes except INITIAL OBJECT are abstract classes, which means that their only use is for inheritance (direct instances of this class are illegal). None of these classes have slots, and, except for the class USER, none of them have message handlers. However, the user may explicitly attach message handlers to all of the system classes except for INSTANCE, INSTANCE ADDRESS and INSTANCE NAME. The OBJECT class is a superclass of all other classes, including user defined classes. All user defined classes should (but are not required to) inherit directly or indirectly from the class USER, since this class has all of the standard system message handlers, such as initialization and deletion, attached to it. Section 9.4 describes these system message handlers.

The PRIMITIVE system class and all of its subclasses are provided mostly for use in generic function method restrictions, but message handlers and new subclasses may be attached if desired. However, the three primitive system classes INSTANCE, INSTANCE ADDRESS and INSTANCE NAME are provided strictly for use in methods (particularly in forming implicit methods for overloaded system functions - see section 8.5.1) and as such cannot have subclasses or message handlers attached to them.

The INITIAL OBJECT class is provided for use by the default definstances initial object in creating the default instance [initial object] during the reset command. This system class is concrete and reactive to pattern matching on the LHS of rules but is in other respects exactly like the system class USER. The instance [initial object] is for use by the initial object pattern (see section 5.4.9).

A defclass is a construct for specifying the properties (slots) and behavior (message handlers) of a class of objects. A defclass consists of five elements: 1) a name, 2) a list of superclasses from which the new class inherits slots and message handlers, 3) a specifier saying whether or not the creation of direct instances of the new class is allowed, 4) a specifier saying whether or not instances of this class can match object patterns on the LHS of rules and 5) a list of slots specific to the new class. All user defined classes must inherit from at least one class, and to this end COOL provides predefined system classes for use as a base in the derivation of new classes.

Any slots explicitly given in the defclass override those gotten from inheritance. COOL applies rules to the list of superclasses to generate a class precedence list (see section 9.3.1) for the new class. Facets (see section 9.3.3) further describe slots. Some examples of facets include: default value, cardinality, and types of access allowed.

Syntax

Defaults are outlined.

(defclass <name> [<comment>]

(is-a <superclass-name>+)

[<role>]

[<pattern-match-role>]

<slot>*

<handler-documentation>*)

<role> ::= (role concrete | abstract)

<pattern-match-role>

::= (pattern-match reactive | non-reactive)

<slot> ::= (slot <name> <facet>*) |

(single-slot <name> <facet>*) |

(multislot <name> <facet>*)

<facet> ::= <default-facet> | <storage-facet> |

<access-facet> | <propagation-facet> |

<source-facet> | <pattern-match-facet> |

<visibility-facet> | <create-accessor-facet>

<override-message-facet> | <constraint-attributes>

<default-facet> ::=

(default ?DERIVE | ?NONE | <expression>*) |

(default-dynamic <expression>*)

<storage-facet> ::= (storage local | shared)

<access-facet>

::= (access read-write | read-only | initialize-only)

<propagation-facet> ::= (propagation inherit | no-inherit)

<source-facet> ::= (source exclusive | composite)

<pattern-match-facet>

::= (pattern-match reactive | non-reactive)

<visibility-facet> ::= (visibility private | public)

<create-accessor-facet>

::= (create-accessor ?NONE | read | write | read-write)

<override-message-facet>

::= (override-message ?DEFAULT | <message-name>)

<handler-documentation>

::= (message-handler <name> [<handler-type>])

<handler-type> ::= primary | around | before | after

Redefining an existing class deletes the current subclasses and all associated message handlers. An error will occur if instances of the class or any of its subclasses exist.

If one class inherits from another class, the first class is a subclass of the second class, and the second class is a superclass of the first class. Every user defined class must have at least one direct superclass, i.e. at least one class must appear in the is a portion of the defclass. Multiple inheritance occurs when a class has more than one direct superclass. COOL examines the direct superclass list for a new class to establish a linear ordering called theclass precedence list. The new class inherits slots and message handlers from each of the classes in the class precedence list. The word precedence implies that slots and message handlers of a class in the list override conflicting definitions of another class found later in the list. A class that comes before another class in the list is said to be more specific. All class precedence lists will terminate in the system class OBJECT, and most (if not all) class precedence lists for user defined classes will terminate in the system classes USER and OBJECT. The class precedence list can be listed using the describe class function (see section 13.11.1.4).

COOL uses the inheritance hierarchy of the direct superclasses to determine the class precedence list for a new class. COOL recursively applies the following two rules to the direct superclasses:

1) A class has higher precedence than any of its superclasses.

2) A class specifies the precedence between its direct superclasses.

If more than one class precedence list would satisfy these rules, COOL chooses the one most similar to a strict preorder depth first traversal. This heuristic attempts to preserve “family trees” to the greatest extent possible. For example, if a child inherited genetic traits from a mother and father, and the mother and father each inherited traits from their parents, the child’s class precedence list would be: child mother maternal grandmother maternal grandfather father paternal grandmother paternal grandfather. There are other orderings which would satisfy the rules (such as child mother father paternal grandfather maternal grandmother paternal grandmother maternal grandfather), but COOL chooses the one which keeps the family trees together as much as possible.

Example 1

(defclass A (is-a USER))

Class A directly inherits information from the class USER. The class precedence list for A is: A USER OBJECT.

Example 2

(defclass B (is-a USER))

Class B directly inherits information from the class USER. The class precedence list for B is: B USER OBJECT.

Example 3

(defclass C (is-a A B))

Class C directly inherits information from the classes A and B. The class precedence list for C is: C A B USER OBJECT.

Example 4

(defclass D (is-a B A))

Class D directly inherits information from the classes B and A. The class precedence list for D is: D B A USER OBJECT.

Example 5

(defclass E (is-a A C))

By rule #2, A must precede C. However, C is a subclass of A and cannot succeed A in a precedence list without violating rule #1. Thus, this is an error.

Example 6

(defclass E (is-a C A))

Specifying that E inherits from A is extraneous, since C inherits from A. However, this definition does not violate any rules and is acceptable. The class precedence list for E is: E C A B USER OBJECT.

Example 7

(defclass F (is-a C B))

Specifying that F inherits from B is extraneous, since C inherits from B. The class precedence list for F is: F C A B USER OBJECT. The superclass list says B must follow C in F’s class precedence list but not that B must immediately follow C.

Example 8

(defclass G (is-a C D))

This is an error, for it violates rule #2. The class precedence of C says that A should precede B, but the class precedence list of D says the opposite.

Example 9

(defclass H (is-a A))

(defclass I (is-a B))

(defclass J (is-a H I A B))

The respective class precedence lists of H and I are: H A USER OBJECT and I B USER OBJECT. If J did not have A and B as direct superclasses, J could have one of three possible class precedence lists: J H A I B USER OBJECT, J H I A B USER OBJECT or J H I B A USER OBJECT. COOL would normally pick the first list since it preserves the family trees (H A and I B) to the greatest extent possible. However, since J inherits directly from A and B, rule #2 dictates that the class precedence list must be J H I A B USER OBJECT.

An abstract class is intended for inheritance only, and no direct instances of this class can be created. A concrete class can have direct instances. Using the abstract role specifier in a defclass will cause COOL to generate an error if make instance is ever called for this class. If the abstract or concrete descriptor for a class is not specified, it is determined by inheritance. For the purpose of role inheritance, system defined classes behave as concrete classes. Thus a class which inherits from USER will be concrete if no role is specified.

Objects of a reactive class can match object patterns in a rule. Objects of a non reactive class cannot match object patterns in a rule and are not considered when the list of applicable classes are determined for an object pattern. An abstract class cannot be reactive. If the reactive or non reactive descriptor for a class is not specified, it is determined by inheritance. For the purpose of pattern-match inheritance, system defined classes behave as reactive classes unless the inheriting class is abstract.

Slots are placeholders for values associated with instances of a user defined class. Each instance has a copy of the set of slots specified by the immediate class as well as any obtained from inheritance. Only available memory limits the number of slots. The name of a slot may be any symbol with the exception of the keywords is a and name which are reserved for use in object patterns.

To determine the set of slots for an instance, the class precedence list for the instance’s class is examined in order from most specific to most general (left to right). A class is more specific than its superclasses. Slots specified in any of the classes in the class precedence list are given to the instance, with the exception of no inherit slots (see section 9.3.3.5). If a slot is inherited from more than one class, the definition given by the more specific class takes precedence, with the exception of composite slots (see section 9.3.3.6).

Example

(defclass A (is-a USER)

(slot fooA)

(slot barA))

(defclass B (is-a A)

(slot fooB)

(slot barB))

The class precedence list of A is: A USER OBJECT. Instances of A will have two slots: fooA and barA. The class precedence list of B is: B A USER OBJECT. Instances of B will have four slots: fooB, barB, fooA and barA.

Just as slots make up classes, facets make up slots. Facets describe various features of a slot that hold true for all objects which have the slot: default value, storage, access, inheritance propagation, source of other facets, pattern matching reactivity, visibility to subclass message handlers, the automatic creation of message handlers to access the slot, the name of the message to send to set the slot and constraint information. Each object can still have its own value for a slot, with the exception of shared slots (see section 9.3.3.3).

A slot can hold either a single field or multifield value. By default, a slot is single field. The keyword multislot specifies that a slot can hold a multifield value comprised of zero or more fields, and the keywords slot or single slot specify that the slot can hold one value. Multifield slot values are stored as multifield values and can be manipulated with the standard multifield functions, such as nth$ and length$, once they are retrieved via messages. COOL also provides functions for setting multifield slots, such as slot insert$(see section 12.16.4.12.2). Single field slots are stored as a CLIPS primitive type, such as integer or string.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(multislot foo (create-accessor read)

(default abc def ghi)))

CLIPS> (make-instance a of A)

[a]

CLIPS> (nth$ 2 (send [a] get-foo))

def

CLIPS>

The default and default dynamic facets can be used to specify an initial value given to a slot when an instance of the class is created or initialized. By default, a slot will have a default value which is derived from the slot’s constraint facets (see sections 9.3.3.11 and 11.5). Default values are directly assigned to slots without the use of messages, unlike slot overrides in a make instance call (see section 9.6.1).

The default facet is a static default: the specified expression is evaluated once when the class is defined, and the result is stored with the class. This result is assigned to the appropriate slot when a new instance is created. If the keyword ?DERIVE is used for the default value, then a default value is derived from the constraints for the slot (see section 11.5 for more details). By default, the default attribute for a slot is (default ?DERIVE). If the keyword ?NONE is used for the default value, then the slot is not assigned a default value. Using this keyword causes make instance to require a slot override for that slot when an instance is created. Note that in CLIPS 6.0, a slot now has a default even if one is not explicitly specified (unlike CLIPS 5.1). This could cause different behavior for CLIPS 5.1 programs using the initialize instance function. The ?NONE keyword can be used to recover the original behavior for classes.

The default dynamic facet is a dynamic default: the specified expression is evaluated every time an instance is created, and the result is assigned to the appropriate slot.

Example

CLIPS> (clear)

CLIPS> (setgen 1)

1

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (default-dynamic (gensym))

(create-accessor read)))

CLIPS> (make-instance a1 of A)

[a1]

CLIPS> (make-instance a2 of A)

[a2]

CLIPS> (send [a1] get-foo)

gen1

CLIPS> (send [a2] get-foo)

gen2

CLIPS>

The actual value of an instance’s copy of a slot can either be stored with the instance or with the class. The local facet specifies that the value be stored with the instance, and this is the default. The shared facet specifies that the value be stored with the class. If the slot value is locally stored, then each instance can have a separate value for the slot. However, if the slot value is stored with the class, all instances will have the same value for the slot. Anytime the value is changed for a shared slot, it will be changed for all instances with that slot.

A shared slot will always pick up a dynamic default value from a defclass when an instance is created or initialized, but the shared slot will ignore a static default value unless it does not currently have a value. Any changes to a shared slot will cause pattern matching for rules to be updated for all reactive instances containing that slot.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (create-accessor write)

(storage shared)

(default 1))

(slot bar (create-accessor write)

(storage shared)

(default-dynamic 2))

(slot woz (create-accessor write)

(storage local)))

CLIPS> (make-instance a of A)

[a]

CLIPS> (send [a] print)

[a] of A

(foo 1)

(bar 2)

(woz nil)

CLIPS> (send [a] put-foo 56)

56

CLIPS> (send [a] put-bar 104)

104

CLIPS> (make-instance b of A)

[b]

CLIPS> (send [b] print)

[b] of A

(foo 56)

(bar 2)

(woz nil)

CLIPS> (send [b] put-foo 34)

34

CLIPS> (send [b] put-woz 68)

68

CLIPS> (send [a] print)

[a] of A

(foo 34)

(bar 2)

(woz nil)

CLIPS> (send [b] print)

[b] of A

(foo 34)

(bar 2)

(woz 68)

CLIPS>

There are three types of access facets which can be specified for a slot: read write, read only, and initialize only. The read write facet is the default and says that a slot can be both written and read. The read only facet says the slot can only be read; the only way to set this slot is with default facets in the class definition. The initialize only facet is like read only except that the slot can also be set by slot overrides in a make instance call(see section 9.6.1) and init message handlers (see section 9.4). These privileges apply to indirect access via messages as well as direct access within message handler bodies (see section 9.4). Note: a read only slot that has a static default value will implicitly have the shared storage facet.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (create-accessor write)

(access read-write))

(slot bar (access read-only)

(default abc))

(slot woz (create-accessor write)

(access initialize-only)))

CLIPS>

(defmessage-handler A put-bar (?value)

(dynamic-put (sym-cat bar) ?value))

CLIPS> (make-instance a of A (bar 34))

[MSGFUN3] bar slot in [a] of A: write access denied.

[PRCCODE4] Execution halted during the actions of message-handler put-bar primary in class A

FALSE

CLIPS> (make-instance a of A (foo 34) (woz 65))

[a]

CLIPS> (send [a] put-bar 1)

[MSGFUN3] bar slot in [a] of A: write access denied.

[PRCCODE4] Execution halted during the actions of message-handler put-bar primary in class A

FALSE

CLIPS> (send [a] put-woz 1)

[MSGFUN3] woz slot in [a] of A: write access denied.

[PRCCODE4] Execution halted during the actions of message-handler put-bar primary in class A

FALSE

CLIPS> (send [a] print)

[a] of A

(foo 34)

(bar abc)

(woz 65)

CLIPS>

An inherit facet says that a slot in a class can be given to instances of other classes that inherit from the first class. This is the default. The no inherit facet says that only direct instances of this class will get the slot.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (propagation inherit))

(slot bar (propagation no-inherit)))

CLIPS> (defclass B (is-a A))

CLIPS> (make-instance a of A)

[a]

CLIPS> (make-instance b of B)

[b]

CLIPS> (send [a] print)

[a] of A

(foo nil)

(bar nil)

CLIPS> (send [b] print)

[b] of B

(foo nil)

CLIPS>

When obtaining slots from the class precedence list during instance creation, the default behavior is to take the facets from the most specific class which gives the slot and give default values to any unspecified facets. This is the behavior specified by the exclusive facet. The composite facet causes facets which are not explicitly specified by the most specific class to be taken from the next most specific class. Thus, in an overlay fashion, the facets of an instance’s slot can be specified by more than one class. Note that even though facets may be taken from superclasses, the slot is still considered to reside in the new class for purposes of visibility (see section 9.3.3.8). One good example of a use of this feature is to pick up a slot definition and change only its default value for a new derived class.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(multislot foo (access read-only)

(default a b c)))

CLIPS>

(defclass B (is-a A)

(slot foo (source composite) ; multiple and read-only

; from class A

(default d e f)))

CLIPS> (describe-class B)

===============================================================

***************************************************************

Abstract: direct instances of this class cannot be created.

Direct Superclasses: A

Inheritance Precedence: B A USER OBJECT

Direct Subclasses:

---------------------------------------------------------------

SLOTS : FLD DEF PRP ACC STO MCH SRC VIS CRT OVRD-MSG SOURCE(S)

foo : MLT STC INH R LCL RCT CMP PRV NIL NIL A B

Constraint information for slots:

SLOTS : SYM STR INN INA EXA FTA INT FLT

foo : + + + + + + + + RNG:[-oo..+oo] CRD:[0..+oo]

---------------------------------------------------------------

Recognized message-handlers:

init primary in class USER

delete primary in class USER

create primary in class USER

print primary in class USER

direct-modify primary in class USER

message-modify primary in class USER

direct-duplicate primary in class USER

message-duplicate primary in class USER

***************************************************************

===============================================================

CLIPS>

Normally, any change to a slot of an instance will be considered as a change to the instance for purposes of pattern matching. However, it is possible to indicate that changes to a slot of an instance should not cause pattern matching. The reactive facet specifies that changes to a slot trigger pattern matching, and this is the default. The non reactive facet specifies that changes to a slot do not affect pattern matching.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(pattern-match reactive)

(slot foo (create-accessor write)

(pattern-match non-reactive)))

CLIPS>

(defclass B (is-a USER)

(role concrete)

(pattern-match reactive)

(slot foo (create-accessor write)

(pattern-match reactive)))

CLIPS>

(defrule Create

?ins←(object (is-a A | B))

⇒

(printout t “Create ” (instance-name ?ins) crlf))

CLIPS>

(defrule Foo-Access

?ins←(object (is-a A | B) (foo ?))

⇒

(printout t “Foo-Access ” (instance-name ?ins) crlf))

CLIPS> (make-instance a of A)

[a]

CLIPS> (make-instance b of B)

[b]

CLIPS> (run)

Create [b]

Foo-Access [b]

Create [a]

CLIPS> (send [a] put-foo 1)

1

CLIPS> (send [b] put-foo 1)

1

CLIPS> (run)

Foo-Access [b]

CLIPS>

Normally, only message handlers attached to the class in which a slot is defined may directly access the slot. However, it is possible to allow message handlers attached to superclasses or subclasses which inherit the slot to directly access the slot as well. Declaring the visibility facet to be private specifies that only the message handlers of the defining class may directly access the slot, and this is the default. Declaring the visibility facet to be public specifies that the message handlers and subclasses which inherit the slot and superclasses may also directly access the slot.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(slot foo (visibility private)))

CLIPS>

(defclass B (is-a A)

(role concrete))

CLIPS>

(defmessage-handler B get-foo ()

?self:foo)

[MSGFUN6] Private slot foo of class A cannot be accessed directly by handlers attached to class B

[PRCCODE3] Undefined variable self:foo referenced in message-handler.

ERROR:

(defmessage-handler MAIN::B get-foo

()

?self:foo

)

CLIPS>

The create accessor facet instructs CLIPS to automatically create explicit message handlers for reading and/or writing a slot. By default, implicit slot accessor message handlers are created for every slot. While these message handlers are real message handlers and can be manipulated as such, they have no pretty print form and cannot be directly modified by the user.

If the value ?NONE is specified for the facet, no message-handlers are created.

If the value read is specified for the facet, CLIPS creates the following message handler:

(defmessage-handler <class> get-<slot-name> primary ()

?self:<slot-name>)

If the value write is specified for the facet, CLIPS creates the following message handler for single field slots:

(defmessage-handler <class> put-<slot-name> primary (?value)

(bind ?self:<slot-name> ?value)

or the following message handler for multifield slots:

(defmessage-handler <class> put-<slot-name> primary ($?value)

(bind ?self:<slot-name> ?value)

If the value read write is specified for the facet, both the get  and one of the put  message handlers are created.

If accessors are required that do not use static slot references (see sections 9.4.2, 9.6.3 and 9.6.4), then user must define them explicitly with the defmessage handler construct.

The access facet affects the default value for the the create accessor facet. If the access facet is read-write, then the default value for the create-accessor facet is read-write. If the access facet is read-only, then the default value is read. If the access facet is initialize only, then the default is ?NONE.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (create-accessor write))

(slot bar (create-accessor read))

CLIPS> (make-instance a of A (foo 36))

[a]

CLIPS> (make-instance b of A (bar 45))

[MSGFUN1] No applicable primary message-handlers found for put-bar.

FALSE

CLIPS>

There are several COOL support functions which set slots via use of message passing, e.g., make instance, initialize instance, message modify instance and message duplicate instance. By default, all these functions attempt to set a slot with the message called put <slot name>. However, if the user has elected not to use standard slot accessors and wishes these functions to be able to perform slot overrides, then the override message facet can be used to indicate what message to send instead.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot special (override-message special-put)))

CLIPS>

(defmessage-handler A special-put primary (?value)

(bind ?self:special ?value))

CLIPS> (watch messages)

CLIPS> (make-instance a of A (special 65))

MSG » create ED:1 (<Instance-a>)

MSG « create ED:1 (<Instance-a>)

MSG » special-put ED:1 (<Instance-a> 65)

MSG « special-put ED:1 (<Instance-a> 65)

MSG » init ED:1 (<Instance-a>)

MSG « init ED:1 (<Instance-a>)

[a]

CLIPS> (unwatch messages)

CLIPS>

The syntax and functionality of single and multifield constraint facets (attributes) are described in detail in Section 11. Static and dynamic constraint checking for classes and their instances is supported. Static checking is performed when constructs or commands which specify slot information are being parsed. Object patterns used on the LHS of a rule are also checked to determine if constraint conflicts exist among variables used in more that one slot. Errors for inappropriate values are immediately signaled. Static checking is enabled by default. This behavior can be changed using the set static constraint checking function. Dynamic checking is also supported. If dynamic checking is enabled, then new instances have their values checked whenever they are set (e.g. initialization, slot overrides, and put  access). This dynamic checking is disabled by default. This behavior can be changed using the set dynamic constraint checking function. If an violation occurs when dynamic checking is being performed, then execution will be halted.

Regardless of whether static or dynamic checking is enabled, multifield values can never be stored in single field slots. Single field values are converted to a multifield value of length one when storing in a multifield slot. In addition, the evaluation of a function which has no return value is always illegal as a slot value.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(multislot foo (create-accessor write)

(type SYMBOL)

(cardinality 2 3)))

CLIPS> (make-instance a of A (foo 45))

[a]

CLIPS> (set-dynamic-constraint-checking TRUE)

FALSE

CLIPS> (make-instance a of A (foo red 5.0))

[CSTRNCHK1] (red 5.0) for slot foo of instance [a] found in put-foo primary in class A does not match the allowed types.

[PRCCODE4] Execution halted during the actions of message-handler put-foo primary in class A

FALSE

CLIPS> (make-instance a of A (foo red))

[CSTRNCHK1] (red) for slot foo of instance [a] found in put-foo primary in class A does not satisfy the cardinality restrictions.

[PRCCODE4] Execution halted during the actions of message-handler put-foo primary in class A

FALSE

CLIPS>

COOL allows the user to forward declare the message handlers for a class within the defclass statement. These declarations are for documentation only and are ignored by CLIPS. The defmessage handler construct must be used to actually add message handlers to a class. Message handlers can later be added which are not documented in the defclass.

Example

CLIPS> (clear)

CLIPS>

(defclass rectangle (is-a USER)

(slot side-a (default 1))

(slot side-b (default 1))

(message-handler find-area))

CLIPS>

(defmessage-handler rectangle find-area ()

(* ?self:side-a ?self:side-b))

CLIPS>

(defmessage-handler rectangle print-area ()

(printout t (send ?self find-area) crlf))

CLIPS>

Objects are manipulated by sending them messages via the function send. The result of a message is a useful return value or side effect. A defmessage handler is a construct for specifying the behavior of a class of objects in response to a particular message. The implementation of a message is made up of pieces of procedural code called message handlers (or handlers for short). Each class in the class precedence list of an object’s class can have handlers for a message. In this way, the object’s class and all its superclasses share the labor of handling the message. Each class’s handlers handle the part of the message which is appropriate to that class. Within a class, the handlers for a particular message can be further subdivided into four types or categories: primary, before, after and around. The intended purposes of each type are summarized in the chart below:

* Type Role for the Class primary Performs the majority of the work for the message before Does auxiliary work for a message before the primary handler executes after Does auxiliary work for a message after the primary handler executes around Sets up an environment for the execution of the rest of the handlers

Before and after handlers are for side effects only; their return values are always ignored. Before handlers execute before the primaryones, and after message handlers execute after the primary ones. The return value of a message is generally given by the primary message handlers, but around handlers can also return a value. Around message handlers allow the user to wrap code around the rest of the handlers. They begin execution before the other handlers and pick up again after all the other message handlers have finished.

A primary handler provides the part of the message implementation which is most specific to an object, and thus the primary handler attached to the class closest to the immediate class of the object overrides other primary handlers. Before and after handlers provide the ability to pick up behavior from classes that are more general than the immediate class of the object, thus the message implementation uses all handlers of this type from all the classes of an object. When only the roles of the handlers specify which handlers get executed and in what order, the message is said to be declaratively implemented. However, some message implementations may not fit this model well. For example, the results of more than one primary handler may be needed. In cases like this, the handlers themselves must take part in deciding which handlers get executed and in what order. This is called the imperative technique. Around handlers provide imperative control over all other types of handlers except more specific around handlers. Around handlers can change the environment in which other handlers execute and modify the return value for the entire message. A message implementation should use the declarative technique if at all possible because this allows the handlers to be more independent and modular.

A defmessage handler is comprised of seven elements: 1) a class name to which to attach the handler (the class must have been previously defined), 2) a message name to which the handler will respond, 3) an optional type (the default is primary), 4) an optional comment, 5) a list of parameters that will be passed to the handler during execution, 6) an optional wildcard parameter and 7) a series of expressions which are executed in order when the handler is called. The return value of a message handler is the evaluation of the last expression in the body.

Syntax

Defaults are outlined.

(defmessage-handler <class-name> <message-name>

[<handler-type>] [<comment>]

(<parameter>* [<wildcard-parameter>])

<action>*)

<handler-type> ::= around | before | primary | after

<parameter> ::= <single-field-variable>

<wildcard-parameter> ::= <multifield-variable>

Message handlers are uniquely identified by class, name and type. Message handlers are never called directly. When the user sends a message to an object, CLIPS selects and orders the applicable message handlers attached to the object’s class(es) and then executes them. This process is termed the message dispatch.

Example

CLIPS> (clear)

CLIPS> (defclass A (is-a USER) (role concrete))

CLIPS>

(defmessage-handler A delete before ()

(printout t “Deleting an instance of the class A…” crlf))

CLIPS>

(defmessage-handler USER delete after ()

(printout t “System completed deletion of an instance.”

crlf))

CLIPS> (watch instances)

CLIPS> (make-instance a of A)

==> instance [a] of A

[a]

CLIPS> (send [a] delete)

Deleting an instance of the class A…

⇐= instance [a] of A

System completed deletion of an instance.

TRUE

CLIPS> (unwatch instances)

CLIPS>

A message handler may accept exactly or at least a specified number of arguments, depending on whether a wildcard parameter is used or not. The regular parameters specify the minimum number of arguments that must be passed to the handler. Each of these parameters may be referenced like a normal single field variable within the actions of the handler. If a wildcard parameter is present, the handler may be passed any number of arguments greater than or equal to the minimum. If no wildcard parameter is present, then the handler must be passed exactly the number of arguments specified by the regular parameters. All arguments to a handler that do not correspond to a regular parameter are grouped into a multifield value that can be referenced by the wildcard parameter. The standard CLIPS multifield functions, such as length$ and expand$, can be applied to the wildcard parameter.

Handler parameters have no bearing on the applicability of a handler to a particular message (see section 9.5.1). However, if the number of arguments is inappropriate, a message execution error (see section 9.5.4) will be generated when the handler is called. Thus, the number of arguments accepted should be consistent for all message handlers applicable to a particular message.

Example

CLIPS> (clear)

CLIPS>

(defclass CAR (is-a USER)

(role concrete)

(slot front-seat)

(multislot trunk)

(slot trunk-count))

CLIPS>

(defmessage-handler CAR put-items-in-car (?item $?rest)

(bind ?self:front-seat ?item)

(bind ?self:trunk ?rest)

(bind ?self:trunk-count (length$ ?rest)))

CLIPS> (make-instance Pinto of CAR)

[Pinto]

CLIPS> (send [Pinto] put-items-in-car bag-of-groceries

tire suitcase)

2

CLIPS> (send [Pinto] print)

[Pinto] of CAR

(front-seat bag-of-groceries)

(trunk tire suitcase)

(trunk-count 2)

CLIPS>

The term active instance refers to an instance which is responding to a message. All message handlers have an implicit parameter called ?self which binds the active instance for a message. This parameter name is reserved and cannot be explicitly listed in the message handler’s parameters, nor can it be rebound within the body of a message handler.

Example

CLIPS> (clear)

CLIPS> (defclass A (is-a USER) (role concrete))

CLIPS> (make-instance a of A)

[a]

CLIPS>

(defmessage-handler A print-args (?a ?b $?c)

(printout t (instance-name ?self) ” “ ?a ” “ ?b

” and “ (length$ ?c) ” extras: “ ?c crlf))

CLIPS> (send [a] print-args 1 2)

[a] 1 2 and 0 extras: ()

CLIPS> (send [a] print-args a b c d)

[a] a b and 2 extras: (c d)

CLIPS>

The body of a message handler is a sequence of expressions that are executed in order when the handler is called. The return value of the message handler is the result of the evaluation of the last expression in the body.

Handler actions may directly manipulate slots of the active instance. Normally, slots can only be manipulated by sending the object slot accessor messages (see sections 9.3.3.9 and 9.4.3). However, handlers are considered part of the encapsulation (see section 2.6.2) of an object, and thus can directly view and change the slots of the object. There are several functions which operate implicitly on the active instance (without the use of messages) and can only be called from within a message handler. These functions are discussed in section 12.16.

A shorthand notation is provided for accessing slots of the active instance from within a message handler.

Syntax

?self:<slot-name>

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (default 1))

(slot bar (default 2)))

CLIPS>

(defmessage-handler A print-all-slots ()

(printout t ?self:foo ” “ ?self:bar crlf))

CLIPS> (make-instance a of A)

[a]

CLIPS> (send [a] print-all-slots)

1 2

CLIPS>

The bind function can also take advantage of this shorthand notation to set the value of a slot.

Syntax

(bind ?self:<slot-name> <value>*)

Example

CLIPS>

(defmessage-handler A set-foo (?value)

(bind ?self:foo ?value))

CLIPS> (send [a] set-foo 34)

34

CLIPS>

Direct slot accesses are statically bound to the appropriate slot in the defclass when the message handler is defined. Care must be taken when these direct slot accesses can be executed as the result of a message sent to an instance of a subclass of the class to which the message handler is attached. If the subclass has redefined the slot, the direct slot access contained in the message handler attached to the superclass will fail. That message handler accesses the slot in the superclass, not the subclass.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(slot foo (create-accessor read)))

CLIPS>

(defclass B (is-a A)

(role concrete)

(slot foo))

CLIPS> (make-instance b of B)

[b]

CLIPS> (send [b] get-foo)

[MSGPASS3] Static reference to slot foo of class A does not apply to [b] of B

[PRCCODE4] Execution halted during the actions of message-handler get-foo primary in class A

FALSE

CLIPS>

In order for direct slot accesses in a superclass message handler to apply to new versions of the slot in subclasses, the dynamic put and dynamic get (see sections 12.16.4.10 and 12.16.4.11) must be used. However, the subclass slot must have public visibility for this to work (see section 9.3.3.8).

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(slot foo))

CLIPS>

(defmessage-handler A get-foo ()

(dynamic-get foo))

CLIPS>

(defclass B (is-a A)

(role concrete)

(slot foo (visibility public)))

CLIPS> (make-instance b of B)

[b]

CLIPS> (send [b] get-foo)

nil

CLIPS>

Daemons are pieces of code which execute implicitly whenever some basic action is taken upon an instance, such as initialization, deletion, or reading and writing of slots. All these basic actions are implemented with primary handlers attached to the class of the instance. Daemons may be easily implemented by defining other types of message handlers, such as before or after, which will recognize the same messages. These pieces of code will then be executed whenever the basic actions are performed on the instance.

Example

CLIPS> (clear)

CLIPS> (defclass A (is-a USER) (role concrete))

CLIPS>

(defmessage-handler A init before ()

(printout t “Initializing a new instance of class A…”

crlf))

CLIPS> (make-instance a of A)

Initializing a new instance of class A…

[a]

CLIPS>

CLIPS defines eight primary message handlers that are attached to the class USER. These handlers cannot be deleted or modified.

Syntax

(defmessage-handler USER init primary ())

This handler is responsible for initializing instances with class default values after creation. The make instance and initialize instance functions send the init message to an instance (see sections 9.6.1 and 9.6.2); the user should never send this message directly. This handler is implemented using the init slots function (see section 12.13). User defined init handlers should not prevent the system message handler from responding to an init message (see section 9.5.3).

Example

CLIPS> (clear)

CLIPS>

(defclass CAR (is-a USER)

(role concrete)

(slot price (default 75000))

(slot model (default Corniche)))

CLIPS> (watch messages)

CLIPS> (watch message-handlers)

CLIPS> (make-instance Rolls-Royce of CAR)

MSG » create ED:1 (<Instance-Rolls-Royce>)

HND » create primary in class USER

ED:1 (<Instance-Rolls-Royce>)

HND « create primary in class USER

ED:1 (<Instance-Rolls-Royce>)

MSG « create ED:1 (<Instance-Rolls-Royce>)

MSG » init ED:1 (<Instance-Rolls-Royce>)

HND » init primary in class USER

ED:1 (<Instance-Rolls-Royce>)

HND « init primary in class USER

ED:1 (<Instance-Rolls-Royce>)

MSG « init ED:1 (<Instance-Rolls-Royce>)

[Rolls-Royce]

CLIPS>

Syntax

(defmessage-handler USER delete primary ())

This handler is responsible for deleting an instance from the system. The user must directly send a delete message to an instance. User defined delete message handlers should not prevent the system message handler from responding to a delete message (see section 9.5.3). The handler returns the symbol TRUE if the instance was successfully deleted, otherwise it returns the symbol FALSE.

Example

CLIPS> (send [Rolls-Royce] delete)

MSG » delete ED:1 (<Instance-Rolls-Royce>)

HND » delete primary in class USER

ED:1 (<Instance-Rolls-Royce>)

HND « delete primary in class USER

ED:1 (<Stale Instance-Rolls-Royce>)

MSG « delete ED:1 (<Stale Instance-Rolls-Royce>)

TRUE

CLIPS>

Syntax

(defmessage-handler USER print primary ())

This handler prints out slots and their values for an instance.

Example

CLIPS> (make-instance Rolls-Royce of CAR)

MSG » create ED:1 (<Instance-Rolls-Royce>)

HND » create primary in class USER

ED:1 (<Instance-Rolls-Royce>)

HND « create primary in class USER

ED:1 (<Instance-Rolls-Royce>)

MSG « create ED:1 (<Instance-Rolls-Royce>)

MSG » init ED:1 (<Instance-Rolls-Royce>)

HND » init primary in class USER

ED:1 (<Instance-Rolls-Royce>)

HND « init primary in class USER

ED:1 (<Instance-Rolls-Royce>)

MSG « init ED:1 (<Instance-Rolls-Royce>)

[Rolls-Royce]

CLIPS> (send [Rolls-Royce] print)

MSG » print ED:1 (<Instance-Rolls-Royce>)

HND » print primary in class USER

ED:1 (<Instance-Rolls-Royce>)

[Rolls-Royce] of CAR

(price 75000)

(model Corniche)

HND « print primary in class USER

ED:1 (<Instance-Rolls-Royce>)

MSG « print ED:1 (<Instance-Rolls-Royce>)

CLIPS> (unwatch messages)

CLIPS. (unwatch message-handlers)

CLIPS>

Syntax

(defmessage-handler USER direct-modify primary

(?slot-override-expressions))

This handler modifies the slots of an instance directly rather than using put- override messages to place the slot values. The slot override expressions are passed as an EXTERNAL_ADDRESS data object to the direct modify handler. This message is used by the functions modify instance and active modify instance.

Example

The following around message handler could be used to insure that all modify message slot overrides are handled using put- messages.

(defmessage-handler USER direct-modify around

(?overrides)

(send ?self message-modify ?overrides))

Syntax

(defmessage-handler USER message-modify primary

(?slot-override-expressions)

This handler modifies the slots of an instance using put  messages for each slot update. The slot override expressions are passed as an EXTERNAL_ADDRESS data object to the message modify handler. This message is used by the functions message modify instance and active message modify instance.

Syntax

(defmessage-handler USER direct-duplicate primary

(?new-instance-name ?slot-override-expressions))

This handler duplicates an instance without using put- messages to assign the slot overrides. Slot values from the original instance and slot overrides are directly copied. If the name of the new instance created matches a currently existing instance name, then the currently existing instance is deleted without use of a message. The slot override expressions are passed as an EXTERNAL_ADDRESS data object to the direct duplicate handler. This message is used by the functions duplicate instance and active duplicate instance.

Example

The following around message handler could be used to insure that all duplicate message slot overrides are handled using put- messages.

(defmessage-handler USER direct-duplicate around

(?new-name ?overrides)

(send ?self message-duplicate ?new-name ?overrides))

Syntax

(defmessage-handler USER message-duplicate primary

(?new-instance-name ?slot-override-expressions)

This handler duplicates an instance using messages. Slot values from the original instance and slot overrides are copied using put  and get  messages. If the name of the new instance created matches a currently existing instance name, then the currently existing instance is deleted using a delete message. After creation, the new instance is sent a create message and then an init message. The slot override expressions are passed as an EXTERNAL_ADDRESS data object to the message duplicate handler. This message is used by the functions message duplicate instance and active message duplicate instance.

Syntax

(defmessage-handler USER create primary ())

This handler is called after an instance is created , but before any slot initialization has occurred. The newly created instance is sent a create message. This handler performs no actions—It is provided so that instance creation can be detected by user-defined message-handlers. The handler returns the symbol TRUE if the instance was successfully created, otherwise it returns the symbol FALSE.

When a message is sent to an object using the send function, CLIPS examines the class precedence list of the active instance’s class to determine a complete set of message handlers which are applicable to the message. CLIPS uses the roles (around, before, primary or after) and specificity of these message handlers to establish an ordering and then executes them. A handler which is attached to a subclass of another message handler’s class is said to be more specific. This entire process is referred to as the message dispatch. Following is a flow diagram summary:

| |





The solid arrows indicate automatic control transfer by the message dispatch system.
The dashed arrows indicate control transfer that can only be accomplished by the use or lack of the use of call next handler (or override next handler). |

A message handler is applicable to a message if its name matches the message, and it is attached to a class which is in the class precedence list of the class of the instance receiving the message.

The set of all applicable message handlers are sorted into four groups according to role, and these four groups are further sorted by class specificity. The around, before and primary handlers are ordered from most specific to most general, whereas after handlers are ordered from most general to most specific.

The order of execution is as follows: 1) around handlers begin execution from most specific to most general (each around handler must explicitly allow execution of other handlers), 2) before handlers execute (one after the other) from most specific to most general 3) primary handlers begin execution from most specific to most general (more specific primary handlers must explicitly allow execution of more general ones), 4) primary handlers finish execution from most general to most specific, 5) after handlers execute (one after the other) from most general to most specific and 6) aroundhandlers finish execution from most general to most specific.

There must be at least one applicable primary handler for a message, or a message execution error will be generated (see section 9.5.4).

When one handler must be called by another handler in order to be executed, the first handler is said to be shadowed by the second. An around handler shadows all handlers except more specific around handlers. A primary handler shadows all more general primary handlers.

Messages should be implemented using the declarative technique, if possible. Only the handler roles will dictate which handlers get executed; only before and after handlers and the most specific primaryhandler are used. This allows each handler for a message to be completely independent of the other message handlers. However, if around handlers or shadowed primary handlers are necessary, then the handlers must explicitly take part in the message dispatch by calling other handlers they are shadowing. This is called the imperative technique. The functions call next handlerand override next handler (see section 12.16.2) allow a handler to execute the handler it is shadowing. A handler can call the same shadowed handler multiple times.

Example

(defmessage-handler USER my-message around () (call-next-handler)) (defmessage-handler USER my-message before ()) (defmessage-handler USER my-message () (call-next-handler)) (defmessage-handler USER my-message after ()) (defmessage-handler OBJECT my-message around () (call-next-handler)) (defmessage-handler OBJECT my-message before ()) (defmessage-handler OBJECT my-message ()) (defmessage-handler OBJECT my-message after ()) For a message sent to an instance of a class which inherits from USER, the diagram to the right illustrates the order of execution for the handlers attached to the classes USER and OBJECT. The brackets indicate where a particular handler begins and ends execution. Handlers enclosed within a bracket are shadowed.

If an error occurs at any time during the execution of a message handler, any currently executing handlers will be aborted, any handlers which have not yet started execution will be ignored, and the sendfunction will return the symbol FALSE.

A lack of applicable of primary message handlers and a handler being called with the wrong number of arguments are common message execution errors.

The return value of call to the send function is the return value of the most specific around handler, or the most specific primary handler if there are no around handlers. The return value of a handler is the result of the evaluation of the last action in the handler.

The return values of the before and after handlers are ignored; they are for side effects only. An around handler can choose to ignore or capture the return value of the next most specific around or primary handler. A primary handler can choose to ignore or capture the return value of a more general primary handler.

Objects are manipulated by sending them messages. This is achieved by using the send function, which takes as arguments the destination object for the message, the message itself and any arguments which are to be passed to handlers.

Syntax

(send <object-expression>

<message-name-expression> <expression>*)

Section 2.4.2 explains object references. The return value of send is the result of the message as explained in section 9.5.5.

The slots of an object may be read or set directly only within the body of a message handler that is executing on behalf of a message that was sent to that object. This is how COOL implements the notion of encapsulation (see Section 2.6.2). Any action performed on an object by an external source, such as a rule or function, must be done with messages. There are two major exceptions: 1) objects which are not instances of user defined classes (floating point and integer numbers, symbols, strings, multifield values, fact addresses and external addresses) can be manipulated in the standard non OOP manner of previous versions of CLIPS as well and 2) creation and initialization of an instance of a user defined class are performed via the function make instance.

Like facts, instances of user defined classes must be explicitly created by the user. Likewise, all instances are deleted during the resetcommand, and they can be loaded and saved similarly to facts. All operations involving instances require message passing using the send function except for creation, since the object does not yet exist. A function called make instance is used to create and initialize a new instance. This function implicitly sends first a create message and then an initialization message to the new object after allocation. The user can customize instance initialization with daemons. make instance also allows slot overrides to change any predefined initialization for a particular instance. make instance automatically delays all object pattern matching activities for rules until all slot overrides have been processed. The function active make instance can be used if delayed pattern matching is not desired. active make instance remembers the current state of delayed pattern matching, explicitly turns delay on, and then restores it to its previous state once all slot overrides have been processed.

Syntax

(make-instance <instance-definition>)

(active-make-instance <instance-definition>)

<instance-definition> ::= [<instance-name-expression>] of

<class-name-expression>

<slot-override>*

<slot-override> ::= (<slot-name-expression> <expression>*)

The return value of make instance is the name of the new instance on success or the symbol FALSE on failure. The evaluation of <instance name expression> can either be an instance name or a symbol. If <instance name expression> is not specified, then the function gensym* will be called to generate the instance name.

make instance performs the following steps in order:

1) If an instance of the specified name already exists, that instance receives a delete message, e.g. (send <instance name> delete). If this fails for any reason, the new instance creation is aborted. Normally, the handler attached to class USER will respond to this message (see section 9.4.5.2).

2) A new and uninitialized instance of the specified class is created with the specified name.

3) The new instance receives the create message, e.g. (send <instance name> create). Normally, the handler attached to class USER will respond to this message (see section 9.4.4.8), although it performs no actions.

4) All slot overrides are immediately evaluated and placed via put messages (see section 9.3.3.10), e.g. (send <instance name> put <slot name> <expression>*). If there are any errors, the new instance is deleted.

5) The new instance receives the init message, e.g. (send <instance name> init). Normally, the handler attached to class USER will respond to this message (see section 9.4.4.1). This handler calls the init slots function (see section 12.16.4.1). This function uses defaults from the class definition (if any) for any slots which do not have slot overrides. The class defaults are placed directly without the use of messages. If there are any errors, the new instance is deleted.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot x (default 34)

(create-accessor write))

(slot y (default abc)))

CLIPS>

(defmessage-handler A put-x before (?value)

(printout t “Slot x set with message.” crlf))

CLIPS>

(defmessage-handler A delete after ()

(printout t “Old instance deleted.” crlf))

CLIPS> (make-instance a of A)

[a]

CLIPS> (send [a] print)

[a] of A

(x 34)

(y abc)

CLIPS> (make-instance [a] of A (x 65))

Old instance deleted.

Slot x set with message.

[a]

CLIPS> (send [a] print)

a of A

(x 65)

(y abc)

CLIPS> (send [a] delete)

Old instance deleted.

TRUE

CLIPS>

Similar to deffacts, the definstances construct allows the specification of instances which will be created every time the reset command is executed. On every reset all current instances receive a delete message, and the equivalent of a make instancefunction call is made for every instance specified in definstances constructs.

Syntax

(definstances <definstances-name> [active] [<comment>]

<instance-template>*)

<instance-template> ::= (<instance-definition>)

A definstances cannot use classes which have not been previously defined. The instances of a definstances are created in order, and if any individual creation fails, the remainder of the definstances will be aborted. Normally, definstances just use the make instance function (which means delayed Rete activity) to create the instances. However, if this is not desired,then the active keyword can be specified after the definstances name so that the active make instance function will be used.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER) (role concrete)

(slot x (create-accessor write) (default 1)))

CLIPS>

(definstances A-OBJECTS

(a1 of A)

(of A (x 65)))

CLIPS> (watch instances)

CLIPS> (reset)

==> instance [initial-object] of INITIAL-OBJECT

==> instance [a1] of A

==> instance [gen1] of A

CLIPS> (reset)

⇐= instance [initial-object] of INITIAL-OBJECT

⇐= instance [a1] of A

⇐= instance [gen1] of A

==> instance [initial-object] of INITIAL-OBJECT

==> instance [a1] of A

==> instance [gen2] of A

CLIPS> (unwatch instances)

CLIPS>

Upon startup and after a clear command, CLIPS automatically constructs the following definstances.

(definstances initial-object

(initial-object of INITIAL-OBJECT))

The class INITIAL-OBJECT is a predefined system class that is a direct subclass of USER.

(defclass INITIAL-OBJECT

(is-a USER)

(role concrete)

(pattern-match reactive))

The initial object definstances and the INITIAL OBJECT class are only defined if both the object system and defrules are enabled (see section 2 of the Advanced Programming Guide). The INITIAL OBJECT class cannot be deleted, but the initial object definstances can. See section 5.4.9 for details on default patterns which pattern match against the initial object instance.

The initialize instance function provides the ability to reinitialize an existing instance with class defaults and new slot overrides. The return value of initialize instance is the name of the instance on success or the symbol FALSE on failure. The evaluation of <instance name expression> can either be an instance name, instance address or a symbol. initialize instance automatically delays all object pattern matching activities for rules until all slot overrides have been processed. The function active initialize instance can be used if delayed pattern matching is not desired.

Syntax

(initialize-instance <instance-name-expression>

<slot-override>*)

initialize instance performs the following steps in order:

1) All slot overrides are immediately evaluated and placed via put  messages (see section 9.3.3.10), e.g. (send <instance name> put <slot name> <expression>*).

2) The instance receives the init message, e.g. (send <instance name> init). Normally, the handler attached to class USER will respond to this message (see section 9.4.5.1). This handler calls the init slots function (see section 12.16.4.1). This function uses defaults from the class definition (if any) for any slots which do not have slot overrides. The class defaults are placed directly without the use of messages.

If no slot override or class default specifies the value of a slot, that value will remain the same. Empty class default values allow initialize instance to clear a slot.

If an error occurs, the instance will not be deleted, but the slot values may be in an inconsistent state.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot x (default 34)

(create-accessor write))

(slot y (default ?NONE)

(create-accessor write))

(slot z (create-accessor write)))

CLIPS> (make-instance a of A (y 100))

[a]

CLIPS> (send [a] print)

[a] of A

(x 34)

(y 100)

(z nil)

CLIPS> (send [a] put-x 65)

65

CLIPS> (send [a] put-y abc)

abc

CLIPS> (send [a] put-z “Hello world.”)

“Hello world.”

CLIPS> (send [a] print)

[a] of A

(x 65)

(y abc)

(z “Hello world.”)

CLIPS> (initialize-instance a)

[a]

CLIPS> (send [a] print)

a of A

(x 34)

(y abc)

(z nil)

CLIPS>

Sources external to an object, such as a rule or deffunction, can read an object’s slots only by sending the object a message. Message handlers executing on the behalf of an object can either use messages or direct access to read the object’s slots (see section 9.4.2). Several functions also exist which operate implicitly on the active instance for a message that can only be called by message handlers, such as dynamic get (see section 12.16.4.10).

Section 12.16 describes ways of testing for the existence of slots and their values.

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot x (create-accessor read)

(default abc)))

CLIPS> (make-instance a of A)

[a]

CLIPS> (sym-cat (send [a] get-x) def)

abcdef

CLIPS>

Sources external to an object, such as a rule or deffunction, can write an object’s slots only by sending the object a message. Several functions also exist which operate implicitly on the active instance for a message that can only be called by message handlers, such as dynamic put (see section 12.16.4.11). The bind function can also be used to set a slot's value from within a message handler (see section 9.4.2).

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot x (create-accessor write)

(default abc)))

CLIPS> (make-instance a of A)

[a]

CLIPS> (send [a] put-x “New value.”)

“New value.”

CLIPS>

Sending the delete message to an instance removes it from the system. Within a message handler, the delete instance function (see section 12.16) can be used to delete the active instance for a message.

Syntax

(send <instance> delete)

While manipulating instances (either by creating, modifying, or deleting), it is possible to delay pattern matching activities for rules until after all of the manipulations have been made. This can be accomplished using the object pattern match delay function. This function acts identically to the progn function, however, any actions which could affect object pattern matching for rules are delayed until the function is exited. This function’s primary purpose is to provide some control over performance.

Syntax

(object-pattern-match-delay <action>*)

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(pattern-match reactive))

CLIPS>

(defrule match-A

(object (is-a A))

⇒)

CLIPS> (make-instance a of A)

[a]

CLIPS> (agenda)

0 match-A: [a]

For a total of 1 activation.

CLIPS> (make-instance b of A)

[b]

CLIPS> (agenda)

0 match-A: [b]

0 match-A: [a]

For a total of 2 activations.

CLIPS>

(object-pattern-match-delay

(make-instance c of A)

(printout t “After c…” crlf)

(agenda)

(make-instance d of A)

(printout t “After d…” crlf)

(agenda))

After c…

0 match-A: [b]

0 match-A: [a]

For a total of 2 activations.

After d…

0 match-A: [b]

0 match-A: [a]

For a total of 2 activations.

CLIPS> (agenda)

0 match-A: [d]

0 match-A: [c]

0 match-A: [b]

0 match-A: [a]

For a total of 4 activations.

CLIPS>

Four functions are provided for modifying instances. These functions allow instance slot updates to be performed in blocks without requiring a series of put  messages. Each of these functions returns the symbol TRUE if successful, otherwise the symbol FALSE is returned.

The modify instance function uses the direct modify message to change the values of the instance. Object pattern matching is delayed until all of the slot modifications have been performed.

Syntax

(modify-instance <instance> <slot-override>*)

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo)

(slot bar))

CLIPS> (make-instance a of A)

[a]

CLIPS> (watch all)

CLIPS> (modify-instance a (foo 0))

MSG » direct-modify ED:1 (<Instance-a> <Pointer-0019CD5A>)

HND » direct-modify primary in class USER.

ED:1 (<Instance-a> <Pointer-0019CD5A>)

::= local slot foo in instance a ← 0

HND « direct-modify primary in class USER.

ED:1 (<Instance-a> <Pointer-0019CD5A>)

MSG « direct-modify ED:1 (<Instance-a> <Pointer-0019CD5A>)

TRUE

CLIPS> (unwatch all)

CLIPS>

The active modify instance function uses the direct modify message to change the values of the instance. Object pattern matching occurs as slot modifications are being performed.

Syntax

(active-modify-instance <instance> <slot-override>*)

The message modify instance function uses the message modify message to change the values of the instance. Object pattern matching is delayed until all of the slot modifications have been performed.

Syntax

(message-modify-instance <instance> <slot-override>*)

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo)

(slot bar (create-accessor write)))

CLIPS> (make-instance a of A)

[a]

CLIPS> (watch all)

CLIPS> (message-modify-instance a (bar 4))

MSG » message-modify ED:1 (<Instance-a> <Pointer-009F04A0>)

HND » message-modify primary in class USER

ED:1 (<Instance-a> <Pointer-009F04A0>)

MSG » put-bar ED:2 (<Instance-a> 4)

HND » put-bar primary in class A

ED:2 (<Instance-a> 4)

::= local slot bar in instance a ← 4

HND « put-bar primary in class A

ED:2 (<Instance-a> 4)

MSG « put-bar ED:2 (<Instance-a> 4)

HND « message-modify primary in class USER

ED:1 (<Instance-a> <Pointer-009F04A0>)

MSG « message-modify ED:1 (<Instance-a> <Pointer-009F04A0>)

TRUE

CLIPS> (unwatch all)

CLIPS>

The active message modify instance function uses the message modify message to change the values of the instance. Object pattern matching occurs as slot modifications are being performed.

Syntax

(active-message-modify-instance <instance> <slot-override>*)

Four functions are provided for duplicating instances. These functions allow instance duplication and slot updates to be performed in blocks without requiring a series of put  messages. Each of these functions return the instance name of the new duplicated instance if successful, otherwise the symbol FALSE is returned.

Each of the duplicate functions can optionally specify the name of the instance to which the old instance will be copied. If the name is not specified, the function will generate the name using the (gensym*) function. If the target instance already exists, it will be deleted directly or with a delete message depending on which function was called.

The duplicate instance function uses the direct duplicate message to change the values of the instance. Object pattern matching is delayed until all of the slot modifications have been performed.

Syntax

(duplicate-instance <instance> [to <instance name>]

<slot-override>*)

Example

CLIPS> (clear)

CLIPS> (setgen 1)

1

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (create-accessor write))

(slot bar (create-accessor write)))

CLIPS> (make-instance a of A (foo 0) (bar 4))

[a]

CLIPS> (watch all)

CLIPS> (duplicate-instance a)

MSG » direct-duplicate ED:1 (<Instance-a> [gen1] <Pointer-00000000>)

HND » direct-duplicate primary in class USER

ED:1 (<Instance-a> [gen1] <Pointer-00000000>)

==> instance [gen1] of A

::= local slot foo in instance gen1 ← 0

::= local slot bar in instance gen1 ← 4

HND « direct-duplicate primary in class USER

ED:1 (<Instance-a> [gen1] <Pointer-00000000>)

MSG « direct-duplicate ED:1 (<Instance-a> [gen1] <Pointer-00000000>)

[gen1]

CLIPS> (unwatch all)

CLIPS>

The active duplicate instance function uses the direct duplicate message to change the values of the instance. Object pattern matching occurs as slot modifications are being performed.

Syntax

(active-duplicate-instance <instance> [to <instance name>]

<slot-override>*)

The message duplicate instance function uses the message duplicate message to change the values of the instance. Object pattern matching is delayed until all of the slot modifications have been performed.

Syntax

(message-duplicate-instance <instance> [to <instance name>]

<slot-override>*)

Example

CLIPS> (clear)

CLIPS>

(defclass A (is-a USER)

(role concrete)

(slot foo (create-accessor write))

(slot bar (create-accessor write)))

CLIPS> (make-instance a of A (foo 0) (bar 4))

[a]

CLIPS> (make-instance b of A)

[b]

CLIPS> (watch all)

CLIPS> (message-duplicate-instance a to b (bar 6))

MSG » message-duplicate ED:1 (<Instance-a> [b] <Pointer-009F04A0>)

HND » message-duplicate primary in class USER

ED:1 (<Instance-a> [b] <Pointer-009F04A0>)

MSG » delete ED:2 (<Instance-b>)

HND » delete primary in class USER

ED:2 (<Instance-b>)

⇐= instance [b] of A

HND « delete primary in class USER

ED:2 (<Stale Instance-b>)

MSG « delete ED:2 (<Stale Instance-b>)

==> instance [b] of A

MSG » create ED:2 (<Instance-b>)

HND » create primary in class USER

ED:2 (<Instance-b>)

HND « create primary in class USER

ED:2 (<Instance-b>)

MSG « create ED:2 (<Instance-b>)

MSG » put-bar ED:2 (<Instance-b> 6)

HND » put-bar primary in class A

ED:2 (<Instance-b> 6)

::= local slot bar in instance b ← 6

HND « put-bar primary in class A

ED:2 (<Instance-b> 6)

MSG « put-bar ED:2 (<Instance-b> 6)

MSG » put-foo ED:2 (<Instance-b> 0)

HND » put-foo primary in class A

ED:2 (<Instance-b> 0)

::= local slot foo in instance b ← 0

HND « put-foo primary in class A

ED:2 (<Instance-b> 0)

MSG « put-foo ED:2 (<Instance-b> 0)

MSG » init ED:2 (<Instance-b>)

HND » init primary in class USER

ED:2 (<Instance-b>)

HND « init primary in class USER

ED:2 (<Instance-b>)

MSG « init ED:2 (<Instance-b>)

HND « message-duplicate primary in class USER

ED:1 (<Instance-a> [b] <Pointer-009F04A0>)

MSG « message-duplicate ED:1 (<Instance-a> [b] <Pointer-009F04A0>)

[b]

CLIPS> (unwatch all)

CLIPS>

The active message duplicate instance function uses the message duplicate message to change the values of the instance. Object pattern matching occurs as slot modifications are being performed.

Syntax

(active-message-duplicate-instance <instance>

[to <instance name>]

<slot-override>*)

COOL provides a useful query system for determining and performing actions on sets of instances of user defined classes that satisfy user defined queries. The instance query system in COOL provides six functions, each of which operate on instance sets determined by user defined criteria:

| Function | Purpose |

Explanations on how to form instance set templates, queries and actions immediately follow, for these definitions are common to all of the query functions. The specific details of each query function will then be given. The following is a complete example of an instance set query function:

Example

For all of the examples in this section, assume that the commands below have already been entered:

Example

CLIPS>

(defclass PERSON (is-a USER)

(role abstract)

(slot sex (access read-only)

(storage shared))

(slot age (type NUMBER)

(visibility public)))

CLIPS>

(defmessage-handler PERSON put-age (?value)

(dynamic-put age ?value))

CLIPS>

(defclass FEMALE (is-a PERSON)

(role abstract)

(slot sex (source composite)

(default female)))

CLIPS>

(defclass MALE (is-a PERSON)

(role abstract)

(slot sex (source composite)

(default male)))

CLIPS>

(defclass GIRL (is-a FEMALE)

(role concrete)

(slot age (source composite)

(default 4)

(range 0.0 17.9)))

CLIPS>

(defclass WOMAN (is-a FEMALE)

(role concrete)

(slot age (source composite)

(default 25)

(range 18.0 100.0)))

CLIPS>

(defclass BOY (is-a MALE)

(role concrete)

(slot age (source composite)

(default 4)

(range 0.0 17.9)))

CLIPS>

(defclass MAN (is-a MALE)

(role concrete)

(slot age (source composite)

(default 25)

(range 18.0 100.0)))

CLIPS>

(definstances PEOPLE

(Man-1 of MAN (age 18))

(Man-2 of MAN (age 60))

(Woman-1 of WOMAN (age 18))

(Woman-2 of WOMAN (age 60))

(Woman-3 of WOMAN)

(Boy-1 of BOY (age 8))

(Boy-2 of BOY)

(Boy-3 of BOY)

(Boy-4 of BOY)

(Girl-1 of GIRL (age 8))

(Girl-2 of GIRL))

CLIPS> (reset)

CLIPS>

An instance set is an ordered collection of instances. Each instance set member is an instance of a set of classes, called class restrictions, defined by the user. The class restrictions can be different for each instance set member. The query functions use instance set templates to generate instance sets. An instance set template is a set of instance set member variables and their associated class restrictions. Instance set member variables reference the corresponding members in each instance set which matches a template. Variables may be used to specify the classes for the instance set template, but if the constant names of the classes are specified, the classes must already be defined. Module specifiers may be included with the class names; the classes need not be in scope of the current module.

Syntax

<instance-set-template>

::= (<instance-set-member-template>+)

<instance-set-member-template>

::= (<instance-set-member-variable> <class-restrictions>)

<instance-set-member-variable> ::= <single-field-variable>

<class-restrictions> ::= <class-name-expression>+

Example

One instance set template might be the ordered pairs of boys or men and girls or women.

((?man-or-boy BOY MAN) (?woman-or-girl GIRL WOMAN))

This instance set template could have been written equivalently:

((?man-or-boy MALE) (?woman-or-girl FEMALE))

Instance set member variables (e.g. ?man or boy) are bound to instance names.

COOL uses straightforward permutations to generate instance sets that match an instance set template from the actual instances in the system. The rules are as follows:

1) When there is more than one member in an instance set template, vary the rightmost members first.

2) When there is more than one class that an instance set member can be, iterate through the classes from left to right.

3) Examine instances of a class in the order that they were defined.

3a) Recursively examine instances of subclasses in the order that the subclasses were defined. If the specified query class was in scope of the current module, then only subclasses which are also in scope will be examined. Otherwise, only subclasses which are in scope of the module to which the query class belongs will be examined.

Example

For the instance set template given in section 9.7.1, thirty instance sets would be generated in the following order:

| 1. [Boy-1] [Girl-1] 2. [Boy-1] [Girl-2] 3. [Boy-1] [Woman-1] 4. [Boy-1] [Woman-2] 5. [Boy-1] [Woman-3] 6. [Boy-2] [Girl-1] 7. [Boy-2] [Girl-2] 8. [Boy-2] [Woman-1] 9. [Boy-2] [Woman-2] 10. [Boy-2] [Woman-3] 11. [Boy-3] [Girl-1] 12. [Boy-3] [Girl-2] 13 [Boy-3] [Woman-1] 14. [Boy-3] [Woman-2] 15. [Boy-3] [Woman-3]
| 16. [Boy-4] [Girl-1] 17. [Boy-4] [Girl-2] 18. [Boy-4] [Woman-1] 19. [Boy-4] [Woman-2] 20. [Boy-4] [Woman-3] 21. [Man-1] [Girl-1] 22. [Man-1] [Girl-2] 23. [Man-1] [Woman-1] 24. [Man-1] [Woman-2] 25. [Man-1] [Woman-3] 26. [Man-2] [Girl-1] 27. [Man-2] [Girl-2] 28. [Man-2] [Woman-1] 29. [Man-2] [Woman-2] 30. [Man-2] [Woman-3]
|

Example

Consider the following instance set template:

((?f1 FEMALE) (?f2 FEMALE))

Twenty five instance sets would be generated in the following order:

| 1. [Girl-1] [Girl-1] 2. [Girl-1] [Girl-2] 3. [Girl-1] [Woman-1] 4. [Girl-1] [Woman-2] 5. [Girl-1] [Woman-3] 6. [Girl-2] [Girl-1] 7. [Girl-2] [Girl-2] 8. [Girl-2] [Woman-1] 9. [Girl-2] [Woman-2] 10.[Girl-2] [Woman-3] 11.[Woman-1] [Girl-1] 12.[Woman-1] [Girl-2] 13.[Woman-1] [Woman-1] | 14.[Woman-1] [Woman-2] 15.[Woman-1] [Woman-3] 16.[Woman-2] [Girl-1] 17.[Woman-2] [Girl-2] 18.[Woman-2] [Woman-1] 19.[Woman-2] [Woman-2] 20.[Woman-2] [Woman-3] 21.[Woman-3] [Girl-1] 22.[Woman-3] [Girl-2] 23.[Woman-3] [Woman-1] 24.[Woman-3] [Woman-2] 25.[Woman-3] [Woman-3] |

The instances of class GIRL are examined before the instances of class WOMAN because GIRL was defined before WOMAN.

A query is a user defined boolean expression applied to an instance set to determine if the instance set meets further user defined restrictions. If the evaluation of this expression for an instance set is anything but the symbol FALSE, the instance set is said to satisfy the query.

Syntax

<query> ::= <boolean-expression>

Example

Continuing the previous example, one query might be that the two instances in an ordered pair have the same age.

(= (send ?man-or-boy get-age) (send ?woman-or-girl get-age))

Within a query, slots of instance set members can be directly read with a shorthand notation similar to that used in message handlers (see section 9.4.2). If message passing is not explicitly required for reading a slot (i.e. there are no accessor daemons for reads), then this second method of slot access should be used, for it gives a significant performance benefit.

Syntax

<instance-set-member-variable>:<slot-name>

Example

The previous example could be rewritten as:

(= ?man-or-boy:age ?woman-or-girl:age)

Since only instance sets which satisfy a query are of interest, and the query is evaluated for all possible instance sets, the query should not have any side effects.

A distributed action is a user defined expression evaluated for each instance set which satisfies a query. Unlike queries, distributed actions must use messages to read slots of instance set members. If more than one action is required, use the progn function (see section 12.6.5) to group them.

Action Syntax

<action> ::= <expression>

Example

Continuing the previous example, one distributed action might be to simply print out the ordered pair to the screen.

(printout t ”(“ ?man-or-boy ”,“ ?woman-or-girl ”)“ crlf)

An instance set query function can be called from anywhere that a regular function can be called. If a variable from an outer scope is not masked by an instance set member variable, then that variable may be referenced within the query and action. In addition, rebinding variables within an instance set function action is allowed. However, attempts to rebind instance set member variables will generate errors. Binding variables is not allowed within a query. Instance set query functions can be nested.

Example

CLIPS>

(deffunction count-instances (?class)

(bind ?count 0)

(do-for-all-instances ((?ins ?class)) TRUE

(bind ?count (+ ?count 1)))

?count)

CLIPS>

(deffunction count-instances-2 (?class)

(length (find-all-instances ((?ins ?class)) TRUE)))

CLIPS> (count-instances WOMAN)

3

CLIPS> (count-instances-2 BOY)

4

CLIPS>

Instance set member variables are only in scope within the instance set query function. Attempting to use instance set member variables in an outer scope will generate an error.

Example

CLIPS>

(deffunction last-instance (?class)

(any-instancep ((?ins ?class)) TRUE)

?ins)

[PRCCODE3] Undefined variable ins referenced in deffunction.

ERROR:

(deffunction last-instance

(?class)

(any-instancep ((?ins ?class))

TRUE)

?ins

)

CLIPS>

If an error occurs during an instance set query function, the function will be immediately terminated and the return value will be the symbol FALSE.

The functions break and return are now valid inside the action of the instance set query functions do for instance, do for all instances and delayed do for all instances. The return function is only valid if it is applicable in the outer scope, whereas the break function actually halts the query.

The instance query system in COOL provides six functions. For a given set of instances, all six query functions will iterate over these instances in the same order (see section 9.7.2). However, if a particular instance is deleted and recreated, the iteration order will change.

This function applies a query to each instance set which matches the template. If an instance set satisfies the query, then the function is immediately terminated, and the return value is the symbol TRUE. Otherwise, the return value is the symbol FALSE.

Syntax

(any instancep <instance-set-template> <query>)

Example

Are there any men over age 30?

CLIPS> (any-instancep ((?man MAN)) (> ?man:age 30))

TRUE

CLIPS>

This function applies a query to each instance set which matches the template. If an instance set satisfies the query, then the function is immediately terminated, and the instance set is returned in a multifield value. Otherwise, the return value is a zero length multifield value. Each field of the multifield value is an instance name representing an instance set member.

Syntax

(find instance <instance-set-template> <query>)

Example

Find the first pair of a man and a woman who have the same age.

CLIPS>

(find-instance ((?m MAN) (?w WOMAN)) (= ?m:age ?w:age))

([Man-1] [Woman-1])

CLIPS>

This function applies a query to each instance set which matches the template. Each instance set which satisfies the query is stored in a multifield value. This multifield value is returned when the query has been applied to all possible instance sets. If there are n instances in each instance set, and m instance sets satisfied the query, then the length of the returned multifield value will be n * m. The first n fields correspond to the first instance set, and so on. Each field of the multifield value is an instance name representing an instance set member. The multifield value can consume a large amount of memory due to permutational explosion, so this function should be used judiciously.

Syntax

(find all instances <instance-set-template> <query>)

Example

Find all pairs of a man and a woman who have the same age.

CLIPS>

(find-all-instances ((?m MAN) (?w WOMAN)) (= ?m:age ?w:age))

([Man-1] [Woman-1] [Man-2] [Woman-2])

CLIPS>

This function applies a query to each instance set which matches the template. If an instance set satisfies the query, the specified action is executed, and the function is immediately terminated. The return value is the evaluation of the action. If no instance set satisfied the query, then the return value is the symbol FALSE.

Syntax

(do for instance <instance-set-template> <query> <action>*)

Example

Print out the first triplet of different people that have the same age. The calls to neq in the query eliminate the permutations where two or more members of the instance set are identical.

CLIPS>

(do-for-instance ((?p1 PERSON) (?p2 PERSON) (?p3 PERSON))

(and (= ?p1:age ?p2:age ?p3:age)

(neq ?p1 ?p2)

(neq ?p1 ?p3)

(neq ?p2 ?p3))

(printout t ?p1 ” “ ?p2 ” “ ?p3 crlf))

[Girl-2] [Boy-2] [Boy-3]

CLIPS>

This function applies a query to each instance set which matches the template. If an instance set satisfies the query, the specified action is executed. The return value is the evaluation of the action for the last instance set which satisfied the query. If no instance set satisfied the query, then the return value is the symbol FALSE.

Syntax

(do for all instances <instance-set-template> <query> <action>*)

Example

Print out all triplets of different people that have the same age. The calls to str compare limit the instance sets which satisfy the query to combinations instead of permutations. Without these restrictions, two instance sets which differed only in the order of their members would both satisfy the query.

CLIPS>

(do-for-all-instances ((?p1 PERSON) (?p2 PERSON) (?p3 PERSON))

(and (= ?p1:age ?p2:age ?p3:age)

(> (str-compare ?p1 ?p2) 0)

(> (str-compare ?p2 ?p3) 0))

(printout t ?p1 ” “ ?p2 ” “ ?p3 crlf))

[Girl-2] [Boy-3] [Boy-2]

[Girl-2] [Boy-4] [Boy-2]

[Girl-2] [Boy-4] [Boy-3]

[Boy-4] [Boy-3] [Boy-2]

CLIPS>

This function is similar to do for all instances except that it groups all instance sets which satisfy the query into an intermediary multifield value. If there are no instance sets which satisfy the query, then the function returns the symbol FALSE. Otherwise, the specified action is executed for each instance set in the multifield value, and the return value is the evaluation of the action for the last instance set to satisfy the query. The intermediary multifield value is discarded. This function can consume large amounts of memory in the same fashion as find all instances. This function should be used in lieu of do for all instances when the action applied to one instance set would change the result of the query for another instance set (unless that is the desired effect).

Syntax

(delayed do for all instances <instance-set-template>

<query> <action>*)

Example

Delete all boys with the greatest age. The test in this case is another query function which determines if there are any older boys than the one currently being examined. The action needs to be delayed until all boys have been processed, or the greatest age will decrease as the older boys are deleted.

CLIPS> (watch instances)

CLIPS>

(delayed-do-for-all-instances ((?b1 BOY))

(not (any-instancep ((?b2 BOY))

(> ?b2:age ?b1:age)))

(send ?b1 delete))

⇐= instance [Boy-1] of BOY

TRUE

CLIPS> (unwatch instances)

CLIPS> (reset)

CLIPS> (watch instances)

CLIPS>

(do-for-all-instances ((?b1 BOY))

(not (any-instancep ((?b2 BOY))

(> ?b2:age ?b1:age)))

(send ?b1 delete))

⇐= instance [Boy-1] of BOY

⇐= instance [Boy-2] of BOY

⇐= instance [Boy-3] of BOY

⇐= instance [Boy-4] of BOY

TRUE

CLIPS> (unwatch instances)

CLIPS>

CLIPS provides support for the modular development and execution of knowledge bases with the defmodule construct. CLIPS modules allow a set of constructs to be grouped together such that explicit control can be maintained over restricting the access of the constructs by other modules. This type of control is similar to global and local scoping used in languages such as C or Ada (note, however, that the global scoping used by CLIPS is strictly hierarchical and in one direction only—if module A can see constructs from module B, then it is not possible for module B to see any of module A’s constructs). By restricting access to deftemplate and defclass constructs, modules can function as blackboards, permitting only certain facts and instances to be seen by other modules. Modules are also used by rules to provide execution control.

Modules are defined using the defmodule construct.

Syntax

(defmodule <module-name> [<comment>]

<port-spec>*)

<port-specification> ::= (export <port-item>) |

(import <module-name> <port-item>)

<port-item> ::= ?ALL |

?NONE |

<port-construct> ?ALL |

<port-construct> ?NONE |

<port-construct> <construct-name>+

<port-construct> ::= deftemplate | defclass |

defglobal | deffunction |

defgeneric

A defmodule cannot be redefined or even deleted once it is defined (with the exception of the MAIN module which can be redefined once). The only way to delete a module is with the clear command. Upon startup and after a clear command, CLIPS automatically constructs the following defmodule.

(defmodule MAIN)

All of the predefined system classes (see section 9.2) belong to the MAIN module. However, it is not necessary to import or export the system classes; they are always in scope. Discounting the previous exception, the predefined MAIN module does not import or export any constructs. However, unlike other modules, the MAIN module can be redefined once after startup or a clear command.

Example

(defmodule FOO

(import BAR ?ALL)

(import YAK deftemplate ?ALL)

(import GOZ defglobal x y z)

(export defgeneric +)

(export defclass ?ALL))

The module in which a constructs is placed can be specified when the construct is defined. The deffacts, deftemplate, defrule, deffunction, defgeneric, defclass, and definstances constructs all specify the module for the construct by including it as part of the name. The module of a defglobal construct is indicated by specifying the module name after the defglobal keyword. The module of a defmessage handler is specified as part of the class specifier. The module of a defmethod is specified as part of the generic function specifier. For example, the following constructs would be placed in the DETECTION module.

(defrule DETECTION::Find-Fault

(sensor (name ?name) (value bad))

⇒

(assert (fault (name ?name))))

(defglobal DETECTION ?*count* = 0)

(defmessage-handler DETECTION::COMPONENT get-charge ()

(* ?self:flux ?self:flow))

(defmethod DETECTION::+ ((?x STRING) (?y STRING))

(str-cat ?x ?y))

Example

CLIPS> (clear)

CLIPS> (defmodule A)

CLIPS> (defmodule B)

CLIPS> (defrule foo ⇒)

CLIPS> (defrule A::bar ⇒)

CLIPS> (list-defrules)

bar

For a total of 1 defrule.

CLIPS> (set-current-module B)

A

CLIPS> (list-defrules)

foo

For a total of 1 defrule.

CLIPS>

Commands such as undefrule and ppdefrule require the name of a construct on which to operate. In previous versions of CLIPS, constructs were always referred to by their name only, so it was sufficient just to pass the name of the construct to these commands. With modules, however, it is possible to have a construct with the same name in two different modules. The modules associated with a name can be specified either explicitly or implicitly. To explicitly specify a name’s module the module name (a symbol) is listed followed by two colons, ::, and then the name is listed. The module name followed by :: is referred to as a module specifier. For example, MAIN::find stuff, refers to the find stuff construct in the MAIN module. A module can also be implicitly specified since there is always a “current” module. The current module is changed whenever a defmodule construct is defined or the set current module function is used. The MAIN module is automatically defined by CLIPS and by default is the current module when CLIPS is started or after a clear command is issued. Thus the name find stuff would implicitly have the MAIN module as its module when CLIPS is first started.

CLIPS> (clear)

CLIPS> (defmodule A)

CLIPS> (defglobal A ?*x* = 0)

CLIPS> (defmodule B)

CLIPS> (defglobal B ?*y* = 1)

CLIPS> (ppdefglobal y)

(defglobal B ?*y* = 1)

CLIPS> (ppdefglobal B::y)

(defglobal B ?*y* = 1)

CLIPS> (ppdefglobal x)

[PRNTUTIL1] Unable to find defglobal x

CLIPS> (ppdefglobal A::x)

(defglobal A ?*x* = 0)

CLIPS>

Unless specifically exported and imported, the constructs of one module may not be used by another module. A construct is said to be visible or within scope of a module if that construct can be used by the module. For example, if module B wants to use the foo deftemplate defined in module A, then module A must export the foo deftemplate and module B must import the foo deftemplate from module A.

CLIPS> (clear)

CLIPS> (defmodule A)

CLIPS> (deftemplate A::foo (slot x))

CLIPS> (defmodule B)

CLIPS> (defrule B::bar (foo (x 3)) ⇒)

[PRNTUTIL2] Syntax Error: Check appropriate syntax for defrule

ERROR:

(defrule B::bar

(foo (

CLIPS> (clear)

CLIPS> (defmodule A (export deftemplate foo))

CLIPS> (deftemplate A::foo (slot x))

CLIPS> (defmodule B (import A deftemplate foo))

CLIPS> (defrule B::bar (foo (x 3)) ⇒)

CLIPS>

CLIPS will not allow a module or other construct to be defined that causes two constructs with the same name to be visible within the same module.

The export specification in a defmodule definition is used to indicate which constructs will be accessible to other modules importing from the module being defined. Only deftemplates, defclasses, defglobals, deffunctions, and defgenerics may be exported. A module may export any valid constructs that are visible to it (not just constructs that it defines).

There are three different types of export specifications. First, a module may export all valid constructs that are visible to it. This accomplished by following the export keyword with the ?ALL keyword. Second, a module may export all valid constructs of a particular type that are visible to it. This accomplished by following the export keyword with the name of the construct type followed by the ?ALL keyword. Third, a module may export specific constructs of a particular type that are visible to it. This accomplished by following the export keyword with the name of the construct type followed by the name of one or more visible constructs of the specified type. In the following code, defmodule A exports all of its constructs; defmodule B exports all of its deftemplates; and defmodule C exports the foo, bar, and yak defglobals.

(defmodule A (export ?ALL))

(defmodule B (export deftemplate ?ALL))

(defmodule C (export defglobal foo bar yak))

The ?NONE keyword may be used in place of the ?ALL keyword to indicate either that no constructs are exported from a module or that no constructs of a particular type are exported from a module.

Defmethods and defmessage handlers cannot be explicitly exported. Exporting a defgeneric automatically exports all associated defmethods. Exporting a defclass automatically exports all associated defmessage handlers. Deffacts, definstances, and defrules cannot be exported.

The import specification in a defmodule definition is used to indicate which constructs the module being defined will use from other modules. Only deftemplates, defclasses, defglobals, deffunctions, and defgenerics may be imported.

There are three different types of import specifications. First, a module may import all valid constructs that are visible to a specified module. This accomplished by following the import keyword with a module name followed by the ?ALL keyword. Second, a module may import all valid constructs of a particular type that are visible to a specified module. This accomplished by following the import keyword with a module name followed by the name of the construct type followed by the ?ALL keyword. Third, a module may import specific constructs of a particular type that are visible to it. This accomplished by following the import keyword with a module name followed by the name of the construct type followed by the name of one or more visible constructs of the specified type. In the following code, defmodule A imports all of module D’s constructs; defmodule B imports all of module D’s deftemplates; and defmodule C imports the foo, bar, and yak defglobals from module D.

(defmodule A (import D ?ALL))

(defmodule B (import D deftemplate ?ALL))

(defmodule C (import D defglobal foo bar yak))

The ?NONE keyword may be used in place of the ?ALL keyword to indicate either that no constructs are imported from a module or that no constructs of a particular type are imported from a module.

Defmethods and defmessage handlers cannot be explicitly imported. Importing a defgeneric automatically imports all associated defmethods. Importing a defclass automatically imports all associated defmessage handlers. Deffacts, definstances, and defrules cannot be imported.

A module must be defined before it is used in an import specification. In addition, if specific constructs are listed in the import specification, they must already be defined in the module exporting them. It is not necessary to import a construct from the module in which it is defined in order to use it. A construct can be indirectly imported from a module that directly imports and then exports the module to be used.

Facts and instances are “owned” by the module in which their corresponding deftemplate or defclass is defined, not by the module which creates them. Facts and instances are thus visible only to those modules which import the corresponding deftemplate or defclass. This allows a knowledge base to be partitioned such that rules and other constructs can only “see” those facts and instances which are of interest to them. Note that the initial-fact deftemplate and the INITIAL OBJECT defclass must explicitly be imported from the MAIN module. Rules which have the initial-fact or initial-object pattern added to their LHS (such as a rule thats first CE is a not CE) will not be activated unless the corresponding construct for the pattern is imported.

Example

CLIPS> (clear)

CLIPS> (defmodule A (export deftemplate foo bar))

CLIPS> (deftemplate A::foo (slot x))

CLIPS> (deftemplate A::bar (slot y))

CLIPS> (deffacts A::info (foo (x 3)) (bar (y 4)))

CLIPS> (defmodule B (import A deftemplate foo))

CLIPS> (reset)

CLIPS> (facts A)

f-1 (foo (x 3))

f-2 (bar (y 4))

For a total of 2 facts.

CLIPS> (facts B)

f-1 (foo (x 3))

For a total of 1 fact.

CLIPS>

Instance names are required to be unique within a particular module, but multiple instances of the same name may be in scope at any one time. The syntax of instance names has been extended to allow module specifications (note that the left and right brackets in bold are to be typed and do not indicate an optional part of the syntax).

Syntax

<instance-name> ::= [<symbol>] |

[::<symbol>] |

[<module>::symbol>]

Specifying just a symbol as the instance name, such as [Rolls Royce], will search for the instance in the current module only. Specifying only the :: before the name, such as [::Rolls Royce], will search for the instance first in the current module and then recursively in the imported modules as defined in the module definition. Specifying both a symbol and a module name, such as [CARS::Rolls Royce], searches for the instance only in the specified module. Regardless of which format is specified, the class of the instance must be in scope of the current module in order for the instance to be found.

Each module has its own pattern matching network for its rules and its own agenda. When a run command is given, the agenda of the module which is the current focus is executed (note that the reset and clear commands make the MAIN module the current focus). Rule execution continues until another module becomes the current focus, no rules are left on the agenda, or the return function is used from the RHS of a rule. Whenever a module that was focused on runs out of rules on its agenda, the current focus is removed from the focus stack and the next module on the focus stack becomes the current focus. Before a rule executes, the current module is changed to the module in which the executing rule is defined (the current focus). The current focus can be changed by using the focus command. See sections 5.2, 5.4.10.2, 12.12, and 13.12 for more details.

Example

CLIPS> (clear)

CLIPS> (defmodule MAIN (export ?ALL))

CLIPS>

(defrule MAIN::focus-example

⇒

(printout t “Firing rule in module MAIN.” crlf)

(focus A B))

CLIPS>

(defmodule A (import MAIN deftemplate initial-fact))

CLIPS>

(defrule A::example-rule

⇒

(printout t “Firing rule in module A.” crlf))

CLIPS>

(defmodule B (import MAIN deftemplate initial-fact))

CLIPS>

(defrule B::example-rule

⇒

(printout t “Firing rule in module B.” crlf))

CLIPS> (reset)

CLIPS> (run)

Firing rule in module MAIN.

Firing rule in module A.

Firing rule in module B.

CLIPS>

This section describes the constraint attributes that can be associated with deftemplates and defclasses so that type checking can be performed on slot values when template facts and instances are created. The constraint information is also analyzed for the patterns on the LHS of a rule to determine if the specified constraints prevent the rule from ever firing.

Two types of constraint checking are supported: static and dynamic. When static constraint checking is enabled, constraint violations are checked when function calls and constructs are parsed. This includes constraint checking between patterns on the LHS of a rule when variables are used in more than one slot. When dynamic constraint checking is enabled, newly created data objects (such as deftemplate facts and instances) have their slot values checked for constraint violations. Essentially, static constraint checking occurs when a CLIPS program is loaded and dynamic constraint checking occurs when a CLIPS program is running. By default, static constraint checking is enabled and dynamic constraint checking is disabled. The default behavior can be changed by using the set static constraint checking and set dynamic constraint checking functions.

Unless dynamic constraint checking is enabled, constraint information associated with constructs is not saved when a binary image is created using the bsave command.

The general syntax for constraint attributes is shown following.

Syntax

<constraint-attribute> ::= <type-attribute> |

<allowed-constant-attribute> |

<range-attribute> |

<cardinality-attribute>

The type attribute allows the types of values to be stored in a slot to be restricted.

Syntax

<type-attribute> ::= (type <type-specification>)

<type-specification> ::= <allowed-type>+ | ?VARIABLE

<allowed-type>

::= SYMBOL | STRING | LEXEME |

INTEGER | FLOAT | NUMBER |

INSTANCE-NAME | INSTANCE-ADDRESS | INSTANCE |

EXTERNAL-ADDRESS | FACT-ADDRESS

Using NUMBER for this attribute is equivalent to using both INTEGER and FLOAT. Using LEXEME for this attribute is equivalent to using both SYMBOL and STRING. Using INSTANCE for this attribute is equivalent to using both INSTANCE NAME and INSTANCE ADDRESS. ?VARIABLE allows any type to be stored.

The allowed constant attributes allow the constant values of a specific type which can be stored in a slot to be restricted. The list of values provided should either be a list of constants of the specified type or the keyword ?VARIABLE which means any constant of that type is allowed. The allowed values attribute allows the slot to be restricted to a specific set of values (encompassing all types). Note the difference between using the attribute (allowed symbols red green blue) and (allowed values red green blue). The allowed symbols attribute states that if the value is of type symbol, then its value must be one of the listed symbols. The allowed values attribute completely restricts the allowed values to the listed values.

Syntax

<allowed-constant-attribute>

::= (allowed-symbols <symbol-list>) |

(allowed-strings <string-list>) |

(allowed-lexemes <lexeme-list> |

(allowed-integers <integer-list>) |

(allowed-floats <float-list>) |

(allowed-numbers <number-list>) |

(allowed-instance-names <instance-list>) |

(allowed-values <value-list>)

<symbol-list> ::= <symbol>+ | ?VARIABLE

<string-list> ::= <string>+ | ?VARIABLE

<lexeme-list> ::= <lexeme>+ | ?VARIABLE

<integer-list> ::= <integer>+ | ?VARIABLE

<float-list> ::= <float>+ | ?VARIABLE

<number-list> ::= <number>+ | ?VARIABLE

<instance-name-list> ::= <instance-name>+ | ?VARIABLE

<value-list> ::= <constant>+ | ?VARIABLE

Specifying the allowed lexemes attribute is equivalent to specifying constant restrictions on both symbols and strings. A string or symbol must match one of the constants in the attribute list. Type conversion from symbols to strings and strings to symbols is not performed. Similarly, specifying the allowed numbers attribute is equivalent to specifying constant restrictions on both integers and floats. In CLIPS 5.1, type conversion of integers to floats and floats to integers was performed when using the allowed numbers attribute (thus using allowed numbers was not equivalent to using both the allowed integers and allowed floats attributes together). In CLIPS 6.0, this type conversion is now longer performed. The allowed instances attribute found in CLIPS 5.1 is no longer supported. The allowed instance names attribute should be used in its place.

The range attribute allows a numeric range to be specified for a slot when a numeric value is used in that slot. If a numeric value is not used in that slot, then no checking is performed.

Syntax

<range-attribute> ::= (range <range-specification>

<range-specification>)

<range-specification> ::= <number> | ?VARIABLE

Either integers or floats can be used in the range specification with the first value to the range attribute signifying the minimum allowed value and the second value signifying the maximum value. Integers will be temporarily converted to floats when necessary to perform range comparisons. If the keyword ?VARIABLE is used for the minimum value, then the minimum value is negative infinity ( ∞). If the keyword ?VARIABLE is used for the maximum value, then the maximum value is positive infinity (+∞). The range attribute cannot be used in conjunction with the allowed values, allowed numbers, allowed integers, or allowed floats attributes.

The cardinality attribute restricts the number of fields which can be stored in a multifield slot. This attribute can not be used with a single field slot.

Syntax

<cardinality-attribute>

::= (cardinality <cardinality-specification>

<cardinality-specification>)

<cardinality-specification> ::= <integer> | ?VARIABLE

Only integers can be used in the cardinality specification with the first value to the cardinality attribute signifying the minimum number of fields which can be stored in the slot and the second value signifying the maximum number of fields which can be stored in the slot. If the keyword ?VARIABLE is used for the minimum value, then the minimum cardinality is zero. If the keyword ?VARIABLE is used for the maximum value, then the maximum cardinality is positive infinity (+∞). If the cardinality is not specified for a multifield slot, then it is assumed to be zero to infinity.

The min number of elements and max number of elements attributes found in CLIPS 5.1 are no longer supported. The cardinality attribute should be used in their place.

Default values for deftemplate and instance slots are automatically derived from the constraints for the slots if an explicit default value is not specified. The following rules are used (in order) to determine the default value for a slot with an unspecified default value.

1) The default type for the slot is chosen from the list of allowed types for the slot in the following order of precedence: SYMBOL, STRING, INTEGER, FLOAT, INSTANCE NAME, INSTANCE ADDRESS, FACT ADDRESS, EXTERNAL ADDRESS.

2) If the default type has an allowed constant restriction specified (such as the allowed-integers attribute for the INTEGER type), then the first value specified in the allowed constant attribute is chosen as the default value.

3) If the default value was not specified by step 2 and the default type is INTEGER or FLOAT and the range attribute is specified, then the minimum range value is used as the default value if it is not ?VARIABLE, otherwise, the maximum range value is used if it is not ?VARIABLE.

4) If the default value was not specified by step 2 or 3, then the default default value is used. This value is nil for type SYMBOL, ”“ for type STRING, 0 for type INTEGER, 0.0 for type FLOAT, [nil] for type INSTANCE NAME, a pointer to a dummy instance for type INSTANCE ADDRESS, a pointer to a dummy fact for type FACT ADDRESS, and the NULL pointer for type EXTERNAL ADDRESS.

5) If the default value is being derived for a single field slot, then the default value derived from steps 1 through 4 is used. The default value for a multifield slot is a multifield value of length zero. However, if the multifield slot has a minimum cardinality greater than zero, then a multifield value with a length of the minimum cardinality is created and the default value which would be used for a single field slot is stored in each field of the multifield value.

The following examples illustrate some of the types of constraint violations that CLIPS can detect.

Example 1

CLIPS>

(deftemplate bar

(slot a (type SYMBOL INTEGER))

(slot b (type INTEGER FLOAT))

(slot c (type SYMBOL STRING)))

CLIPS>

(defrule error

(bar (a ?x))

(bar (b ?x))

(bar (c ?x))

⇒)

[RULECSTR1] Variable ?x in CE #3 slot c

has constraint conflicts which make the pattern unmatchable

ERROR:

(defrule error-4

(bar (a ?x))

(bar (b ?x))

(bar (c ?x))

⇒)

CLIPS>

The first occurrence of the variable ?x in slot a of the first pattern restricts its allowed types to either a symbol or integer. The second occurrence of ?x in slot b of the second pattern further restricts its allowed types to only integers. The final occurence of ?x in the third pattern generates an error because slot c expects ?x to be either a symbol of a string, but its only allowed type is an integer.

Example 2

CLIPS>

(deftemplate foo (multislot x (cardinality ?VARIABLE 3)))

CLIPS>

(deftemplate bar (multislot y (cardinality ?VARIABLE 2)))

CLIPS>

(deftemplate woz (multislot z (cardinality 7 ?VARIABLE)))

CLIPS>

(defrule error

(foo (x $?x))

(bar (y $?y))

(woz (z $?x $?y))

⇒)

[CSTRNCHK1] The group of restrictions found in CE #3

do not satisfy the cardinality restrictions for slot z

ERROR:

(defrule error

(foo (x $?x))

(bar (y $?y))

(woz (z $?x $?y))

⇒)

CLIPS>

The variable ?x, found in the first pattern, can have a maximum of two fields. The variable ?y, found in the second pattern, can have a maximum of three fields. Added together, both variables have a maximum of five fields. Since slot z in the the third pattern has a minimum cardinality of seven, the variables ?x and ?y cannot satisfy the minimum cardinality restriction for this slot.

Example 3

CLIPS> (deftemplate foo (slot x (type SYMBOL)))

CLIPS>

(defrule error

(foo (x ?x))

(test (> ?x 10))

⇒)

[RULECSTR2] Previous variable bindings of ?x caused the type restrictions for argument #1 of the expression (> ?x 10)

found in CE #2 to be violated

ERROR:

(defrule error

(foo (x ?x))

(test (> ?x 10))

⇒)

CLIPS>

The variable ?x, found in slot x of the first pattern, must be a symbol. Since the > function expects numeric values for its arguments, an error occurs.

This section describes various actions and functions which may be used on the LHS and RHS of rules, from the top level command prompt, and from other constructs such as deffunctions, defmessage handlers, and defmethods. The terms functions, actions, and commands should be thought of interchangeably. However, when the term function is used it generally refers to a function which returns a value. The term action refers to a function having no return value but performing some basic operation as a side effect (such as printout). The term command refers to functions normally entered at the top level command prompt (such as the reset command, which does not return a value, and the set strategy command, which does return a value).

The following functions perform predicate tests.

The numberp function returns the symbol TRUE if its argument is a float or integer, otherwise it returns the symbol FALSE.

Syntax

(numberp <expression>)

The floatp function returns the symbol TRUE if its argument is a float, otherwise it returns the symbol FALSE.

Syntax

(floatp <expression>)

The integerp function returns the symbol TRUE if its argument is an integer, otherwise it returns the symbol FALSE.

Syntax

(integerp <expression>)

The lexemep function returns the symbol TRUE if its argument is a string or symbol, otherwise it returns the symbol FALSE.

Syntax

(lexemep <expression>)

The stringp function returns the symbol TRUE if its argument is a string, otherwise it returns the symbol FALSE.

Syntax

(stringp <expression>)

The symbolp function returns the symbol TRUE if its argument is a symbol, otherwise it returns the symbol FALSE. This function may also be called using the name wordp.

Syntax

(symbolp <expression>)

The evenp function returns the symbol TRUE if its argument is an even number, otherwise it returns the symbol FALSE.

Syntax

(evenp <integer-expression>)

The oddp function returns the symbol TRUE if its argument is an odd number, otherwise it returns the symbol FALSE.

Syntax

(oddp <integer-expression>)

The multifieldp function returns the symbol TRUE if its argument is a multifield value, otherwise it returns the symbol FALSE. This function may also be called using the name sequencep.

Syntax

(multifieldp <expression>)

The pointerp function returns the symbol TRUE if its argument is an external address, otherwise it returns the symbol FALSE. External address;es are discussed in further detail in the Advanced Programming Guide.

Syntax

(pointerp <expression>)

The eq function returns the symbol TRUE if its first argument is equal in value to all its subsequent arguments, otherwise it returns the symbol FALSE. Note that eq compares types as well as values. Thus, (eq 3 3.0) is FALSE since 3 is an integer and 3.0 is a float.

Syntax

(eq <expression> <expression>+)

Example

CLIPS> (eq foo bar mumble foo)

FALSE

CLIPS> (eq foo foo foo foo)

TRUE

CLIPS> (eq 3 4)

FALSE

CLIPS>

The neq function returns the symbol TRUE if its first argument is not equal in value to all its subsequent arguments, otherwise it returns the symbol FALSE. Note that neq compares types as well as values. Thus, (neq 3 3.0) is TRUE since 3 is an integer and 3.0 is a float.

Syntax

(neq <expression> <expression>+)

Example

CLIPS> (neq foo bar yak bar)

TRUE

CLIPS> (neq foo foo yak bar)

FALSE

CLIPS> (neq 3 a)

TRUE

CLIPS>

The = function returns the symbol TRUE if its first argument is equal in value to all its subsequent arguments, otherwise it returns the symbol FALSE. Note that = compares only numeric values and will convert integers to floats when necessary for comparison.

Syntax

(= <numeric-expression> <numeric-expression>+)

Example

CLIPS> (= 3 3.0)

TRUE

CLIPS> (= 4 4.1)

FALSE

CLIPS>

Portability Note

Because the precision of floating point numbers varies from one machine to another, it is possible for the numeric comparison functions to work correctly one machine and incorrectly on another. In fact, you should be aware, even if code is not being ported, that roundoff error can cause erroneous results. For example, the following expression erroneously returns the symbol TRUE because both numbers are rounded up to 0.6666666666666666667.

CLIPS> (= 0.66666666666666666666 0.66666666666666666667)

TRUE

CLIPS>

The <> function returns the symbol TRUE if its first argument is not equal in value to all its subsequent arguments, otherwise it returns the symbol FALSE. Note that <> compares only numeric values and will convert integers to floats when necessary for comparison.

Syntax

(<> <numeric-expression> <numeric-expression>+)

Example

CLIPS> (<> 3 3.0)

FALSE

CLIPS> (<> 4 4.1)

TRUE

CLIPS>

Portability Note

See portability note in section 12.1.13.

The > function returns the symbol TRUE if for all its arguments, argument n 1 is greater than argument n, otherwise it returns the symbol FALSE. Note that > compares only numeric values and will convert integers to floats when necessary for comparison.

Syntax

(> <numeric-expression> <numeric-expression>+)

Example

CLIPS> (> 5 4 3)

TRUE

CLIPS> (> 5 3 4)

FALSE

CLIPS>

Portability Note

See portability note in section 12.1.13.

The >= function returns the symbol TRUE if for all its arguments, argument n 1 is greater than or equal to argument n, otherwise it returns the symbol FALSE. Note that >= compares only numeric values and will convert integers to floats when necessary for comparison.

Syntax

(>= <numeric-expression> <numeric-expression>+)

Example

CLIPS> (>= 5 5 3)

TRUE

CLIPS> (>= 5 3 5)

FALSE

CLIPS>

Portability Note

See portability note in section 12.1.13.

The < function returns the symbol TRUE if for all its arguments, argument n 1 is less than argument n, otherwise it returns the symbol FALSE. Note that < compares only numeric values and will convert integers to floats when necessary for comparison.

Syntax

(< <numeric-expression> <numeric-expression>+)

Example

CLIPS> (< 3 4 5)

TRUE

CLIPS> (< 3 5 4)

FALSE

CLIPS>

Portability Note

See portability note in section 12.1.13.

The ⇐ function returns the symbol TRUE if for all its arguments, argument n 1 is less than or equal to argument n, otherwise it returns the symbol FALSE. Note that ⇐ compares only numeric values and will convert integers to floats when necessary for comparison.

Syntax

(⇐ <numeric-expression> <numeric-expression>+)

Example

CLIPS> (⇐ 3 5 5)

TRUE

CLIPS> (⇐ 5 3 5)

FALSE

CLIPS>

Portability Note

See portability note in section 12.1.13.

The and function returns the symbol TRUE if each of its arguments evaluates to TRUE, otherwise it returns the symbol FALSE. The and function performs short circuited boolean logic. Each argument of the function is evaluated from left to right. If any argument evaluates to FALSE, then the symbol FALSE is immediately returned by the function.

Syntax

(and <expression>+)

The or function returns the symbol TRUE if any of its arguments evaluates to TRUE, otherwise it returns the symbol FALSE. The or function performs short circuited boolean logic. Each argument of the function is evaluated from left to right. If any argument evaluates to TRUE, then the symbol TRUE is immediately returned by the function.

Syntax

(or <expression>+)

The not function returns the symbol TRUE if its argument evaluates to FALSE, otherwise it returns the symbol FALSE.

Syntax

(not <expression>)

The following functions operate on multifield values.

This function appends any number of fields together to create a multifield value.

Syntax

(create$ <expression>*)

The return value of create$ is a multifield value regardless of the number or types of arguments (single field or multifield). Calling create$ with no arguments creates a multifield value of length zero.

Example

CLIPS (create$ hammer drill saw screw pliers wrench)

(hammer drill saw screw pliers wrench)

CLIPS> (create$ (+ 3 4) (* 2 3) (/ 8 4))

(7 6 2)

CLIPS>

The nth$ function will return a specified field from a multifield value.

Syntax

(nth$ <integer-expression> <multifield-expression>)

where the first argument should be an integer from 1 to the number of elements within the second argument. The symbol nil will be returned if the first argument is greater than the number of fields in the second argument.

Example

CLIPS> (nth$ 3 (create$ a b c d e f g))

c

CLIPS>

The member$ function will tell if a single field value is contained in a multifield value.

Syntax

(member$ <expression> <multifield-expression>)

If the first argument is a single field value and is one of the fields within the second argument, member$ will return the integer position of the field (from 1 to the length of the second argument). If the first argument is a multifield value and this value is embedded in the second argument, then the return value is a two field multifield value consisting of the starting and ending integer indices of the first argument within the second argument. If neither of these situations is satisfied, then FALSE is returned.

Example

CLIPS> (member$ blue (create$ red 3 “text” 8.7 blue))

5

CLIPS> (member$ 4 (create$ red 3 “text” 8.7 blue))

FALSE

CLIPS> (member$ (create$ b c) (create$ a b c d))

(2 3)

CLIPS>

This function checks if one multifield value is a subset of another; i.e., if all the fields in the first multifield value are also in the second multifield value.

Syntax

(subsetp <multifield-expression> <multifield-expression>)

If the first argument is a subset of the second argument, the function returns TRUE; otherwise, it returns FALSE. The order of the fields is not consi­dered. If the first argument is bound to a multifield of length zero, the subsetp function always returns TRUE.

Example

CLIPS> (subsetp (create$ hammer saw drill)

(create$ hammer drill wrench pliers saw))

TRUE

CLIPS> (subsetp (create$ wrench crowbar)

(create$ hammer drill wrench pliers saw))

FALSE

CLIPS>

This function deletes the specified range from a multifield value.

Syntax

(delete$ <multifield-expression>

<begin-integer-expression>

<end-integer-expression>)

The modified multifield value is returned, which is the same as <multifield expression> with the fields ranging from <begin integer expression> to <end integer expression> removed. To delete a single field, the begin range field should equal the end range field.

Example

CLIPS> (delete$ (create$ hammer drill saw pliers wrench) 3 4)

(hammer drill wrench)

CLIPS> (delete$ (create$ computer printer hard-disk) 1 1)

(printer hard-disk)

CLIPS>

This function constructs a multifield value from a string by using each field in a string as a field in a new multifield value.

Syntax

(explode$ <string-expression>)

A new multifield value is created in which each delimited field in order in <string expression> is taken to be a field in the new multifield value which is returned. A string with no fields creates a multifield value of length zero. Fields other than symbols, strings, integer, floats, or instances names (such as parentheses or variables) are converted to strings.

Example

CLIPS> (explode$ “hammer drill saw screw”)

(hammer drill saw screw)

CLIPS> (explode$ “1 2 abc 3 4 \”abc\” \“def\”“)

(1 2 abc 3 4 “abc” “def”)

CLIPS> (explode$ ”?x ~ )“)

(”?x“ ”~“ ”)“)

CLIPS>

This function creates a single string from a multifield value.

Syntax

(implode$ <multifield-expression>)

Each field in <multifield expression> in order is concatenated into a string value with a single blank sepa­rating fields. The new string is returned.

Example

CLIPS> (implode$ (create$ hammer drill screwdriver))

“hammer drill screwdriver wrench pliers saw”

CLIPS> (implode$ (create$ 1 “abc” def “ghi” 2))

“1 “abc” def “ghi” 2”

CLIPS> (implode$ (create$ “abc def ghi”))

”“abc def ghi”“

CLIPS>

This function extracts a specified range from a multifield value and returns a new mul­tifield value containing just the sub sequence.

Syntax

(subseq$ <multifield-value>

<begin-integer-expression>

<end-integer-expression>)

where the second and third arguments are integers specifying the begin and end fields of the desired sub sequence in <multifield expression>.

Example

CLIPS> (subseq$ (create$ hammer drill wrench pliers) 3 4)

(wrench pliers)

CLIPS> (subseq$ (create$ 1 “abc” def “ghi” 2) 1 1)

(1)

CLIPS>

This function replaces a range of field in a multifield value with a series of single field and/or multifield values and returns a new mul­tifield value containing the replacement values within the original multifield value.

Syntax

(replace$ <multifield-expression>

<begin-integer-expression>

<end-integer-expression>

<single-or-multi-field-expression>+)

where <begin integer expression> to <end integer expression> is the range of values to be replaced.

Example

CLIPS> (replace$ (create$ drill wrench pliers) 3 3 machete)

(drill wrench machete)

CLIPS> (replace$ (create$ a b c d) 2 3 x y (create$ q r s))

(a x y q r s d)

CLIPS>

This function inserts a series of single field and/or multifield values at a specified location in a multifield value with and returns a new mul­tifield value containing the inserted values within the original multifield value.

Syntax

(insert$ <multifield-expression>

<integer-expression>

<single-or-multi-field-expression>+)

where <integer expression> is the location where the values are to be inserted. This value must be greater than or equal to 1. A value of 1 inserts the new value(s) at the beginning of the <multifield expression>. Any value greater than the length of the <multifield expression> appends the new values to the end of the <multifield expression>.

Example

CLIPS> (insert$ (create$ a b c d) 1 x)

(x a b c d)

CLIPS> (insert$ (create$ a b c d) 4 y z)

(a b c y z d)

CLIPS> (insert$ (create$ a b c d) 5 (create$ q r))

(a b c d q r)

CLIPS>

This function returns the first field of a multifield value as a multifield value

Syntax

(first$ <multifield-expression>)

Example

CLIPS> (first$ (create$ a b c))

(a)

CLIPS> (first$ (create$))

()

CLIPS>

This function returns all but the first field of a multifield value as a multifield value.

Syntax

(rest$ <multifield-expression>)

Example

CLIPS> (rest$ (create$ a b c))

(b c)

CLIPS> (rest$ (create$))

()

CLIPS>

The length$ function returns an integer indicating the number of fields contained in a multifield value. If the argument passed to length$ is not the appropriate type, a negative one ( 1) is returned.

Syntax

(length$ <multifield-expression>)

Example

CLIPS> (length$ (create$ a b c d e f g))

7

CLIPS>

This function deletes specific values contained within a multifield value and returns the modified multifield value.

Syntax

(delete-member$ <multifield-expression> <expression>+)

where <expression>+ is one or more values to be deleted from <multifield-expression>. If <expression> is a multifield value, the entire sequence must be contained within the first argument in the correct order.

Example

CLIPS> (delete-member$ (create$ a b a c) b a)

©

CLIPS> (delete-member$ (create$ a b c c b a) (create$ b a))

(a b c c)

CLIPS>

This function replaces specific values contained within a multifield value and returns the modified multifield value.

Syntax

(replace-member$ <multifield-expression> <substitute-expression>

<search-expression>+)

where any <search-expression> that is contained within <multifield-expression> is replaced by <substitute-expression>.

Example

CLIPS> (replace-member$ (create$ a b a b) (create$ a b a) a b)

(a b a a b a a b a a b a)

CLIPS> (replace-member$ (create$ a b a b) (create$ a b a) (create$ a b))

(a b a a b a)

CLIPS>

The following functions perform operations that are related to strings.

The str cat function will concatenates its arguments into a single string.

Syntax

(str-cat <expression>*)

Each <expression> should be one of the following types: symbol, string, float, integer, or instance name.

Example

CLIPS> (str-cat “foo” bar)

“foobar”

CLIPS>

The sym cat function will concatenate its arguments into a single symbol. It is functionally identical to the str cat function with the exception that the returned value is a symbol and not a string.

Syntax

(sym-cat <expression>*)

Each <expression> should be one of the following types: symbol, string, float, integer, or instance name.

The sub string function will retrieve a portion of a string from another string.

Syntax

(sub-string <integer-expression> <integer-expression>

<string-expression>)

where the first argument, counting from one, must be a number marking the begin­ning position in the string and the second argument must be a number marking the ending position in the string. If the first argument is greater than the second argument, a null string is returned.

Example

CLIPS> (sub-string 3 8 “abcdefghijkl”)

“cdefgh”

CLIPS>

The str index function will return the position of a string inside another string.

Syntax

(str-index <lexeme-expression> <lexeme-expression>)

where the second argument is searched for the first occurrence of the first argument. The str index function re­turns the integer starting position, counting from one, of the first argument in the second argument or returns the symbol FALSE if not found.

Example

CLIPS> (str-index “def” “abcdefghi”)

4

CLIPS> (str-index “qwerty” “qwertypoiuyt”)

1

CLIPS> (str-index “qwerty” “poiuytqwer”)

FALSE

CLIPS>

The eval function evaluates the string as though it were entered at the command prompt.

Syntax

(eval <string-or-symbol-expression>)

where the only argument is the command, constant, or global variable to be executed. NOTE: eval does not permit the use of local variables (except when the local variables are defined as part of the command such as with an instance query function), nor will it evaluate any of the construct definition forms (i.e., defrule, deffacts, etc.;). The return value is the result of the evaluation of the string (or FALSE if an error occurs).

The eval function is not available for binary-load only or run time CLIPS configurations (see the Advanced Programming Guide).

Example

CLIPS> (eval ”(+ 3 4)“)

7

CLIPS> (eval ”(create$ a b c)“)

(a b c)

CLIPS>

The build function evaluates the string as though it were entered at the command prompt.

Syntax

(build <string-or-symbol-expression>)

where the only argument is the construct to be added. The return value is TRUE if the construct was added (or FALSE if an error occurs).

The build function is not available for binary-load only or run time CLIPS configurations (see the Advanced Programming Guide).

Example

CLIPS> (clear)

CLIPS> (build ”(defrule foo (a) ⇒ (assert (b)))“)

TRUE

CLIPS> (rules)

foo

For a total of 1 rule.

CLIPS>

The upcase function will return a string or symbol with uppercase alphabetic characters.

Syntax

(upcase <string-or-symbol-expression>)

Example

CLIPS> (upcase “This is a test of upcase”)

“THIS IS A TEST OF UPCASE”

CLIPS> (upcase A_Word_Test_for_Upcase)

A_WORD_TEST_FOR_UPCASE

CLIPS>

The lowcase function will return a string or symbol with lowercase alphabetic characters.

Syntax

(lowcase <string-or-symbol-expression>)

Example

CLIPS> (lowcase “This is a test of lowcase”)

“this is a test of lowcase”

CLIPS> (lowcase A_Word_Test_for_Lowcase)

a_word_test_for_lowcase

CLIPS>

The str compare function will compare two strings to determine their logical relationship (i.e., equal to, less than, greater than). The comparison is performed character by character until the strings are exhausted (implying equal strings) or un­equal characters are found. The positions of the unequal characters within the ASCII character set are used to determine the logical relationship of unequal strings.

Syntax

(str-compare <string-or-symbol-expression>

<string-or-symbol-expression>)

This function returns an integer representing the result of the comparison (0 if the strings are equal, < 0 if the first argument < the second argument, and > 0 if the first argument > the second argument).

Example